Whamcloud - gitweb
b=9729
[fs/lustre-release.git] / build / autoconf / lustre-build.m4
1 #
2 # LB_CHECK_VERSION
3 #
4 # Verify that LUSTRE_VERSION was defined properly
5 #
6 AC_DEFUN([LB_CHECK_VERSION],
7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
8         AC_MSG_ERROR([This script was not built with a version number.])
9 fi
10 ])
11
12 #
13 # LB_CANONICAL_SYSTEM
14 #
15 # fixup $target_os for use in other places
16 #
17 AC_DEFUN([LB_CANONICAL_SYSTEM],
18 [case $target_os in
19         linux*)
20                 lb_target_os="linux"
21                 ;;
22         darwin*)
23                 lb_target_os="darwin"
24                 ;;
25 esac
26 AC_SUBST(lb_target_os)
27 ])
28
29 #
30 # LB_CHECK_FILE
31 #
32 # Check for file existance even when cross compiling
33 #
34 AC_DEFUN([LB_CHECK_FILE],
35 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
36 AC_CACHE_CHECK([for $1], lb_File,
37 [if test -r "$1"; then
38   AS_VAR_SET(lb_File, yes)
39 else
40   AS_VAR_SET(lb_File, no)
41 fi])
42 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
43 AS_VAR_POPDEF([lb_File])dnl
44 ])# LB_CHECK_FILE
45
46 #
47 # LB_CHECK_FILES
48 #
49 # LB_CHECK_FILE over multiple files
50 #
51 AC_DEFUN([LB_CHECK_FILES],
52 [AC_FOREACH([AC_FILE_NAME], [$1],
53   [LB_CHECK_FILE(AC_FILE_NAME,
54                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
55                                     [Define to 1 if you have the
56                                      file `]AC_File['.])
57 $2],
58                  [$3])])])
59
60 #
61 # LB_ARG_LIBS_INCLUDES
62 #
63 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
64 # a single magical macro
65 #
66 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
67 [lb_pathvar="m4_bpatsubst([$2], -, _)"
68 AC_MSG_CHECKING([for $1])
69 AC_ARG_WITH([$2],
70         AC_HELP_STRING([--with-$2=path],
71                 [path to $1]),
72         [],[withval=$4])
73
74 if test x$withval = xyes ; then
75         eval "$lb_pathvar='$3'"
76 else
77         eval "$lb_pathvar='$withval'"
78 fi
79 AC_MSG_RESULT([${!lb_pathvar:-no}])
80
81 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
82         AC_MSG_CHECKING([for $1 includes])
83         AC_ARG_WITH([$2-includes],
84                 AC_HELP_STRING([--with-$2-includes=path],
85                         [path to $1 includes]),
86                 [],[withval='yes'])
87
88         lb_includevar="${lb_pathvar}_includes"
89         if test x$withval = xyes ; then
90                 eval "${lb_includevar}='${!lb_pathvar}/include'"
91         else
92                 eval "${lb_includevar}='$withval'"
93         fi
94         AC_MSG_RESULT([${!lb_includevar}])
95
96         AC_MSG_CHECKING([for $1 libs])
97         AC_ARG_WITH([$2-libs],
98                 AC_HELP_STRING([--with-$2-libs=path],
99                         [path to $1 libs]),
100                 [],[withval='yes'])
101
102         lb_libvar="${lb_pathvar}_libs"
103         if test x$withval = xyes ; then
104                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
105         else
106                 eval "${lb_libvar}='$withval'"
107         fi
108         AC_MSG_RESULT([${!lb_libvar}])
109 fi
110 ])
111 ])
112
113 #
114 # LB_PATH_LIBSYSIO
115 #
116 # Handle internal/external libsysio
117 #
118 AC_DEFUN([LB_PATH_LIBSYSIO],
119 [AC_ARG_WITH([sysio],
120         AC_HELP_STRING([--with-sysio=path],
121                         [set path to libsysio source (default is included libsysio)]),
122         [],[
123                 case $lb_target_os in
124                         linux)
125                                 with_sysio='yes'
126                                 ;;
127                         *)
128                                 with_sysio='no'
129                                 ;;
130                 esac
131         ])
132 AC_MSG_CHECKING([location of libsysio])
133 enable_sysio="$with_sysio"
134 case x$with_sysio in
135         xyes)
136                 AC_MSG_RESULT([internal])
137                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
138                         AC_MSG_ERROR([A complete internal libsysio was not found.])
139                 ])
140                 LIBSYSIO_SUBDIR="libsysio"
141                 SYSIO="$PWD/libsysio"
142                 ;;
143         xno)
144                 AC_MSG_RESULT([disabled])
145                 ;;
146         *)
147                 AC_MSG_RESULT([$with_sysio])
148                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
149                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
150                 ])
151                 SYSIO=$with_sysio
152                 with_sysio="yes"
153                 ;;
154 esac
155
156 # We have to configure even if we don't build here for make dist to
157 # work
158 AC_CONFIG_SUBDIRS(libsysio)
159 ])
160
161 #
162 # LB_CONFIG_PORTALS
163 #
164 # configure support for Cray Portals
165 #
166 AC_DEFUN([LB_CONFIG_PORTALS],
167 [AC_MSG_CHECKING([for external Portals])
168 AC_ARG_WITH([portals],
169         AC_HELP_STRING([--with-portals=path],
170                        [set path to portals]),
171         [
172                 case $with_portals in
173                         no)     PORTALS=""
174                                 enable_portals=no
175                                 ;;
176                         *)      if test x$with_portals != x ; then
177                                         PORTALS="$with_portals"
178                                         enable_portals=yes
179                                 else
180                                         AC_MSG_ERROR([Path to portals must be specified])
181                                         enable_portals=no
182                                 fi
183                                 ;;
184                 esac
185                 
186         ], [enable_portals=no])
187 AC_MSG_CHECKING([location of portals])
188 case x$enable_portals in
189         xyes)
190                 AC_MSG_RESULT([$PORTALS])
191                 LB_CHECK_FILE([$PORTALS/include/portals/api.h],[],
192                               AC_MSG_ERROR([Cannot find portals headers]))
193                 ;;
194         *)
195                 AC_MSG_RESULT([no external portals])
196                 ;;
197 esac
198
199 AC_SUBST(PORTALS)
200 ])
201
202 #
203 # LB_CONFIG_LUSTRE_PORTALS
204 #
205 # configure support for Lustre Portals
206 #
207 AC_DEFUN([LB_CONFIG_LUSTRE_PORTALS],
208 [AC_MSG_CHECKING([for Lustre Portals])
209 AC_ARG_WITH([lustre-portals],
210         AC_HELP_STRING([--with-lustre-portals=path],
211                        [set path to Lustre portals]),
212         [
213                 case $with_lustre_portals in
214                         yes)    LUSTRE_PORTALS="$PWD/portals"
215                                 enable_lustre_portals=yes
216                                 ;;
217                         no)     LUSTRE_PORTALS=""
218                                 enable_lustre_portals=no
219                                 ;;
220                         *)      if test x$with_lustre_portals != x ; then
221                                         LUSTRE_PORTALS="$with_lustre_portals"
222                                 else
223                                         LUSTRE_PORTALS="$PWD/portals"
224                                 fi
225                                 enable_lustre_portals=yes
226                                 ;;
227                 esac
228                 
229         ], [enable_lustre_portals=no])
230
231 AC_MSG_CHECKING([location of Lustre portals])
232 case x$enable_lustre_portals in
233         xyes)
234                 AC_MSG_RESULT([$LUSTRE_PORTALS])
235                 LB_CHECK_FILE([$LUSTRE_PORTALS/include/portals/api.h],[LUSTRE_PORTALS_SUBDIR="portals"],
236                               AC_MSG_ERROR([Cannot find Lustre portals headers]))
237                 ;;
238         *)
239                 AC_MSG_RESULT([disable Lustre portals])
240                 ;;
241 esac
242
243 AC_SUBST(LUSTRE_PORTALS_SUBDIR)
244 AC_SUBST(LUSTRE_PORTALS)
245 ])
246
247 #
248 # LB_CONFIG_CRAY_XT3
249 #
250 # Enable Cray XT3 features
251 #
252 AC_DEFUN([LB_CONFIG_CRAY_XT3],
253 [AC_MSG_CHECKING([whether to build Cray XT3 features])
254 AC_ARG_ENABLE([cray_xt3],
255         AC_HELP_STRING([--enable-cray-xt3],
256                         [enable building of Cray XT3 features]),
257         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
258 AC_MSG_RESULT([$enable_cray_xt3])
259 if test x$enable_cray_xt3 != xno; then
260         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
261 fi
262 ])
263
264 #
265 # LB_CONFIG_BGL
266 #
267 # Enable BGL features
268 #
269 AC_DEFUN([LB_CONFIG_BGL],
270 [AC_MSG_CHECKING([whether to build BGL features])
271 AC_ARG_ENABLE([bgl],
272         AC_HELP_STRING([--enable-bgl],
273                         [enable building of BGL features]),
274         [enable_bgl='yes'],[enable_bgl='no'])
275 AC_MSG_RESULT([$enable_bgl])
276 if test x$enable_bgl != xno; then
277         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
278 fi
279 ])
280
281 #
282 # LB_PATH_SNMP
283 #
284 # check for in-tree snmp support
285 #
286 AC_DEFUN([LB_PATH_SNMP],
287 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
288 AC_SUBST(SNMP_DIST_SUBDIR)
289 AC_SUBST(SNMP_SUBDIR)
290 ])
291
292 #
293 # LB_CONFIG_MODULES
294 #
295 # Build kernel modules?
296 #
297 AC_DEFUN([LB_CONFIG_MODULES],
298 [AC_MSG_CHECKING([whether to build kernel modules])
299 AC_ARG_ENABLE([modules],
300         AC_HELP_STRING([--disable-modules],
301                         [disable building of Lustre kernel modules]),
302         [],[
303                 LC_TARGET_SUPPORTED([
304                         enable_modules='yes'
305                 ],[
306                         enable_modules='no'
307                 ])
308         ])
309 AC_MSG_RESULT([$enable_modules ($target_os)])
310
311 if test x$enable_modules = xyes ; then
312         case $target_os in
313                 linux*)
314                         LB_PROG_LINUX
315                         ;;
316                 darwin*)
317                         LB_PROG_DARWIN
318                         ;;
319                 *)
320                         # This is strange - Lustre supports a target we don't
321                         AC_MSG_ERROR([Modules are not supported on $target_os])
322                         ;;
323         esac
324 fi
325 ])
326
327 #
328 # LB_CONFIG_UTILS
329 #
330 # Build utils?
331 #
332 AC_DEFUN([LB_CONFIG_UTILS],
333 [AC_MSG_CHECKING([whether to build utilities])
334 AC_ARG_ENABLE([utils],
335         AC_HELP_STRING([--disable-utils],
336                         [disable building of Lustre utility programs]),
337         [],[enable_utils='yes'])
338 AC_MSG_RESULT([$enable_utils])
339 if test x$enable_utils = xyes ; then 
340         LB_CONFIG_INIT_SCRIPTS
341 fi
342 ])
343
344 #
345 # LB_CONFIG_TESTS
346 #
347 # Build tests?
348 #
349 AC_DEFUN([LB_CONFIG_TESTS],
350 [AC_MSG_CHECKING([whether to build Lustre tests])
351 AC_ARG_ENABLE([tests],
352         AC_HELP_STRING([--disable-tests],
353                         [disable building of Lustre tests]),
354         [],
355         [
356                 enable_tests='yes'
357         ])
358 AC_MSG_RESULT([$enable_tests])
359 ])
360
361 #
362 # LB_CONFIG_DOCS
363 #
364 # Build docs?
365 #
366 AC_DEFUN([LB_CONFIG_DOCS],
367 [AC_MSG_CHECKING([whether to build docs])
368 AC_ARG_ENABLE(doc,
369         AC_HELP_STRING([--disable-doc],
370                         [skip creation of pdf documentation]),
371         [
372                 if test x$enable_doc = xyes ; then
373                     ENABLE_DOC=1           
374                 else
375                     ENABLE_DOC=0
376                 fi
377         ],[
378                 ENABLE_DOC=0
379                 enable_doc='no'
380         ])
381 AC_MSG_RESULT([$enable_doc])
382 AC_SUBST(ENABLE_DOC)
383 ])
384
385 #
386 # LB_CONFIG_INIT_SCRIPTS
387 #
388 # our init scripts only work on red hat linux
389 #
390 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
391 [ENABLE_INIT_SCRIPTS=0
392 if test x$enable_utils = xyes ; then
393         AC_MSG_CHECKING([whether to install init scripts])
394         # our scripts only work on red hat systems
395         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
396                 ENABLE_INIT_SCRIPTS=1
397                 AC_MSG_RESULT([yes])
398         else
399                 AC_MSG_RESULT([no])
400         fi
401 fi
402 AC_SUBST(ENABLE_INIT_SCRIPTS)
403 ])
404
405 #
406 # LB_CONFIG_HEADERS
407 #
408 # add -include config.h
409 #
410 AC_DEFUN([LB_CONFIG_HEADERS],
411 [AC_CONFIG_HEADERS([config.h])
412 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
413 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
414 AC_SUBST(EXTRA_KCFLAGS)
415 ])
416
417 #
418 # LB_INCLUDE_RULES
419 #
420 # defines for including the toplevel Rules
421 #
422 AC_DEFUN([LB_INCLUDE_RULES],
423 [INCLUDE_RULES="include $PWD/build/Rules"
424 AC_SUBST(INCLUDE_RULES)
425 ])
426
427 #
428 # LB_PATH_DEFAULTS
429 #
430 # 'fixup' default paths
431 #
432 AC_DEFUN([LB_PATH_DEFAULTS],
433 [# directories for binaries
434 AC_PREFIX_DEFAULT([/usr])
435
436 sysconfdir='/etc'
437 AC_SUBST(sysconfdir)
438
439 # Directories for documentation and demos.
440 docdir='${datadir}/doc/$(PACKAGE)'
441 AC_SUBST(docdir)
442
443 LN_PATH_DEFAULTS
444 LC_PATH_DEFAULTS
445
446 ])
447
448 #
449 # LB_PROG_CC
450 #
451 # checks on the C compiler
452 #
453 AC_DEFUN([LB_PROG_CC],
454 [AC_PROG_RANLIB
455 AC_MSG_CHECKING([for buggy compiler])
456 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
457 bad_cc() {
458         AC_MSG_RESULT([buggy compiler found!])
459         echo
460         echo "   '$CC_VERSION'"
461         echo "  has been known to generate bad code, "
462         echo "  please get an updated compiler."
463         AC_MSG_ERROR([sorry])
464 }
465 case "$CC_VERSION" in
466         "gcc version 2.95"*)
467                 bad_cc
468                 ;;
469         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
470         # without "sub    $0xc,%esp" to protect the stack from being
471         # stomped on by interrupts (bug 606)
472         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
473                 bad_cc
474                 ;;
475         # mandrake's similar sub 0xc compiler bug
476         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
477         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
478                 bad_cc
479                 ;;
480         *)
481                 AC_MSG_RESULT([no known problems])
482                 ;;
483 esac
484
485 # ---------  unsigned long long sane? -------
486 AC_CHECK_SIZEOF(unsigned long long, 0)
487 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
488 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
489 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
490         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
491 fi
492
493 if test x$enable_bgl != xyes; then
494 AC_MSG_CHECKING([if $CC accepts -m64])
495 CC_save="$CC"
496 CC="$CC -m64"
497 AC_TRY_COMPILE([],[],[
498         AC_MSG_RESULT([yes])
499 ],[
500         AC_MSG_RESULT([no])
501         CC="$CC_save"
502 ])
503 fi
504
505 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
506
507 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
508 AC_SUBST(LLCPPFLAGS)
509
510 LLCFLAGS="-g -Wall -fPIC"
511 AC_SUBST(LLCFLAGS)
512
513 # everyone builds against lnet and lustre
514 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
515 AC_SUBST(EXTRA_KCFLAGS)
516 ])
517
518 #
519 # LB_CONTITIONALS
520 #
521 # AM_CONDITIONAL instances for everything
522 # (so that portals/lustre can disable some if needed)
523 AC_DEFUN([LB_CONDITIONALS],
524 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
525 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
526 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
527 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
528 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
529 AM_CONDITIONAL(BUILD_PORTALS, test x$LUSTRE_PORTALS_SUBDIR = "xportals")
530 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
531 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
532
533 # this lets lustre cancel libsysio, per-branch or if liblustre is
534 # disabled
535 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
536         if test "x$with_sysio" != xyes ; then
537                 SYSIO=""
538                 LIBSYSIO_SUBDIR=""
539         fi
540 fi
541 AC_SUBST(LIBSYSIO_SUBDIR)
542 AC_SUBST(SYSIO)
543
544 LB_LINUX_CONDITIONALS
545 LB_DARWIN_CONDITIONALS
546
547 LN_CONDITIONALS
548 LC_CONDITIONALS
549 #if test "$LUSTRE_PORTALS" ; then
550         LP_CONDITIONALS
551 #fi
552 ])
553
554 #
555 # LB_CONFIGURE
556 #
557 # main configure steps
558 #
559 AC_DEFUN([LB_CONFIGURE],
560 [LB_CANONICAL_SYSTEM
561
562 LB_INCLUDE_RULES
563
564 LB_CONFIG_PORTALS
565 if ! test "$PORTALS" ; then
566 # if portals is configured, Lustre portals will be ignored
567         LB_CONFIG_LUSTRE_PORTALS
568 fi
569 LB_CONFIG_CRAY_XT3
570 LB_CONFIG_BGL
571 LB_PATH_DEFAULTS
572
573 LB_PROG_CC
574
575 LB_PATH_LIBSYSIO
576 LB_PATH_SNMP
577
578 if test "$LUSTRE_PORTALS" ; then
579         LP_PROG_CC
580 fi
581
582 LB_CONFIG_DOCS
583 LB_CONFIG_UTILS
584 LB_CONFIG_TESTS
585 LC_CONFIG_CLIENT_SERVER
586
587 LB_CONFIG_MODULES
588
589 LC_CONFIG_LIBLUSTRE
590
591 LN_CONFIGURE
592
593 LC_CONFIGURE
594 if test "$LUSTRE_PORTALS" ; then
595         LP_CONFIGURE
596 fi
597 if test "$SNMP_DIST_SUBDIR" ; then
598         LS_CONFIGURE
599 fi
600
601 LB_CONDITIONALS
602 LB_CONFIG_HEADERS
603
604 AC_CONFIG_FILES(
605 [Makefile:build/Makefile.in.toplevel]
606 [autoMakefile
607 build/autoMakefile
608 build/autoconf/Makefile
609 build/Rules
610 build/lustre.spec
611 ])
612
613 LN_CONFIG_FILES
614 LC_CONFIG_FILES
615 if test "$LUSTRE_PORTALS" ; then
616         LP_CONFIG_FILES
617 fi
618 if test "$SNMP_DIST_SUBDIR" ; then
619         LS_CONFIG_FILES
620 fi
621
622 AC_SUBST(ac_configure_args)
623
624 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.*'
625 AC_SUBST(MOSTLYCLEANFILES)
626
627 AC_OUTPUT
628
629 cat <<_ACEOF
630
631 CC:            $CC
632 LD:            $LD
633 CPPFLAGS:      $CPPFLAGS
634 LLCPPFLAGS:    $LLCPPFLAGS
635 CFLAGS:        $CFLAGS
636 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
637 LLCFLAGS:      $LLCFLAGS
638
639 Type 'make' to build Lustre.
640 _ACEOF
641 ])