build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_DOWNSTREAM_RELEASE
  33 #
  34 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  35 [AC_ARG_WITH([downstream-release],
  36         AC_HELP_STRING([--with-downstream-release=string],
  37                        [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  38         [DOWNSTREAM_RELEASE=$with_downstream_release],
  39         [
  40         # if not specified, see if it's in the META file
  41         if test -f META; then
  42                 DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)
  43         fi
  44         ])
  45 AC_SUBST(DOWNSTREAM_RELEASE)
  46 ])
  47
  48 #
  49 # LB_BUILDID
  50 #
  51 # Check if the source is a GA release and if not, set a "BUILDID"
  52 #
  53 # Currently there are at least two ways/modes of/for doing this.  One
  54 # is if we are in a valid git repository, the other is if we are in a
  55 # non-git source tree of some form.  Building the latter from the former
  56 # will be handled here.
  57 AC_DEFUN([LB_BUILDID],
  58 [
  59 AC_MSG_CHECKING([for buildid])
  60 BUILDID=""
  61 if git branch >/dev/null 2>&1; then
  62         ffw=0
  63         hash=""
  64         ver=$(git describe --match v[[0-9]]_*_[[0-9]] --tags)
  65         if [[[ $ver = *-*-* ]]]; then
  66                 hash=${ver##*-}
  67                 ffw=${ver#*-}
  68                 ffw=${ffw%-*}
  69                 ver=${ver%%-*}
  70         fi
  71         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  72         # here but the portability of the regex on the right is dismal
  73         # (thanx suse)
  74         if echo "$ver" | egrep -q "^v([0-9]+_)+([0-9]+|RC[0-9]+)$"; then
  75                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  76                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  77         fi
  78
  79         # a "lustre fix" value of .0 should be truncated
  80         if [[[ $ver = *.*.*.0 ]]]; then
  81                 ver=${ver%.0}
  82         fi
  83         # ditto for a "lustre fix" value of _0
  84         if [[[ $ver = v*_*_*_0 ]]]; then
  85                 ver=${ver%_0}
  86         fi
  87         if [[[ $ver = v*_*_* ]]]; then
  88                 ver=${ver#v}
  89                 ver=${ver//_/.}
  90         fi
  91
  92         # only do this test for lustre (not ldiskfs)
  93         if test "$PACKAGE" = "lustre" -a "$ver" != "$VERSION"; then
  94                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  95         fi
  96
  97         if test "$ffw" != "0"; then
  98                 BUILDID="$hash"
  99                 msg="$BUILDID (ahead by $ffw commits)"
 100                 AC_MSG_RESULT([$msg])
 101         else
 102                 AC_MSG_RESULT([none... congratulations, you must be on a tag])
 103         fi
 104 elif test -f META; then
 105         BUILDID=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
 106         msg="$BUILDID (from META file)"
 107         AC_MSG_RESULT([$msg])
 108 else
 109         AC_MSG_WARN([FIXME: I don't know how to deal with source trees outside of git that don't have a META file.  Not setting a buildid.])
 110 fi
 111 AC_SUBST(BUILDID)
 112 ])
 113
 114 #
 115 # LB_CHECK_FILE
 116 #
 117 # Check for file existance even when cross compiling
 118 #
 119 AC_DEFUN([LB_CHECK_FILE],
 120 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
 121 AC_CACHE_CHECK([for $1], lb_File,
 122 [if test -r "$1"; then
 123   AS_VAR_SET(lb_File, yes)
 124 else
 125   AS_VAR_SET(lb_File, no)
 126 fi])
 127 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
 128 AS_VAR_POPDEF([lb_File])dnl
 129 ])# LB_CHECK_FILE
 130
 131
 132 #
 133 # LB_ARG_LIBS_INCLUDES
 134 #
 135 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 136 # a single magical macro
 137 #
 138 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
 139 [lb_pathvar="m4_bpatsubst([$2], -, _)"
 140 AC_MSG_CHECKING([for $1])
 141 AC_ARG_WITH([$2],
 142         AC_HELP_STRING([--with-$2=path],
 143                 [path to $1]),
 144         [],[withval=$4])
 145
 146 if test x$withval = xyes ; then
 147         eval "$lb_pathvar='$3'"
 148 else
 149         eval "$lb_pathvar='$withval'"
 150 fi
 151 AC_MSG_RESULT([${!lb_pathvar:-no}])
 152
 153 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
 154         AC_MSG_CHECKING([for $1 includes])
 155         AC_ARG_WITH([$2-includes],
 156                 AC_HELP_STRING([--with-$2-includes=path],
 157                         [path to $1 includes]),
 158                 [],[withval='yes'])
 159
 160         lb_includevar="${lb_pathvar}_includes"
 161         if test x$withval = xyes ; then
 162                 eval "${lb_includevar}='${!lb_pathvar}/include'"
 163         else
 164                 eval "${lb_includevar}='$withval'"
 165         fi
 166         AC_MSG_RESULT([${!lb_includevar}])
 167
 168         AC_MSG_CHECKING([for $1 libs])
 169         AC_ARG_WITH([$2-libs],
 170                 AC_HELP_STRING([--with-$2-libs=path],
 171                         [path to $1 libs]),
 172                 [],[withval='yes'])
 173
 174         lb_libvar="${lb_pathvar}_libs"
 175         if test x$withval = xyes ; then
 176                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 177         else
 178                 eval "${lb_libvar}='$withval'"
 179         fi
 180         AC_MSG_RESULT([${!lb_libvar}])
 181 fi
 182 ])
 183 ])
 184
 185 #
 186 # LB_PATH_LIBSYSIO
 187 #
 188 # Handle internal/external libsysio
 189 #
 190 AC_DEFUN([LB_PATH_LIBSYSIO],
 191 [AC_ARG_WITH([sysio],
 192         AC_HELP_STRING([--with-sysio=path],
 193                         [set path to libsysio source (default is included libsysio)]),
 194         [],[
 195                 case $lb_target_os in
 196                         linux)
 197                                 with_sysio='yes'
 198                                 ;;
 199                         *)
 200                                 with_sysio='no'
 201                                 ;;
 202                 esac
 203         ])
 204 AC_MSG_CHECKING([location of libsysio])
 205 enable_sysio="$with_sysio"
 206 case x$with_sysio in
 207         xyes)
 208                 AC_MSG_RESULT([internal])
 209                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 210                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 211                 ])
 212                 LIBSYSIO_SUBDIR="libsysio"
 213                 SYSIO="$PWD/libsysio"
 214                 ;;
 215         xno)
 216                 AC_MSG_RESULT([disabled])
 217                 ;;
 218         *)
 219                 AC_MSG_RESULT([$with_sysio])
 220                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 221                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 222                 ])
 223                 SYSIO=$with_sysio
 224                 with_sysio="yes"
 225                 ;;
 226 esac
 227
 228 # We have to configure even if we don't build here for make dist to work
 229 AC_CONFIG_SUBDIRS(libsysio)
 230 ])
 231
 232 #
 233 # LB_PATH_LUSTREIOKIT
 234 #
 235 # Handle internal/external lustre-iokit
 236 #
 237 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 238 [AC_ARG_WITH([lustre-iokit],
 239         AC_HELP_STRING([--with-lustre-iokit=path],
 240                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 241         [],[
 242                         with_lustre_iokit='yes'
 243         ])
 244 AC_MSG_CHECKING([location of lustre-iokit])
 245 enable_lustre_iokit="$with_lustre_iokit"
 246 case x$with_lustre_iokit in
 247         xyes)
 248                 AC_MSG_RESULT([internal])
 249                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 250                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 251                 ])
 252                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 253                 LUSTREIOKIT="$PWD/lustre-iokit"
 254                 ;;
 255         xno)
 256                 AC_MSG_RESULT([disabled])
 257                 ;;
 258         *)
 259                 AC_MSG_RESULT([$with_lustre_iokit])
 260                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 261                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 262                 ])
 263                 LUSTREIOKIT="$with_lustre_iokit"
 264                 ;;
 265 esac
 266 AC_SUBST(LUSTREIOKIT_SUBDIR)
 267 # We have to configure even if we don't build here for make dist to work
 268 AC_CONFIG_SUBDIRS(lustre-iokit)
 269 ])
 270
 271 # Define no libcfs by default.
 272 AC_DEFUN([LB_LIBCFS_DIR],
 273 [
 274 case x$libcfs_is_module in
 275         xyes)
 276           LIBCFS_INCLUDE_DIR="libcfs/include"
 277           LIBCFS_SUBDIR="libcfs"
 278           ;;
 279         x*)
 280           LIBCFS_INCLUDE_DIR="lnet/include"
 281           LIBCFS_SUBDIR=""
 282           ;;
 283 esac
 284 AC_SUBST(LIBCFS_SUBDIR)
 285 AC_SUBST(LIBCFS_INCLUDE_DIR)
 286 ])
 287
 288 #
 289 # LB_CONFIG_CRAY_XT3
 290 #
 291 # Enable Cray XT3 features
 292 #
 293 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 294 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 295 AC_ARG_ENABLE([cray_xt3],
 296         AC_HELP_STRING([--enable-cray-xt3],
 297                         [enable building of Cray XT3 features]),
 298         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 299 AC_MSG_RESULT([$enable_cray_xt3])
 300 if test x$enable_cray_xt3 != xno; then
 301         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 302 fi
 303 ])
 304
 305 #
 306 # LB_CONFIG_BGL
 307 #
 308 # Enable BGL features
 309 #
 310 AC_DEFUN([LB_CONFIG_BGL],
 311 [AC_MSG_CHECKING([whether to build BGL features])
 312 AC_ARG_ENABLE([bgl],
 313         AC_HELP_STRING([--enable-bgl],
 314                         [enable building of BGL features]),
 315         [enable_bgl='yes'],[enable_bgl='no'])
 316 AC_MSG_RESULT([$enable_bgl])
 317 if test x$enable_bgl != xno; then
 318         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 319         enable_doc='no'
 320         enable_tests='no'
 321         enable_server='no'
 322         enable_liblustre='no'
 323         enable_libreadline='no'
 324 fi
 325 ])
 326
 327 #
 328 # Support for --enable-uoss
 329 #
 330 AC_DEFUN([LB_UOSS],
 331 [AC_MSG_CHECKING([whether to enable uoss])
 332 AC_ARG_ENABLE([uoss],
 333         AC_HELP_STRING([--enable-uoss],
 334                         [enable userspace OSS]),
 335         [enable_uoss='yes'],[enable_uoss='no'])
 336 AC_MSG_RESULT([$enable_uoss])
 337 if test x$enable_uoss = xyes; then
 338         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 339         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 340         enable_uoss='yes'
 341         enable_ulevel_mt='yes'
 342         enable_modules='no'
 343         enable_client='no'
 344         enable_tests='no'
 345         enable_liblustre='no'
 346         with_ldiskfs='no'
 347 fi
 348 AC_SUBST(enable_uoss)
 349 ])
 350
 351 #
 352 # Support for --enable-posix-osd
 353 #
 354 AC_DEFUN([LB_POSIX_OSD],
 355 [AC_MSG_CHECKING([whether to enable posix osd])
 356 AC_ARG_ENABLE([posix-osd],
 357         AC_HELP_STRING([--enable-posix-osd],
 358                         [enable using of posix osd]),
 359         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 360 AC_MSG_RESULT([$enable_posix_osd])
 361 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 362         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 363         posix_osd='yes'
 364 fi
 365 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 366 ])
 367
 368 #
 369 # LB_PATH_DMU
 370 #
 371 AC_DEFUN([LB_PATH_DMU],
 372 [AC_ARG_ENABLE([dmu],
 373         AC_HELP_STRING([--enable-dmu],
 374                        [enable the DMU backend]),
 375         [],[with_dmu='default'])
 376 AC_MSG_CHECKING([whether to enable DMU])
 377 case x$with_dmu in
 378         xyes)
 379                 dmu_osd='yes'
 380                 ;;
 381         xno)
 382                 dmu_osd='no'
 383                 ;;
 384         xdefault)
 385                 if test x$enable_uoss = xyes -a x$posix_osd != xyes; then
 386                         # Enable the DMU if we're configuring a userspace server
 387                         dmu_osd='yes'
 388                 else
 389                         # Enable the DMU by default on the b_hd_kdmu branch
 390                         if test -d $PWD/zfs -a x$linux25$enable_server = xyesyes; then
 391                                 dmu_osd='yes'
 392                         else
 393                                 dmu_osd='no'
 394                         fi
 395                 fi
 396                 ;;
 397         *)
 398                 dmu_osd='yes'
 399                 ;;
 400 esac
 401 AC_MSG_RESULT([$dmu_osd])
 402 if test x$dmu_osd = xyes; then
 403         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 404         if test x$enable_uoss = xyes; then
 405                 # Userspace DMU
 406                 DMU_SRC="$PWD/lustre/zfs-lustre"
 407                 AC_SUBST(DMU_SRC)
 408                 LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 409                         AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 410                 ])
 411                 AC_CONFIG_SUBDIRS(lustre/zfs-lustre)
 412         else
 413                 # Kernel DMU
 414                 SPL_SUBDIR="spl"
 415                 ZFS_SUBDIR="zfs"
 416
 417                 SPL_DIR="$PWD/$SPL_SUBDIR"
 418                 ZFS_DIR="$PWD/$ZFS_SUBDIR"
 419
 420                 LB_CHECK_FILE([$SPL_DIR/module/spl/spl-generic.c],[],[
 421                         AC_MSG_ERROR([A complete SPL tree was not found in $SPL_DIR.])
 422                 ])
 423
 424                 LB_CHECK_FILE([$ZFS_DIR/module/zfs/dmu.c],[],[
 425                         AC_MSG_ERROR([A complete kernel DMU tree was not found in $ZFS_DIR.])
 426                 ])
 427
 428                 AC_CONFIG_SUBDIRS(spl)
 429                 ac_configure_args="$ac_configure_args --with-spl=$SPL_DIR"
 430                 AC_CONFIG_SUBDIRS(zfs)
 431         fi
 432 fi
 433 AC_SUBST(SPL_SUBDIR)
 434 AC_SUBST(ZFS_SUBDIR)
 435 AC_SUBST(SPL_DIR)
 436 AC_SUBST(ZFS_DIR)
 437 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 438 AM_CONDITIONAL(KDMU, test x$dmu_osd$enable_uoss = xyesno)
 439 ])
 440
 441 #
 442 # LB_PATH_SNMP
 443 #
 444 # check for in-tree snmp support
 445 #
 446 AC_DEFUN([LB_PATH_SNMP],
 447 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 448 AC_SUBST(SNMP_DIST_SUBDIR)
 449 AC_SUBST(SNMP_SUBDIR)
 450 ])
 451
 452 #
 453 # LB_CONFIG_MODULES
 454 #
 455 # Build kernel modules?
 456 #
 457 AC_DEFUN([LB_CONFIG_MODULES],
 458 [AC_MSG_CHECKING([whether to build kernel modules])
 459 AC_ARG_ENABLE([modules],
 460         AC_HELP_STRING([--disable-modules],
 461                         [disable building of Lustre kernel modules]),
 462         [],[
 463                 LC_TARGET_SUPPORTED([
 464                         enable_modules='yes'
 465                 ],[
 466                         enable_modules='no'
 467                 ])
 468         ])
 469 AC_MSG_RESULT([$enable_modules ($target_os)])
 470
 471 if test x$enable_modules = xyes ; then
 472         case $target_os in
 473                 linux*)
 474                         LB_PROG_LINUX
 475                         LIBCFS_PROG_LINUX
 476                         LN_PROG_LINUX
 477                         LC_PROG_LINUX
 478                         ;;
 479                 darwin*)
 480                         LB_PROG_DARWIN
 481                         LIBCFS_PROG_DARWIN
 482                         ;;
 483                 *)
 484                         # This is strange - Lustre supports a target we don't
 485                         AC_MSG_ERROR([Modules are not supported on $target_os])
 486                         ;;
 487         esac
 488 fi
 489 ])
 490
 491 #
 492 # LB_CONFIG_UTILS
 493 #
 494 # Build utils?
 495 #
 496 AC_DEFUN([LB_CONFIG_UTILS],
 497 [AC_MSG_CHECKING([whether to build utilities])
 498 AC_ARG_ENABLE([utils],
 499         AC_HELP_STRING([--disable-utils],
 500                         [disable building of Lustre utility programs]),
 501         [],[enable_utils='yes'])
 502 AC_MSG_RESULT([$enable_utils])
 503 if test x$enable_utils = xyes ; then
 504         LB_CONFIG_INIT_SCRIPTS
 505 fi
 506 ])
 507
 508 #
 509 # LB_CONFIG_TESTS
 510 #
 511 # Build tests?
 512 #
 513 AC_DEFUN([LB_CONFIG_TESTS],
 514 [AC_MSG_CHECKING([whether to build Lustre tests])
 515 AC_ARG_ENABLE([tests],
 516         AC_HELP_STRING([--disable-tests],
 517                         [disable building of Lustre tests]),
 518         [],
 519         [
 520                 enable_tests='yes'
 521         ])
 522 AC_MSG_RESULT([$enable_tests])
 523 ])
 524
 525 #
 526 # LB_CONFIG_DIST
 527 #
 528 # Just enough configure so that "make dist" is useful
 529 #
 530 # this simply re-adjusts some defaults, which of course can be overridden
 531 # on the configure line after the --for-dist option
 532 #
 533 AC_DEFUN([LB_CONFIG_DIST],
 534 [AC_MSG_CHECKING([whether to configure just enough for make dist])
 535 AC_ARG_ENABLE([dist],
 536         AC_HELP_STRING([--enable-dist],
 537                         [only configure enough for make dist]),
 538         [enable_dist='yes'],[enable_dist='no'])
 539 AC_MSG_RESULT([$enable_dist])
 540 if test x$enable_dist != xno; then
 541         enable_modules='no'
 542         enable_utils='no'
 543         enable_liblustre='no'
 544         enable_doc='no'
 545         enable_tests='no'
 546 fi
 547 ])
 548
 549 #
 550 # LB_CONFIG_DOCS
 551 #
 552 # Build docs?
 553 #
 554 AC_DEFUN([LB_CONFIG_DOCS],
 555 [AC_MSG_CHECKING([whether to build docs])
 556 AC_ARG_ENABLE(doc,
 557         AC_HELP_STRING([--disable-doc],
 558                         [skip creation of pdf documentation]),
 559         [
 560                 if test x$enable_doc = xyes ; then
 561                     ENABLE_DOC=1
 562                 else
 563                     ENABLE_DOC=0
 564                 fi
 565         ],[
 566                 ENABLE_DOC=0
 567                 enable_doc='no'
 568         ])
 569 AC_MSG_RESULT([$enable_doc])
 570 AC_SUBST(ENABLE_DOC)
 571 ])
 572
 573 #
 574 # LB_CONFIG_INIT_SCRIPTS
 575 #
 576 # our init scripts only work on red hat linux
 577 #
 578 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 579 [ENABLE_INIT_SCRIPTS=0
 580 if test x$enable_utils = xyes ; then
 581         AC_MSG_CHECKING([whether to install init scripts])
 582         # our scripts only work on red hat systems
 583         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 584                 ENABLE_INIT_SCRIPTS=1
 585                 AC_MSG_RESULT([yes])
 586         else
 587                 AC_MSG_RESULT([no])
 588         fi
 589 fi
 590 AC_SUBST(ENABLE_INIT_SCRIPTS)
 591 ])
 592
 593 #
 594 # LB_CONFIG_HEADERS
 595 #
 596 # add -include config.h
 597 #
 598 AC_DEFUN([LB_CONFIG_HEADERS],
 599 [AC_CONFIG_HEADERS([config.h])
 600 CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 601 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 602 AC_SUBST(EXTRA_KCFLAGS)
 603 ])
 604
 605 #
 606 # LB_INCLUDE_RULES
 607 #
 608 # defines for including the toplevel Rules
 609 #
 610 AC_DEFUN([LB_INCLUDE_RULES],
 611 [INCLUDE_RULES="include $PWD/Rules"
 612 AC_SUBST(INCLUDE_RULES)
 613 ])
 614
 615 #
 616 # LB_PATH_DEFAULTS
 617 #
 618 # 'fixup' default paths
 619 #
 620 AC_DEFUN([LB_PATH_DEFAULTS],
 621 [# directories for binaries
 622 AC_PREFIX_DEFAULT([/usr])
 623
 624 sysconfdir='/etc'
 625 AC_SUBST(sysconfdir)
 626
 627 # Directories for documentation and demos.
 628 docdir='${datadir}/doc/$(PACKAGE)'
 629 AC_SUBST(docdir)
 630
 631 LIBCFS_PATH_DEFAULTS
 632 LN_PATH_DEFAULTS
 633 LC_PATH_DEFAULTS
 634
 635 ])
 636
 637 #
 638 # LB_PROG_CC
 639 #
 640 # checks on the C compiler
 641 #
 642 AC_DEFUN([LB_PROG_CC],
 643 [AC_PROG_RANLIB
 644 AC_MSG_CHECKING([for buggy compiler])
 645 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 646 bad_cc() {
 647         AC_MSG_RESULT([buggy compiler found!])
 648         echo
 649         echo "   '$CC_VERSION'"
 650         echo "  has been known to generate bad code, "
 651         echo "  please get an updated compiler."
 652         AC_MSG_ERROR([sorry])
 653 }
 654 case "$CC_VERSION" in
 655         "gcc version 2.95"*)
 656                 bad_cc
 657                 ;;
 658         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 659         # without "sub    $0xc,%esp" to protect the stack from being
 660         # stomped on by interrupts (bug 606)
 661         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 662                 bad_cc
 663                 ;;
 664         # mandrake's similar sub 0xc compiler bug
 665         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 666         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 667                 bad_cc
 668                 ;;
 669         *)
 670                 AC_MSG_RESULT([no known problems])
 671                 ;;
 672 esac
 673
 674 # ---------  unsigned long long sane? -------
 675 AC_CHECK_SIZEOF(unsigned long long, 0)
 676 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 677 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 678 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 679         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 680 fi
 681
 682 if test $target_cpu == "powerpc64"; then
 683         AC_MSG_WARN([set compiler with -m64])
 684         CFLAGS="$CFLAGS -m64"
 685         CC="$CC -m64"
 686 fi
 687
 688 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 689
 690 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 691 AC_SUBST(LLCPPFLAGS)
 692
 693 # Add _GNU_SOURCE for strnlen on linux
 694 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 695 AC_SUBST(LLCFLAGS)
 696
 697 # everyone builds against lnet and lustre
 698 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 699 AC_SUBST(EXTRA_KCFLAGS)
 700 ])
 701
 702 #
 703 # LB_CONTITIONALS
 704 #
 705 # AM_CONDITIONAL instances for everything
 706 # (so that portals/lustre can disable some if needed)
 707 AC_DEFUN([LB_CONDITIONALS],
 708 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 709 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 710 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 711 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 712 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 713 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 714 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 715 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 716 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 717 AM_CONDITIONAL(USES_DPKG, test x$uses_dpkg = "xyes")
 718
 719 # this lets lustre cancel libsysio, per-branch or if liblustre is
 720 # disabled
 721 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 722         if test "x$with_sysio" != xyes ; then
 723                 SYSIO=""
 724                 LIBSYSIO_SUBDIR=""
 725         fi
 726 fi
 727 AC_SUBST(LIBSYSIO_SUBDIR)
 728 AC_SUBST(SYSIO)
 729
 730 LB_LINUX_CONDITIONALS
 731 LB_DARWIN_CONDITIONALS
 732
 733 LIBCFS_CONDITIONALS
 734 LN_CONDITIONALS
 735 LC_CONDITIONALS
 736 ])
 737
 738 #
 739 # LB_CONFIG_FILES
 740 #
 741 # build-specific config files
 742 #
 743 AC_DEFUN([LB_CONFIG_FILES],
 744 [
 745 AC_CONFIG_FILES(
 746 [Makefile
 747 autoMakefile
 748 ]
 749 [Rules:build/Rules.in]
 750 AC_PACKAGE_TARNAME[.spec]
 751 )
 752 ])
 753
 754 #
 755 # LB_CONFIGURE
 756 #
 757 # main configure steps
 758 #
 759 AC_DEFUN([LB_CONFIGURE],
 760 [LB_CANONICAL_SYSTEM
 761
 762 LB_CONFIG_DIST
 763
 764 LB_DOWNSTREAM_RELEASE
 765 LB_USES_DPKG
 766 LB_BUILDID
 767
 768 LB_LIBCFS_DIR
 769
 770 LB_INCLUDE_RULES
 771
 772 LB_CONFIG_CRAY_XT3
 773 LB_CONFIG_BGL
 774 LB_PATH_DEFAULTS
 775
 776 LB_PROG_CC
 777
 778 LB_UOSS
 779 LB_POSIX_OSD
 780
 781 LB_CONFIG_DOCS
 782 LB_CONFIG_UTILS
 783 LB_CONFIG_TESTS
 784 LC_CONFIG_CLIENT_SERVER
 785
 786 # two macros for cmd3
 787 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 788 LN_CONFIG_CDEBUG
 789 LC_QUOTA
 790
 791 LB_CONFIG_MODULES
 792 LN_CONFIG_USERSPACE
 793
 794 LB_PATH_DMU
 795 LB_PATH_LIBSYSIO
 796 LB_PATH_SNMP
 797 LB_PATH_LDISKFS
 798 LB_PATH_LUSTREIOKIT
 799
 800 LB_DEFINE_E2FSPROGS_NAMES
 801
 802 LC_CONFIG_LIBLUSTRE
 803 LIBCFS_CONFIGURE
 804 LN_CONFIGURE
 805
 806 LC_CONFIGURE
 807
 808 if test "$SNMP_DIST_SUBDIR" ; then
 809         LS_CONFIGURE
 810 fi
 811
 812
 813 LB_CONDITIONALS
 814 LB_CONFIG_HEADERS
 815
 816 LIBCFS_CONFIG_FILES
 817 LB_CONFIG_FILES
 818 LN_CONFIG_FILES
 819 LC_CONFIG_FILES
 820 if test "$SNMP_DIST_SUBDIR" ; then
 821         LS_CONFIG_FILES
 822 fi
 823
 824 AC_SUBST(ac_configure_args)
 825
 826 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 827 AC_SUBST(MOSTLYCLEANFILES)
 828
 829 AC_OUTPUT
 830
 831 cat <<_ACEOF
 832
 833 CC:            $CC
 834 LD:            $LD
 835 CPPFLAGS:      $CPPFLAGS
 836 LLCPPFLAGS:    $LLCPPFLAGS
 837 CFLAGS:        $CFLAGS
 838 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 839 LLCFLAGS:      $LLCFLAGS
 840
 841 Type 'make' to build Lustre.
 842 _ACEOF
 843 ])