build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_DOWNSTREAM_RELEASE
  33 #
  34 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  35 [AC_ARG_WITH([downstream-release],
  36         AC_HELP_STRING([--with-downstream-release=string],
  37                        [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  38         [DOWNSTREAM_RELEASE=$with_downstream_release],
  39         [
  40         # if not specified, see if it's in the META file
  41         if test -f META; then
  42                 DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)
  43         fi
  44         ])
  45 AC_SUBST(DOWNSTREAM_RELEASE)
  46 ])
  47
  48 #
  49 # LB_BUILDID
  50 #
  51 # Check if the source is a GA release and if not, set a "BUILDID"
  52 #
  53 # Currently there are at least two ways/modes of/for doing this.  One
  54 # is if we are in a valid git repository, the other is if we are in a
  55 # non-git source tree of some form.  Building the latter from the former
  56 # will be handled here.
  57 AC_DEFUN([LB_BUILDID],
  58 [
  59 AC_MSG_CHECKING([for buildid])
  60 BUILDID=""
  61 if git branch >/dev/null 2>&1; then
  62         ffw=0
  63         hash=""
  64         ver=$(git describe --match [[0-9v]]\* --tags)
  65         if [[[ $ver = *-*-* ]]]; then
  66                 hash=${ver##*-}
  67                 ffw=${ver#*-}
  68                 ffw=${ffw%-*}
  69                 ver=${ver%%-*}
  70         fi
  71         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  72         # here but the portability of the regex on the right is dismal
  73         # (thanx suse)
  74         if echo "$ver" | egrep -q "^v([0-9]+_)+([0-9]+|RC[0-9]+)$"; then
  75                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  76                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  77         fi
  78
  79         # a "lustre fix" value of .0 should be truncated
  80         if [[[ $ver = *.*.*.0 ]]]; then
  81                 ver=${ver%.0}
  82         fi
  83         # ditto for a "lustre fix" value of _0
  84         if [[[ $ver = v*_*_*_0 ]]]; then
  85                 ver=${ver%_0}
  86         fi
  87
  88
  89         # only do this test for lustre (not ldiskfs)
  90         if test "$PACKAGE" = "lustre" -a "$ver" != "$VERSION"; then
  91                 AC_MSG_ERROR([most recent tag found: $ver does not match current version $VERSION.])
  92         fi
  93
  94         if test "$ffw" != "0"; then
  95                 BUILDID="$hash"
  96                 msg="$BUILDID (ahead by $ffw commits)"
  97                 AC_MSG_RESULT([$msg])
  98         else
  99                 AC_MSG_RESULT([none... congratulations, you must be on a tag])
 100         fi
 101 elif test -f META; then
 102         BUILDID=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
 103         msg="$BUILDID (from META file)"
 104         AC_MSG_RESULT([$msg])
 105 else
 106         AC_MSG_WARN([FIXME: I don't know how to deal with source trees outside of git that don't have a META file.  Not setting a buildid.])
 107 fi
 108 AC_SUBST(BUILDID)
 109 ])
 110
 111 #
 112 # LB_CHECK_FILE
 113 #
 114 # Check for file existance even when cross compiling
 115 #
 116 AC_DEFUN([LB_CHECK_FILE],
 117 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
 118 AC_CACHE_CHECK([for $1], lb_File,
 119 [if test -r "$1"; then
 120   AS_VAR_SET(lb_File, yes)
 121 else
 122   AS_VAR_SET(lb_File, no)
 123 fi])
 124 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
 125 AS_VAR_POPDEF([lb_File])dnl
 126 ])# LB_CHECK_FILE
 127
 128
 129 #
 130 # LB_ARG_LIBS_INCLUDES
 131 #
 132 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 133 # a single magical macro
 134 #
 135 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
 136 [lb_pathvar="m4_bpatsubst([$2], -, _)"
 137 AC_MSG_CHECKING([for $1])
 138 AC_ARG_WITH([$2],
 139         AC_HELP_STRING([--with-$2=path],
 140                 [path to $1]),
 141         [],[withval=$4])
 142
 143 if test x$withval = xyes ; then
 144         eval "$lb_pathvar='$3'"
 145 else
 146         eval "$lb_pathvar='$withval'"
 147 fi
 148 AC_MSG_RESULT([${!lb_pathvar:-no}])
 149
 150 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
 151         AC_MSG_CHECKING([for $1 includes])
 152         AC_ARG_WITH([$2-includes],
 153                 AC_HELP_STRING([--with-$2-includes=path],
 154                         [path to $1 includes]),
 155                 [],[withval='yes'])
 156
 157         lb_includevar="${lb_pathvar}_includes"
 158         if test x$withval = xyes ; then
 159                 eval "${lb_includevar}='${!lb_pathvar}/include'"
 160         else
 161                 eval "${lb_includevar}='$withval'"
 162         fi
 163         AC_MSG_RESULT([${!lb_includevar}])
 164
 165         AC_MSG_CHECKING([for $1 libs])
 166         AC_ARG_WITH([$2-libs],
 167                 AC_HELP_STRING([--with-$2-libs=path],
 168                         [path to $1 libs]),
 169                 [],[withval='yes'])
 170
 171         lb_libvar="${lb_pathvar}_libs"
 172         if test x$withval = xyes ; then
 173                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 174         else
 175                 eval "${lb_libvar}='$withval'"
 176         fi
 177         AC_MSG_RESULT([${!lb_libvar}])
 178 fi
 179 ])
 180 ])
 181
 182 #
 183 # LB_PATH_LIBSYSIO
 184 #
 185 # Handle internal/external libsysio
 186 #
 187 AC_DEFUN([LB_PATH_LIBSYSIO],
 188 [AC_ARG_WITH([sysio],
 189         AC_HELP_STRING([--with-sysio=path],
 190                         [set path to libsysio source (default is included libsysio)]),
 191         [],[
 192                 case $lb_target_os in
 193                         linux)
 194                                 with_sysio='yes'
 195                                 ;;
 196                         *)
 197                                 with_sysio='no'
 198                                 ;;
 199                 esac
 200         ])
 201 AC_MSG_CHECKING([location of libsysio])
 202 enable_sysio="$with_sysio"
 203 case x$with_sysio in
 204         xyes)
 205                 AC_MSG_RESULT([internal])
 206                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 207                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 208                 ])
 209                 LIBSYSIO_SUBDIR="libsysio"
 210                 SYSIO="$PWD/libsysio"
 211                 ;;
 212         xno)
 213                 AC_MSG_RESULT([disabled])
 214                 ;;
 215         *)
 216                 AC_MSG_RESULT([$with_sysio])
 217                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 218                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 219                 ])
 220                 SYSIO=$with_sysio
 221                 with_sysio="yes"
 222                 ;;
 223 esac
 224
 225 # We have to configure even if we don't build here for make dist to work
 226 AC_CONFIG_SUBDIRS(libsysio)
 227 ])
 228
 229 #
 230 # LB_PATH_LUSTREIOKIT
 231 #
 232 # Handle internal/external lustre-iokit
 233 #
 234 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 235 [AC_ARG_WITH([lustre-iokit],
 236         AC_HELP_STRING([--with-lustre-iokit=path],
 237                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 238         [],[
 239                         with_lustre_iokit='yes'
 240         ])
 241 AC_MSG_CHECKING([location of lustre-iokit])
 242 enable_lustre_iokit="$with_lustre_iokit"
 243 case x$with_lustre_iokit in
 244         xyes)
 245                 AC_MSG_RESULT([internal])
 246                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 247                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 248                 ])
 249                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 250                 LUSTREIOKIT="$PWD/lustre-iokit"
 251                 ;;
 252         xno)
 253                 AC_MSG_RESULT([disabled])
 254                 ;;
 255         *)
 256                 AC_MSG_RESULT([$with_lustre_iokit])
 257                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 258                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 259                 ])
 260                 LUSTREIOKIT="$with_lustre_iokit"
 261                 with_lustre_iokit="yes"
 262                 ;;
 263 esac
 264 AC_SUBST(LUSTREIOKIT_SUBDIR)
 265 # We have to configure even if we don't build here for make dist to work
 266 AC_CONFIG_SUBDIRS(lustre-iokit)
 267 ])
 268
 269 #
 270 # LB_PATH_LDISKFS
 271 #
 272 # Handle internal/external ldiskfs
 273 #
 274 AC_DEFUN([LB_PATH_LDISKFS],
 275 [AC_ARG_WITH([ldiskfs],
 276         AC_HELP_STRING([--with-ldiskfs=path],
 277                         [set path to ldiskfs source (default is included ldiskfs)]),
 278         [],[
 279                 if test x$linux25$enable_server = xyesyes ; then
 280                         with_ldiskfs=yes
 281                 else
 282                         with_ldiskfs=no
 283                 fi
 284         ])
 285 AC_ARG_WITH([ldiskfs-inkernel],
 286         AC_HELP_STRING([--with-ldiskfs-inkernel],
 287                         [use ldiskfs built in to the kernel]),
 288         [with_ldiskfs=inkernel], [])
 289 AC_MSG_CHECKING([location of ldiskfs])
 290 case x$with_ldiskfs in
 291         xyes)
 292                 AC_MSG_RESULT([internal])
 293                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 294                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 295                 ])
 296                 LDISKFS_SUBDIR="ldiskfs"
 297                 LDISKFS_DIR="$PWD/ldiskfs"
 298                 ;;
 299         xno)
 300                 AC_MSG_RESULT([disabled])
 301                 ;;
 302         xinkernel)
 303                 AC_MSG_RESULT([inkernel])
 304                 LB_CHECK_FILE([$LINUX/fs/ldiskfs/inode.c],[],[
 305                         AC_MSG_ERROR([ldiskfs was not found in $LINUX/fs/ldiskfs/inode.c])
 306                 ])
 307                 ;;
 308         *)
 309                 AC_MSG_RESULT([$with_ldiskfs])
 310                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/inode.c],[],[
 311                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 312                 ])
 313                 LDISKFS_DIR=$with_ldiskfs
 314                 ;;
 315 esac
 316 AC_SUBST(LDISKFS_DIR)
 317 AC_SUBST(LDISKFS_SUBDIR)
 318 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 319 AM_CONDITIONAL(LDISKFS_IN_KERNEL, test x$with_ldiskfs = xinkernel)
 320
 321 if test x$enable_ext4 = xyes ; then
 322         AC_DEFINE(HAVE_EXT4_LDISKFS, 1, [build ext4 based ldiskfs])
 323 fi
 324
 325 # We have to configure even if we don't build here for make dist to work
 326 AC_CONFIG_SUBDIRS(ldiskfs)
 327 ])
 328
 329 AC_DEFUN([LC_KERNEL_WITH_EXT4],
 330 [if test -f $LINUX/fs/ext4/ext4.h ; then
 331 $1
 332 else
 333 $2
 334 fi
 335 ])
 336
 337 #
 338 # LB_HAVE_EXT4_ENABLED
 339 #
 340 AC_DEFUN([LB_HAVE_EXT4_ENABLED],
 341 [
 342 if test x$RHEL_KERNEL = xyes; then
 343         AC_ARG_ENABLE([ext4],
 344                  AC_HELP_STRING([--enable-ext4],
 345                                 [enable building of ldiskfs based on ext4]),
 346                 [],
 347                 [
 348                         if test x$ldiskfs_is_ext4 = xyes; then
 349                                 enable_ext4=yes
 350                         else
 351                                 enable_ext4=no
 352                         fi
 353                 ])
 354 else
 355         case $LINUXRELEASE in
 356         # ext4 was in 2.6.22-2.6.26 but not stable enough to use
 357         2.6.2[[0-9]]*) enable_ext4='no' ;;
 358         *)  LC_KERNEL_WITH_EXT4([enable_ext4='yes'],
 359                                 [enable_ext4='no']) ;;
 360         esac
 361 fi
 362 if test x$enable_ext4 = xyes; then
 363          ac_configure_args="$ac_configure_args --enable-ext4"
 364 fi
 365 AC_MSG_CHECKING([whether to build ldiskfs based on ext4])
 366 AC_MSG_RESULT([$enable_ext4])
 367 ])
 368
 369 # Define no libcfs by default.
 370 AC_DEFUN([LB_LIBCFS_DIR],
 371 [
 372 case x$libcfs_is_module in
 373         xyes)
 374           LIBCFS_INCLUDE_DIR="libcfs/include"
 375           LIBCFS_SUBDIR="libcfs"
 376           ;;
 377         x*)
 378           LIBCFS_INCLUDE_DIR="lnet/include"
 379           LIBCFS_SUBDIR=""
 380           ;;
 381 esac
 382 AC_SUBST(LIBCFS_SUBDIR)
 383 AC_SUBST(LIBCFS_INCLUDE_DIR)
 384 ])
 385
 386 #
 387 # LB_DEFINE_LDISKFS_OPTIONS
 388 #
 389 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 390 # and lvfs (which includes ldiskfs headers.)
 391 #
 392 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 393 [
 394         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 395         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 396         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 397         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 398         AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 399         AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1, [enable extented attributes for ldiskfs])
 400         AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1, [enable fs security for ldiskfs])
 401 ])
 402
 403 #
 404 # LB_DEFINE_E2FSPROGS_NAMES
 405 #
 406 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 407 #
 408 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 409 [AC_ARG_WITH([ldiskfsprogs],
 410         AC_HELP_STRING([--with-ldiskfsprogs],
 411                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 412         [],[withval='no'])
 413
 414 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 415 if test x$withval = xyes ; then
 416         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 417         E2FSPROGS="ldiskfsprogs"
 418         MKE2FS="mkfs.ldiskfs"
 419         DEBUGFS="debugfs.ldiskfs"
 420         TUNE2FS="tunefs.ldiskfs"
 421         E2LABEL="label.ldiskfs"
 422         DUMPE2FS="dumpfs.ldiskfs"
 423         E2FSCK="fsck.ldiskfs"
 424         AC_MSG_RESULT([enabled])
 425 else
 426         E2FSPROGS="e2fsprogs"
 427         MKE2FS="mke2fs"
 428         DEBUGFS="debugfs"
 429         TUNE2FS="tune2fs"
 430         E2LABEL="e2label"
 431         DUMPE2FS="dumpe2fs"
 432         E2FSCK="e2fsck"
 433         AC_MSG_RESULT([disabled])
 434 fi
 435         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 436         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 437         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 438         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 439         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 440         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 441         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 442 ])
 443
 444 #
 445 # LB_CONFIG_CRAY_XT3
 446 #
 447 # Enable Cray XT3 features
 448 #
 449 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 450 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 451 AC_ARG_ENABLE([cray_xt3],
 452         AC_HELP_STRING([--enable-cray-xt3],
 453                         [enable building of Cray XT3 features]),
 454         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 455 AC_MSG_RESULT([$enable_cray_xt3])
 456 if test x$enable_cray_xt3 != xno; then
 457         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 458 fi
 459 ])
 460
 461 #
 462 # LB_CONFIG_BGL
 463 #
 464 # Enable BGL features
 465 #
 466 AC_DEFUN([LB_CONFIG_BGL],
 467 [AC_MSG_CHECKING([whether to build BGL features])
 468 AC_ARG_ENABLE([bgl],
 469         AC_HELP_STRING([--enable-bgl],
 470                         [enable building of BGL features]),
 471         [enable_bgl='yes'],[enable_bgl='no'])
 472 AC_MSG_RESULT([$enable_bgl])
 473 if test x$enable_bgl != xno; then
 474         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 475         enable_doc='no'
 476         enable_tests='no'
 477         enable_server='no'
 478         enable_liblustre='no'
 479         enable_libreadline='no'
 480 fi
 481 ])
 482
 483 #
 484 # Support for --enable-uoss
 485 #
 486 AC_DEFUN([LB_UOSS],
 487 [AC_MSG_CHECKING([whether to enable uoss])
 488 AC_ARG_ENABLE([uoss],
 489         AC_HELP_STRING([--enable-uoss],
 490                         [enable userspace OSS]),
 491         [enable_uoss='yes'],[enable_uoss='no'])
 492 AC_MSG_RESULT([$enable_uoss])
 493 if test x$enable_uoss = xyes; then
 494         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 495         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 496         enable_uoss='yes'
 497         enable_ulevel_mt='yes'
 498         enable_modules='no'
 499         enable_client='no'
 500         enable_tests='no'
 501         enable_liblustre='no'
 502         with_ldiskfs='no'
 503 fi
 504 AC_SUBST(enable_uoss)
 505 ])
 506
 507 #
 508 # Support for --enable-posix-osd
 509 #
 510 AC_DEFUN([LB_POSIX_OSD],
 511 [AC_MSG_CHECKING([whether to enable posix osd])
 512 AC_ARG_ENABLE([posix-osd],
 513         AC_HELP_STRING([--enable-posix-osd],
 514                         [enable using of posix osd]),
 515         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 516 AC_MSG_RESULT([$enable_posix_osd])
 517 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 518         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 519         posix_osd='yes'
 520 fi
 521 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 522 ])
 523
 524 #
 525 # LB_PATH_DMU
 526 #
 527 AC_DEFUN([LB_PATH_DMU],
 528 [AC_ARG_ENABLE([dmu],
 529         AC_HELP_STRING([--enable-dmu],
 530                        [enable the DMU backend]),
 531         [],[with_dmu='default'])
 532 AC_MSG_CHECKING([whether to enable DMU])
 533 case x$with_dmu in
 534         xyes)
 535                 dmu_osd='yes'
 536                 ;;
 537         xno)
 538                 dmu_osd='no'
 539                 ;;
 540         xdefault)
 541                 if test x$enable_uoss = xyes -a x$posix_osd != xyes; then
 542                         # Enable the DMU if we're configuring a userspace server
 543                         dmu_osd='yes'
 544                 else
 545                         # Enable the DMU by default on the b_hd_kdmu branch
 546                         if test -d $PWD/zfs -a x$linux25$enable_server = xyesyes; then
 547                                 dmu_osd='yes'
 548                         else
 549                                 dmu_osd='no'
 550                         fi
 551                 fi
 552                 ;;
 553         *)
 554                 dmu_osd='yes'
 555                 ;;
 556 esac
 557 AC_MSG_RESULT([$dmu_osd])
 558 if test x$dmu_osd = xyes; then
 559         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 560         if test x$enable_uoss = xyes; then
 561                 # Userspace DMU
 562                 DMU_SRC="$PWD/lustre/zfs-lustre"
 563                 AC_SUBST(DMU_SRC)
 564                 LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 565                         AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 566                 ])
 567                 AC_CONFIG_SUBDIRS(lustre/zfs-lustre)
 568         else
 569                 # Kernel DMU
 570                 SPL_SUBDIR="spl"
 571                 ZFS_SUBDIR="zfs"
 572
 573                 SPL_DIR="$PWD/$SPL_SUBDIR"
 574                 ZFS_DIR="$PWD/$ZFS_SUBDIR"
 575
 576                 LB_CHECK_FILE([$SPL_DIR/module/spl/spl-generic.c],[],[
 577                         AC_MSG_ERROR([A complete SPL tree was not found in $SPL_DIR.])
 578                 ])
 579
 580                 LB_CHECK_FILE([$ZFS_DIR/module/zfs/dmu.c],[],[
 581                         AC_MSG_ERROR([A complete kernel DMU tree was not found in $ZFS_DIR.])
 582                 ])
 583
 584                 AC_CONFIG_SUBDIRS(spl)
 585                 ac_configure_args="$ac_configure_args --with-spl=$SPL_DIR"
 586                 AC_CONFIG_SUBDIRS(zfs)
 587         fi
 588 fi
 589 AC_SUBST(SPL_SUBDIR)
 590 AC_SUBST(ZFS_SUBDIR)
 591 AC_SUBST(SPL_DIR)
 592 AC_SUBST(ZFS_DIR)
 593 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 594 AM_CONDITIONAL(KDMU, test x$dmu_osd$enable_uoss = xyesno)
 595 ])
 596
 597 #
 598 # LB_PATH_SNMP
 599 #
 600 # check for in-tree snmp support
 601 #
 602 AC_DEFUN([LB_PATH_SNMP],
 603 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 604 AC_SUBST(SNMP_DIST_SUBDIR)
 605 AC_SUBST(SNMP_SUBDIR)
 606 ])
 607
 608 #
 609 # LB_CONFIG_MODULES
 610 #
 611 # Build kernel modules?
 612 #
 613 AC_DEFUN([LB_CONFIG_MODULES],
 614 [AC_MSG_CHECKING([whether to build kernel modules])
 615 AC_ARG_ENABLE([modules],
 616         AC_HELP_STRING([--disable-modules],
 617                         [disable building of Lustre kernel modules]),
 618         [],[
 619                 LC_TARGET_SUPPORTED([
 620                         enable_modules='yes'
 621                 ],[
 622                         enable_modules='no'
 623                 ])
 624         ])
 625 AC_MSG_RESULT([$enable_modules ($target_os)])
 626
 627 if test x$enable_modules = xyes ; then
 628         case $target_os in
 629                 linux*)
 630                         LB_PROG_LINUX
 631                         LIBCFS_PROG_LINUX
 632                         LN_PROG_LINUX
 633                         LC_PROG_LINUX
 634                         ;;
 635                 darwin*)
 636                         LB_PROG_DARWIN
 637                         LIBCFS_PROG_DARWIN
 638                         ;;
 639                 *)
 640                         # This is strange - Lustre supports a target we don't
 641                         AC_MSG_ERROR([Modules are not supported on $target_os])
 642                         ;;
 643         esac
 644 fi
 645 ])
 646
 647 #
 648 # LB_CONFIG_UTILS
 649 #
 650 # Build utils?
 651 #
 652 AC_DEFUN([LB_CONFIG_UTILS],
 653 [AC_MSG_CHECKING([whether to build utilities])
 654 AC_ARG_ENABLE([utils],
 655         AC_HELP_STRING([--disable-utils],
 656                         [disable building of Lustre utility programs]),
 657         [],[enable_utils='yes'])
 658 AC_MSG_RESULT([$enable_utils])
 659 if test x$enable_utils = xyes ; then
 660         LB_CONFIG_INIT_SCRIPTS
 661 fi
 662 ])
 663
 664 #
 665 # LB_CONFIG_TESTS
 666 #
 667 # Build tests?
 668 #
 669 AC_DEFUN([LB_CONFIG_TESTS],
 670 [AC_MSG_CHECKING([whether to build Lustre tests])
 671 AC_ARG_ENABLE([tests],
 672         AC_HELP_STRING([--disable-tests],
 673                         [disable building of Lustre tests]),
 674         [],
 675         [
 676                 enable_tests='yes'
 677         ])
 678 AC_MSG_RESULT([$enable_tests])
 679 ])
 680
 681 #
 682 # LB_CONFIG_DIST
 683 #
 684 # Just enough configure so that "make dist" is useful
 685 #
 686 # this simply re-adjusts some defaults, which of course can be overridden
 687 # on the configure line after the --for-dist option
 688 #
 689 AC_DEFUN([LB_CONFIG_DIST],
 690 [AC_MSG_CHECKING([whether to configure just enough for make dist])
 691 AC_ARG_ENABLE([dist],
 692         AC_HELP_STRING([--enable-dist],
 693                         [only configure enough for make dist]),
 694         [enable_dist='yes'],[enable_dist='no'])
 695 AC_MSG_RESULT([$enable_dist])
 696 if test x$enable_dist != xno; then
 697         enable_modules='no'
 698         enable_utils='no'
 699         enable_liblustre='no'
 700         enable_doc='no'
 701         enable_tests='no'
 702 fi
 703 ])
 704
 705 #
 706 # LB_CONFIG_DOCS
 707 #
 708 # Build docs?
 709 #
 710 AC_DEFUN([LB_CONFIG_DOCS],
 711 [AC_MSG_CHECKING([whether to build docs])
 712 AC_ARG_ENABLE(doc,
 713         AC_HELP_STRING([--disable-doc],
 714                         [skip creation of pdf documentation]),
 715         [
 716                 if test x$enable_doc = xyes ; then
 717                     ENABLE_DOC=1
 718                 else
 719                     ENABLE_DOC=0
 720                 fi
 721         ],[
 722                 ENABLE_DOC=0
 723                 enable_doc='no'
 724         ])
 725 AC_MSG_RESULT([$enable_doc])
 726 AC_SUBST(ENABLE_DOC)
 727 ])
 728
 729 #
 730 # LB_CONFIG_INIT_SCRIPTS
 731 #
 732 # our init scripts only work on red hat linux
 733 #
 734 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 735 [ENABLE_INIT_SCRIPTS=0
 736 if test x$enable_utils = xyes ; then
 737         AC_MSG_CHECKING([whether to install init scripts])
 738         # our scripts only work on red hat systems
 739         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 740                 ENABLE_INIT_SCRIPTS=1
 741                 AC_MSG_RESULT([yes])
 742         else
 743                 AC_MSG_RESULT([no])
 744         fi
 745 fi
 746 AC_SUBST(ENABLE_INIT_SCRIPTS)
 747 ])
 748
 749 #
 750 # LB_CONFIG_HEADERS
 751 #
 752 # add -include config.h
 753 #
 754 AC_DEFUN([LB_CONFIG_HEADERS],
 755 [AC_CONFIG_HEADERS([config.h])
 756 CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 757 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 758 AC_SUBST(EXTRA_KCFLAGS)
 759 ])
 760
 761 #
 762 # LB_INCLUDE_RULES
 763 #
 764 # defines for including the toplevel Rules
 765 #
 766 AC_DEFUN([LB_INCLUDE_RULES],
 767 [INCLUDE_RULES="include $PWD/Rules"
 768 AC_SUBST(INCLUDE_RULES)
 769 ])
 770
 771 #
 772 # LB_PATH_DEFAULTS
 773 #
 774 # 'fixup' default paths
 775 #
 776 AC_DEFUN([LB_PATH_DEFAULTS],
 777 [# directories for binaries
 778 AC_PREFIX_DEFAULT([/usr])
 779
 780 sysconfdir='/etc'
 781 AC_SUBST(sysconfdir)
 782
 783 # Directories for documentation and demos.
 784 docdir='${datadir}/doc/$(PACKAGE)'
 785 AC_SUBST(docdir)
 786
 787 LIBCFS_PATH_DEFAULTS
 788 LN_PATH_DEFAULTS
 789 LC_PATH_DEFAULTS
 790
 791 ])
 792
 793 #
 794 # LB_PROG_CC
 795 #
 796 # checks on the C compiler
 797 #
 798 AC_DEFUN([LB_PROG_CC],
 799 [AC_PROG_RANLIB
 800 AC_MSG_CHECKING([for buggy compiler])
 801 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 802 bad_cc() {
 803         AC_MSG_RESULT([buggy compiler found!])
 804         echo
 805         echo "   '$CC_VERSION'"
 806         echo "  has been known to generate bad code, "
 807         echo "  please get an updated compiler."
 808         AC_MSG_ERROR([sorry])
 809 }
 810 case "$CC_VERSION" in
 811         "gcc version 2.95"*)
 812                 bad_cc
 813                 ;;
 814         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 815         # without "sub    $0xc,%esp" to protect the stack from being
 816         # stomped on by interrupts (bug 606)
 817         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 818                 bad_cc
 819                 ;;
 820         # mandrake's similar sub 0xc compiler bug
 821         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 822         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 823                 bad_cc
 824                 ;;
 825         *)
 826                 AC_MSG_RESULT([no known problems])
 827                 ;;
 828 esac
 829
 830 # ---------  unsigned long long sane? -------
 831 AC_CHECK_SIZEOF(unsigned long long, 0)
 832 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 833 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 834 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 835         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 836 fi
 837
 838 if test $target_cpu == "powerpc64"; then
 839         AC_MSG_WARN([set compiler with -m64])
 840         CFLAGS="$CFLAGS -m64"
 841         CC="$CC -m64"
 842 fi
 843
 844 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 845
 846 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 847 AC_SUBST(LLCPPFLAGS)
 848
 849 # Add _GNU_SOURCE for strnlen on linux
 850 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 851 AC_SUBST(LLCFLAGS)
 852
 853 # everyone builds against lnet and lustre
 854 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 855 AC_SUBST(EXTRA_KCFLAGS)
 856 ])
 857
 858 #
 859 # LB_CONTITIONALS
 860 #
 861 # AM_CONDITIONAL instances for everything
 862 # (so that portals/lustre can disable some if needed)
 863 AC_DEFUN([LB_CONDITIONALS],
 864 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 865 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 866 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 867 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 868 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 869 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 870 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 871 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 872 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 873
 874 # this lets lustre cancel libsysio, per-branch or if liblustre is
 875 # disabled
 876 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 877         if test "x$with_sysio" != xyes ; then
 878                 SYSIO=""
 879                 LIBSYSIO_SUBDIR=""
 880         fi
 881 fi
 882 AC_SUBST(LIBSYSIO_SUBDIR)
 883 AC_SUBST(SYSIO)
 884
 885 LB_LINUX_CONDITIONALS
 886 LB_DARWIN_CONDITIONALS
 887
 888 LIBCFS_CONDITIONALS
 889 LN_CONDITIONALS
 890 LC_CONDITIONALS
 891 ])
 892
 893 #
 894 # LB_CONFIG_FILES
 895 #
 896 # build-specific config files
 897 #
 898 AC_DEFUN([LB_CONFIG_FILES],
 899 [
 900 AC_CONFIG_FILES(
 901 [Makefile
 902 autoMakefile
 903 ]
 904 [Rules:build/Rules.in]
 905 AC_PACKAGE_TARNAME[.spec]
 906 )
 907 ])
 908
 909 #
 910 # LB_CONFIGURE
 911 #
 912 # main configure steps
 913 #
 914 AC_DEFUN([LB_CONFIGURE],
 915 [LB_CANONICAL_SYSTEM
 916
 917 LB_CONFIG_DIST
 918
 919 LB_DOWNSTREAM_RELEASE
 920 LB_BUILDID
 921
 922 LB_LIBCFS_DIR
 923
 924 LB_INCLUDE_RULES
 925
 926 LB_CONFIG_CRAY_XT3
 927 LB_CONFIG_BGL
 928 LB_PATH_DEFAULTS
 929
 930 LB_PROG_CC
 931
 932 LB_UOSS
 933 LB_POSIX_OSD
 934
 935 LB_CONFIG_DOCS
 936 LB_CONFIG_UTILS
 937 LB_CONFIG_TESTS
 938 LC_CONFIG_CLIENT_SERVER
 939
 940 # two macros for cmd3
 941 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 942 LN_CONFIG_CDEBUG
 943 LC_QUOTA
 944
 945 LB_CONFIG_MODULES
 946 LN_CONFIG_USERSPACE
 947 LB_HAVE_EXT4_ENABLED
 948
 949 LB_PATH_DMU
 950 LB_PATH_LIBSYSIO
 951 LB_PATH_SNMP
 952 LB_PATH_LDISKFS
 953 LB_PATH_LUSTREIOKIT
 954
 955 LB_DEFINE_E2FSPROGS_NAMES
 956
 957 LC_CONFIG_LIBLUSTRE
 958 LIBCFS_CONFIGURE
 959 LN_CONFIGURE
 960
 961 LC_CONFIGURE
 962
 963 if test "$SNMP_DIST_SUBDIR" ; then
 964         LS_CONFIGURE
 965 fi
 966
 967
 968 LB_CONDITIONALS
 969 LB_CONFIG_HEADERS
 970
 971 LIBCFS_CONFIG_FILES
 972 LB_CONFIG_FILES
 973 LN_CONFIG_FILES
 974 LC_CONFIG_FILES
 975 if test "$SNMP_DIST_SUBDIR" ; then
 976         LS_CONFIG_FILES
 977 fi
 978
 979 AC_SUBST(ac_configure_args)
 980
 981 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 982 AC_SUBST(MOSTLYCLEANFILES)
 983
 984 AC_OUTPUT
 985
 986 cat <<_ACEOF
 987
 988 CC:            $CC
 989 LD:            $LD
 990 CPPFLAGS:      $CPPFLAGS
 991 LLCPPFLAGS:    $LLCPPFLAGS
 992 CFLAGS:        $CFLAGS
 993 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 994 LLCFLAGS:      $LLCFLAGS
 995
 996 Type 'make' to build Lustre.
 997 _ACEOF
 998 ])