build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25 esac
  26 AC_SUBST(lb_target_os)
  27 ])
  28
  29 #
  30 # LB_CHECK_FILE
  31 #
  32 # Check for file existance even when cross compiling
  33 #
  34 AC_DEFUN([LB_CHECK_FILE],
  35 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  36 AC_CACHE_CHECK([for $1], lb_File,
  37 [if test -r "$1"; then
  38   AS_VAR_SET(lb_File, yes)
  39 else
  40   AS_VAR_SET(lb_File, no)
  41 fi])
  42 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  43 AS_VAR_POPDEF([lb_File])dnl
  44 ])# LB_CHECK_FILE
  45
  46 #
  47 # LB_CHECK_FILES
  48 #
  49 # LB_CHECK_FILE over multiple files
  50 #
  51 AC_DEFUN([LB_CHECK_FILES],
  52 [AC_FOREACH([AC_FILE_NAME], [$1],
  53   [LB_CHECK_FILE(AC_FILE_NAME,
  54                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  55                                     [Define to 1 if you have the
  56                                      file `]AC_File['.])
  57 $2],
  58                  [$3])])])
  59
  60 #
  61 # LB_ARG_LIBS_INCLUDES
  62 #
  63 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  64 # a single magical macro
  65 #
  66 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  67 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  68 AC_MSG_CHECKING([for $1])
  69 AC_ARG_WITH([$2],
  70         AC_HELP_STRING([--with-$2=path],
  71                 [path to $1]),
  72         [],[withval=$4])
  73
  74 if test x$withval = xyes ; then
  75         eval "$lb_pathvar='$3'"
  76 else
  77         eval "$lb_pathvar='$withval'"
  78 fi
  79 AC_MSG_RESULT([${!lb_pathvar:-no}])
  80
  81 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  82         AC_MSG_CHECKING([for $1 includes])
  83         AC_ARG_WITH([$2-includes],
  84                 AC_HELP_STRING([--with-$2-includes=path],
  85                         [path to $1 includes]),
  86                 [],[withval='yes'])
  87
  88         lb_includevar="${lb_pathvar}_includes"
  89         if test x$withval = xyes ; then
  90                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  91         else
  92                 eval "${lb_includevar}='$withval'"
  93         fi
  94         AC_MSG_RESULT([${!lb_includevar}])
  95
  96         AC_MSG_CHECKING([for $1 libs])
  97         AC_ARG_WITH([$2-libs],
  98                 AC_HELP_STRING([--with-$2-libs=path],
  99                         [path to $1 libs]),
 100                 [],[withval='yes'])
 101
 102         lb_libvar="${lb_pathvar}_libs"
 103         if test x$withval = xyes ; then
 104                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 105         else
 106                 eval "${lb_libvar}='$withval'"
 107         fi
 108         AC_MSG_RESULT([${!lb_libvar}])
 109 fi
 110 ])
 111 ])
 112
 113 #
 114 # LB_PATH_LIBSYSIO
 115 #
 116 # Handle internal/external libsysio
 117 #
 118 AC_DEFUN([LB_PATH_LIBSYSIO],
 119 [AC_ARG_WITH([sysio],
 120         AC_HELP_STRING([--with-sysio=path],
 121                         [set path to libsysio source (default is included libsysio)]),
 122         [],[
 123                 case $lb_target_os in
 124                         linux)
 125                                 with_sysio='yes'
 126                                 ;;
 127                         *)
 128                                 with_sysio='no'
 129                                 ;;
 130                 esac
 131         ])
 132 AC_MSG_CHECKING([location of libsysio])
 133 enable_sysio="$with_sysio"
 134 case x$with_sysio in
 135         xyes)
 136                 AC_MSG_RESULT([internal])
 137                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 138                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 139                 ])
 140                 LIBSYSIO_SUBDIR="libsysio"
 141                 SYSIO="$PWD/libsysio"
 142                 ;;
 143         xno)
 144                 AC_MSG_RESULT([disabled])
 145                 ;;
 146         *)
 147                 AC_MSG_RESULT([$with_sysio])
 148                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 149                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 150                 ])
 151                 SYSIO=$with_sysio
 152                 with_sysio="yes"
 153                 ;;
 154 esac
 155
 156 # We have to configure even if we don't build here for make dist to
 157 # work
 158 AC_CONFIG_SUBDIRS(libsysio)
 159 ])
 160
 161 #
 162 # LB_CONFIG_PORTALS
 163 #
 164 # configure support for Cray Portals
 165 #
 166 AC_DEFUN([LB_CONFIG_PORTALS],
 167 [AC_MSG_CHECKING([for external Portals])
 168 AC_ARG_WITH([portals],
 169         AC_HELP_STRING([--with-portals=path],
 170                        [set path to portals]),
 171         [
 172                 case $with_portals in
 173                         no)     PORTALS=""
 174                                 enable_portals=no
 175                                 ;;
 176                         *)      if test x$with_portals != x ; then
 177                                         PORTALS="$with_portals"
 178                                         enable_portals=yes
 179                                 else
 180                                         AC_MSG_ERROR([Path to portals must be specified])
 181                                         enable_portals=no
 182                                 fi
 183                                 ;;
 184                 esac
 185
 186         ], [enable_portals=no])
 187 AC_MSG_CHECKING([location of portals])
 188 case x$enable_portals in
 189         xyes)
 190                 AC_MSG_RESULT([$PORTALS])
 191                 LB_CHECK_FILE([$PORTALS/include/portals/api.h],[],
 192                               AC_MSG_ERROR([Cannot find portals headers]))
 193                 ;;
 194         *)
 195                 AC_MSG_RESULT([no external portals])
 196                 ;;
 197 esac
 198
 199 AC_SUBST(PORTALS)
 200 ])
 201
 202 #
 203 # LB_CONFIG_LUSTRE_PORTALS
 204 #
 205 # configure support for Lustre Portals
 206 #
 207 AC_DEFUN([LB_CONFIG_LUSTRE_PORTALS],
 208 [AC_MSG_CHECKING([for Lustre Portals])
 209 AC_ARG_WITH([lustre-portals],
 210         AC_HELP_STRING([--with-lustre-portals=path],
 211                        [set path to Lustre portals]),
 212         [
 213                 case $with_lustre_portals in
 214                         yes)    LUSTRE_PORTALS="$PWD/portals"
 215                                 enable_lustre_portals=yes
 216                                 ;;
 217                         no)     LUSTRE_PORTALS=""
 218                                 enable_lustre_portals=no
 219                                 ;;
 220                         *)      if test x$with_lustre_portals != x ; then
 221                                         LUSTRE_PORTALS="$with_lustre_portals"
 222                                 else
 223                                         LUSTRE_PORTALS="$PWD/portals"
 224                                 fi
 225                                 enable_lustre_portals=yes
 226                                 ;;
 227                 esac
 228
 229         ], [enable_lustre_portals=no])
 230
 231 AC_MSG_CHECKING([location of Lustre portals])
 232 case x$enable_lustre_portals in
 233         xyes)
 234                 AC_MSG_RESULT([$LUSTRE_PORTALS])
 235                 LB_CHECK_FILE([$LUSTRE_PORTALS/include/portals/api.h],[LUSTRE_PORTALS_SUBDIR="portals"],
 236                               AC_MSG_ERROR([Cannot find Lustre portals headers]))
 237                 ;;
 238         *)
 239                 AC_MSG_RESULT([disable Lustre portals])
 240                 ;;
 241 esac
 242
 243 AC_SUBST(LUSTRE_PORTALS_SUBDIR)
 244 AC_SUBST(LUSTRE_PORTALS)
 245 ])
 246
 247 #
 248 # LB_CONFIG_CRAY_XT3
 249 #
 250 # Enable Cray XT3 features
 251 #
 252 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 253 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 254 AC_ARG_ENABLE([cray_xt3],
 255         AC_HELP_STRING([--enable-cray-xt3],
 256                         [enable building of Cray XT3 features]),
 257         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 258 AC_MSG_RESULT([$enable_cray_xt3])
 259 if test x$enable_cray_xt3 != xno; then
 260         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 261 fi
 262 ])
 263
 264
 265 #
 266 # LB_PATH_SNMP
 267 #
 268 # check for in-tree snmp support
 269 #
 270 AC_DEFUN([LB_PATH_SNMP],
 271 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 272 AC_SUBST(SNMP_DIST_SUBDIR)
 273 AC_SUBST(SNMP_SUBDIR)
 274 ])
 275
 276 #
 277 # LB_CONFIG_MODULES
 278 #
 279 # Build kernel modules?
 280 #
 281 AC_DEFUN([LB_CONFIG_MODULES],
 282 [AC_MSG_CHECKING([whether to build kernel modules])
 283 AC_ARG_ENABLE([modules],
 284         AC_HELP_STRING([--disable-modules],
 285                         [disable building of Lustre kernel modules]),
 286         [],[
 287                 LC_TARGET_SUPPORTED([
 288                         enable_modules='yes'
 289                 ],[
 290                         enable_modules='no'
 291                 ])
 292         ])
 293 AC_MSG_RESULT([$enable_modules ($target_os)])
 294
 295 if test x$enable_modules = xyes ; then
 296         case $target_os in
 297                 linux*)
 298                         LB_PROG_LINUX
 299                         ;;
 300                 darwin*)
 301                         LB_PROG_DARWIN
 302                         ;;
 303                 *)
 304                         # This is strange - Lustre supports a target we don't
 305                         AC_MSG_ERROR([Modules are not supported on $target_os])
 306                         ;;
 307         esac
 308 fi
 309 ])
 310
 311 #
 312 # LB_CONFIG_UTILS
 313 #
 314 # Build utils?
 315 #
 316 AC_DEFUN([LB_CONFIG_UTILS],
 317 [AC_MSG_CHECKING([whether to build utilities])
 318 AC_ARG_ENABLE([utils],
 319         AC_HELP_STRING([--disable-utils],
 320                         [disable building of Lustre utility programs]),
 321         [],[enable_utils='yes'])
 322 AC_MSG_RESULT([$enable_utils])
 323 if test x$enable_utils = xyes ; then
 324         LB_CONFIG_INIT_SCRIPTS
 325 fi
 326 ])
 327
 328 #
 329 # LB_CONFIG_TESTS
 330 #
 331 # Build tests?
 332 #
 333 AC_DEFUN([LB_CONFIG_TESTS],
 334 [AC_MSG_CHECKING([whether to build Lustre tests])
 335 AC_ARG_ENABLE([tests],
 336         AC_HELP_STRING([--disable-tests],
 337                         [disable building of Lustre tests]),
 338         [],
 339         [
 340                 enable_tests='yes'
 341         ])
 342 AC_MSG_RESULT([$enable_tests])
 343 ])
 344
 345 #
 346 # LB_CONFIG_DOCS
 347 #
 348 # Build docs?
 349 #
 350 AC_DEFUN([LB_CONFIG_DOCS],
 351 [AC_MSG_CHECKING([whether to build docs])
 352 AC_ARG_ENABLE(doc,
 353         AC_HELP_STRING([--disable-doc],
 354                         [skip creation of pdf documentation]),
 355         [
 356                 if test x$enable_doc = xyes ; then
 357                     ENABLE_DOC=1
 358                 else
 359                     ENABLE_DOC=0
 360                 fi
 361         ],[
 362                 ENABLE_DOC=0
 363                 enable_doc='no'
 364         ])
 365 AC_MSG_RESULT([$enable_doc])
 366 AC_SUBST(ENABLE_DOC)
 367 ])
 368
 369 #
 370 # LB_CONFIG_INIT_SCRIPTS
 371 #
 372 # our init scripts only work on red hat linux
 373 #
 374 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 375 [ENABLE_INIT_SCRIPTS=0
 376 if test x$enable_utils = xyes ; then
 377         AC_MSG_CHECKING([whether to install init scripts])
 378         # our scripts only work on red hat systems
 379         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 380                 ENABLE_INIT_SCRIPTS=1
 381                 AC_MSG_RESULT([yes])
 382         else
 383                 AC_MSG_RESULT([no])
 384         fi
 385 fi
 386 AC_SUBST(ENABLE_INIT_SCRIPTS)
 387 ])
 388
 389 #
 390 # LB_CONFIG_HEADERS
 391 #
 392 # add -include config.h
 393 #
 394 AC_DEFUN([LB_CONFIG_HEADERS],
 395 [AC_CONFIG_HEADERS([config.h])
 396 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 397 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 398 AC_SUBST(EXTRA_KCFLAGS)
 399 ])
 400
 401 #
 402 # LB_INCLUDE_RULES
 403 #
 404 # defines for including the toplevel Rules
 405 #
 406 AC_DEFUN([LB_INCLUDE_RULES],
 407 [INCLUDE_RULES="include $PWD/build/Rules"
 408 AC_SUBST(INCLUDE_RULES)
 409 ])
 410
 411 #
 412 # LB_PATH_DEFAULTS
 413 #
 414 # 'fixup' default paths
 415 #
 416 AC_DEFUN([LB_PATH_DEFAULTS],
 417 [# directories for binaries
 418 AC_PREFIX_DEFAULT([/usr])
 419
 420 sysconfdir='/etc'
 421 AC_SUBST(sysconfdir)
 422
 423 # Directories for documentation and demos.
 424 docdir='${datadir}/doc/$(PACKAGE)'
 425 AC_SUBST(docdir)
 426
 427 LN_PATH_DEFAULTS
 428 LC_PATH_DEFAULTS
 429
 430 ])
 431
 432 #
 433 # LB_PROG_CC
 434 #
 435 # checks on the C compiler
 436 #
 437 AC_DEFUN([LB_PROG_CC],
 438 [AC_PROG_RANLIB
 439 AC_MSG_CHECKING([for buggy compiler])
 440 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 441 bad_cc() {
 442         AC_MSG_RESULT([buggy compiler found!])
 443         echo
 444         echo "   '$CC_VERSION'"
 445         echo "  has been known to generate bad code, "
 446         echo "  please get an updated compiler."
 447         AC_MSG_ERROR([sorry])
 448 }
 449 case "$CC_VERSION" in
 450         "gcc version 2.95"*)
 451                 bad_cc
 452                 ;;
 453         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 454         # without "sub    $0xc,%esp" to protect the stack from being
 455         # stomped on by interrupts (bug 606)
 456         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 457                 bad_cc
 458                 ;;
 459         # mandrake's similar sub 0xc compiler bug
 460         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 461         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 462                 bad_cc
 463                 ;;
 464         *)
 465                 AC_MSG_RESULT([no known problems])
 466                 ;;
 467 esac
 468
 469 # ---------  unsigned long long sane? -------
 470 AC_CHECK_SIZEOF(unsigned long long, 0)
 471 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 472 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 473 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 474         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 475 fi
 476
 477 AC_MSG_CHECKING([if $CC accepts -m64])
 478 CC_save="$CC"
 479 CC="$CC -m64"
 480 AC_TRY_COMPILE([],[],[
 481         AC_MSG_RESULT([yes])
 482 ],[
 483         AC_MSG_RESULT([no])
 484         CC="$CC_save"
 485 ])
 486
 487 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 488
 489 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 490 AC_SUBST(LLCPPFLAGS)
 491
 492 LLCFLAGS="-g -Wall -fPIC"
 493 AC_SUBST(LLCFLAGS)
 494
 495 # everyone builds against lnet and lustre
 496 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
 497 AC_SUBST(EXTRA_KCFLAGS)
 498 ])
 499
 500 #
 501 # LB_CONTITIONALS
 502 #
 503 # AM_CONDITIONAL instances for everything
 504 # (so that portals/lustre can disable some if needed)
 505 AC_DEFUN([LB_CONDITIONALS],
 506 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 507 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 508 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 509 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 510 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 511 AM_CONDITIONAL(BUILD_PORTALS, test x$LUSTRE_PORTALS_SUBDIR = "xportals")
 512 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 513 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 514
 515 # this lets lustre cancel libsysio, per-branch or if liblustre is
 516 # disabled
 517 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 518         if test "x$with_sysio" != xyes ; then
 519                 SYSIO=""
 520                 LIBSYSIO_SUBDIR=""
 521         fi
 522 fi
 523 AC_SUBST(LIBSYSIO_SUBDIR)
 524 AC_SUBST(SYSIO)
 525
 526 LB_LINUX_CONDITIONALS
 527 LB_DARWIN_CONDITIONALS
 528
 529 LN_CONDITIONALS
 530 LC_CONDITIONALS
 531 #if test "$LUSTRE_PORTALS" ; then
 532         LP_CONDITIONALS
 533 #fi
 534 ])
 535
 536 #
 537 # LB_CONFIGURE
 538 #
 539 # main configure steps
 540 #
 541 AC_DEFUN([LB_CONFIGURE],
 542 [LB_CANONICAL_SYSTEM
 543
 544 LB_INCLUDE_RULES
 545
 546 LB_CONFIG_PORTALS
 547 if ! test "$PORTALS" ; then
 548 # if portals is configured, Lustre portals will be ignored
 549         LB_CONFIG_LUSTRE_PORTALS
 550 fi
 551 LB_CONFIG_CRAY_XT3
 552 LB_PATH_DEFAULTS
 553
 554 LB_PROG_CC
 555
 556 LB_PATH_LIBSYSIO
 557 LB_PATH_SNMP
 558
 559 if test "$LUSTRE_PORTALS" ; then
 560         LP_PROG_CC
 561 fi
 562
 563 LB_CONFIG_DOCS
 564 LB_CONFIG_UTILS
 565 LB_CONFIG_TESTS
 566 LC_CONFIG_CLIENT_SERVER
 567
 568 LB_CONFIG_MODULES
 569
 570 LC_CONFIG_LIBLUSTRE
 571
 572 LN_CONFIGURE
 573
 574 LC_CONFIGURE
 575 if test "$LUSTRE_PORTALS" ; then
 576         LP_CONFIGURE
 577 fi
 578 if test "$SNMP_DIST_SUBDIR" ; then
 579         LS_CONFIGURE
 580 fi
 581
 582 LB_CONDITIONALS
 583 LB_CONFIG_HEADERS
 584
 585 AC_CONFIG_FILES(
 586 [Makefile:build/Makefile.in.toplevel]
 587 [autoMakefile
 588 build/autoMakefile
 589 build/autoconf/Makefile
 590 build/Rules
 591 build/lustre.spec
 592 ])
 593
 594 LN_CONFIG_FILES
 595 LC_CONFIG_FILES
 596 if test "$LUSTRE_PORTALS" ; then
 597         LP_CONFIG_FILES
 598 fi
 599 if test "$SNMP_DIST_SUBDIR" ; then
 600         LS_CONFIG_FILES
 601 fi
 602
 603 AC_SUBST(ac_configure_args)
 604
 605 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.*'
 606 AC_SUBST(MOSTLYCLEANFILES)
 607
 608 AC_OUTPUT
 609
 610 cat <<_ACEOF
 611
 612 CC:            $CC
 613 LD:            $LD
 614 CPPFLAGS:      $CPPFLAGS
 615 LLCPPFLAGS:    $LLCPPFLAGS
 616 CFLAGS:        $CFLAGS
 617 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 618 LLCFLAGS:      $LLCFLAGS
 619
 620 Type 'make' to build Lustre.
 621 _ACEOF
 622 ])