build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25 esac
  26 AC_SUBST(lb_target_os)
  27 ])
  28
  29 #
  30 # LB_CHECK_FILE
  31 #
  32 # Check for file existance even when cross compiling
  33 #
  34 AC_DEFUN([LB_CHECK_FILE],
  35 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  36 AC_CACHE_CHECK([for $1], lb_File,
  37 [if test -r "$1"; then
  38   AS_VAR_SET(lb_File, yes)
  39 else
  40   AS_VAR_SET(lb_File, no)
  41 fi])
  42 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  43 AS_VAR_POPDEF([lb_File])dnl
  44 ])# LB_CHECK_FILE
  45
  46 #
  47 # LB_CHECK_FILES
  48 #
  49 # LB_CHECK_FILE over multiple files
  50 #
  51 AC_DEFUN([LB_CHECK_FILES],
  52 [AC_FOREACH([AC_FILE_NAME], [$1],
  53   [LB_CHECK_FILE(AC_FILE_NAME,
  54                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  55                                     [Define to 1 if you have the
  56                                      file `]AC_File['.])
  57 $2],
  58                  [$3])])])
  59
  60 #
  61 # LB_ARG_LIBS_INCLUDES
  62 #
  63 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  64 # a single magical macro
  65 #
  66 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  67 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  68 AC_MSG_CHECKING([for $1])
  69 AC_ARG_WITH([$2],
  70         AC_HELP_STRING([--with-$2=path],
  71                 [path to $1]),
  72         [],[withval=$4])
  73
  74 if test x$withval = xyes ; then
  75         eval "$lb_pathvar='$3'"
  76 else
  77         eval "$lb_pathvar='$withval'"
  78 fi
  79 AC_MSG_RESULT([${!lb_pathvar:-no}])
  80
  81 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  82         AC_MSG_CHECKING([for $1 includes])
  83         AC_ARG_WITH([$2-includes],
  84                 AC_HELP_STRING([--with-$2-includes=path],
  85                         [path to $1 includes]),
  86                 [],[withval='yes'])
  87
  88         lb_includevar="${lb_pathvar}_includes"
  89         if test x$withval = xyes ; then
  90                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  91         else
  92                 eval "${lb_includevar}='$withval'"
  93         fi
  94         AC_MSG_RESULT([${!lb_includevar}])
  95
  96         AC_MSG_CHECKING([for $1 libs])
  97         AC_ARG_WITH([$2-libs],
  98                 AC_HELP_STRING([--with-$2-libs=path],
  99                         [path to $1 libs]),
 100                 [],[withval='yes'])
 101
 102         lb_libvar="${lb_pathvar}_libs"
 103         if test x$withval = xyes ; then
 104                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 105         else
 106                 eval "${lb_libvar}='$withval'"
 107         fi
 108         AC_MSG_RESULT([${!lb_libvar}])
 109 fi
 110 ])
 111 ])
 112
 113 #
 114 # LB_PATH_LIBSYSIO
 115 #
 116 # Handle internal/external libsysio
 117 #
 118 AC_DEFUN([LB_PATH_LIBSYSIO],
 119 [AC_ARG_WITH([sysio],
 120         AC_HELP_STRING([--with-sysio=path],
 121                         [set path to libsysio source (default is included libsysio)]),
 122         [],[
 123                 case $lb_target_os in
 124                         linux)
 125                                 with_sysio='yes'
 126                                 ;;
 127                         *)
 128                                 with_sysio='no'
 129                                 ;;
 130                 esac
 131         ])
 132 AC_MSG_CHECKING([location of libsysio])
 133 enable_sysio="$with_sysio"
 134 case x$with_sysio in
 135         xyes)
 136                 AC_MSG_RESULT([internal])
 137                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 138                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 139                 ])
 140                 LIBSYSIO_SUBDIR="libsysio"
 141                 SYSIO="$PWD/libsysio"
 142                 ;;
 143         xno)
 144                 AC_MSG_RESULT([disabled])
 145                 ;;
 146         *)
 147                 AC_MSG_RESULT([$with_sysio])
 148                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 149                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 150                 ])
 151                 SYSIO=$with_sysio
 152                 with_sysio="yes"
 153                 ;;
 154 esac
 155
 156 # We have to configure even if we don't build here for make dist to
 157 # work
 158 AC_CONFIG_SUBDIRS(libsysio)
 159 ])
 160
 161 #
 162 # LB_PATH_CRAY_PORTALS
 163 #
 164 # Support for external Cray portals
 165 #
 166 AC_DEFUN([LB_PATH_CRAY_PORTALS],
 167 [LB_ARG_LIBS_INCLUDES([Cray Portals],[cray-portals])
 168
 169 if test x$cray_portals_includes != x ; then
 170         if test ! -r $cray_portals_includes/portals/api.h ; then
 171                 AC_MSG_ERROR([Cray portals headers were not found in $cray_portals_includes.  Please check the paths passed to --with-cray-portals or --with-cray-portals-includes.])
 172         fi
 173 fi
 174 if test x$cray_portals_libs != x ; then
 175         if test ! -r $cray_portals_libs/libportals.a ; then
 176                 AC_MSG_ERROR([Cray portals libraries were not found in $cray_portals_libs.  Please check the paths passed to --with-cray-portals or --with-cray-portals-libs.])
 177         fi
 178 fi
 179
 180 if test x$cray_portals_includes != x -a x$cray_portals_libs != x ; then
 181         cray_portals=yes
 182         AC_DEFINE(CRAY_PORTALS, 1, [Building with Cray Portals])
 183         CPPFLAGS="-I$cray_portals_includes $CPPFLAGS"
 184         EXTRA_KCFLAGS="-I$cray_portals_includes $EXTRA_KCFLAGS"
 185         # for liblustre + b_cray
 186         CRAY_PORTALS_LIBS="$cray_portals_libs"
 187         AC_SUBST(CRAY_PORTALS_LIBS)
 188 else
 189         cray_portals=no
 190 fi
 191 ])
 192
 193 #
 194 # LB_CONFIG_MODULES
 195 #
 196 # Build kernel modules?
 197 #
 198 AC_DEFUN([LB_CONFIG_MODULES],
 199 [AC_MSG_CHECKING([whether to build kernel modules])
 200 AC_ARG_ENABLE([modules],
 201         AC_HELP_STRING([--disable-modules],
 202                         [disable building of Lustre kernel modules]),
 203         [],[
 204                 LC_TARGET_SUPPORTED([
 205                         enable_modules='yes'
 206                 ],[
 207                         enable_modules='no'
 208                 ])
 209         ])
 210 AC_MSG_RESULT([$enable_modules ($target_os)])
 211
 212 if test x$enable_modules = xyes ; then
 213         case $target_os in
 214                 linux*)
 215                         LB_PROG_LINUX
 216                         ;;
 217                 darwin*)
 218                         LB_PROG_DARWIN
 219                         ;;
 220                 *)
 221                         # This is strange - Lustre supports a target we don't
 222                         AC_MSG_ERROR([Modules are not supported on $target_os])
 223                         ;;
 224         esac
 225 fi
 226 ])
 227
 228 #
 229 # LB_CONFIG_UTILS
 230 #
 231 # Build utils?
 232 #
 233 AC_DEFUN([LB_CONFIG_UTILS],
 234 [AC_MSG_CHECKING([whether to build utilities])
 235 AC_ARG_ENABLE([utils],
 236         AC_HELP_STRING([--disable-utils],
 237                         [disable building of Lustre utility programs]),
 238         [],[enable_utils='yes'])
 239 AC_MSG_RESULT([$enable_utils])
 240 if test x$enable_utils = xyes ; then
 241         LB_CONFIG_INIT_SCRIPTS
 242 fi
 243 ])
 244
 245 #
 246 # LB_CONFIG_TESTS
 247 #
 248 # Build tests?
 249 #
 250 AC_DEFUN([LB_CONFIG_TESTS],
 251 [AC_MSG_CHECKING([whether to build Lustre tests])
 252 AC_ARG_ENABLE([tests],
 253         AC_HELP_STRING([--disable-tests],
 254                         [disable building of Lustre tests]),
 255         [],[enable_tests='yes'])
 256 if test x$cray_portals = xyes ; then
 257         enable_tests='no'
 258 fi
 259 AC_MSG_RESULT([$enable_tests])
 260 ])
 261
 262 #
 263 # LB_CONFIG_DOCS
 264 #
 265 # Build docs?
 266 #
 267 AC_DEFUN([LB_CONFIG_DOCS],
 268 [AC_MSG_CHECKING([whether to build docs])
 269 AC_ARG_ENABLE(doc,
 270         AC_HELP_STRING([--disable-doc],
 271                         [skip creation of pdf documentation]),
 272         [
 273                 if test x$enable_doc = xyes ; then
 274                     ENABLE_DOC=1
 275                 else
 276                     ENABLE_DOC=0
 277                 fi
 278         ],[
 279                 ENABLE_DOC=0
 280                 enable_doc='no'
 281         ])
 282 AC_MSG_RESULT([$enable_doc])
 283 AC_SUBST(ENABLE_DOC)
 284 ])
 285
 286 #
 287 # LB_CONFIG_INIT_SCRIPTS
 288 #
 289 # our init scripts only work on red hat linux
 290 #
 291 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 292 [ENABLE_INIT_SCRIPTS=0
 293 if test x$enable_utils = xyes ; then
 294         AC_MSG_CHECKING([whether to install init scripts])
 295         # our scripts only work on red hat systems
 296         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 297                 ENABLE_INIT_SCRIPTS=1
 298                 AC_MSG_RESULT([yes])
 299         else
 300                 AC_MSG_RESULT([no])
 301         fi
 302 fi
 303 AC_SUBST(ENABLE_INIT_SCRIPTS)
 304 ])
 305
 306 #
 307 # LB_CONFIG_HEADERS
 308 #
 309 # add -include config.h
 310 #
 311 AC_DEFUN([LB_CONFIG_HEADERS],
 312 [AC_CONFIG_HEADERS([config.h])
 313 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 314 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 315 AC_SUBST(EXTRA_KCFLAGS)
 316 ])
 317
 318 #
 319 # LB_INCLUDE_RULES
 320 #
 321 # defines for including the toplevel Rules
 322 #
 323 AC_DEFUN([LB_INCLUDE_RULES],
 324 [INCLUDE_RULES="include $PWD/build/Rules"
 325 AC_SUBST(INCLUDE_RULES)
 326 ])
 327
 328 #
 329 # LB_PATH_DEFAULTS
 330 #
 331 # 'fixup' default paths
 332 #
 333 AC_DEFUN([LB_PATH_DEFAULTS],
 334 [# directories for binaries
 335 AC_PREFIX_DEFAULT([/usr])
 336
 337 sysconfdir='/etc'
 338 AC_SUBST(sysconfdir)
 339
 340 # Directories for documentation and demos.
 341 docdir='${datadir}/doc/$(PACKAGE)'
 342 AC_SUBST(docdir)
 343
 344 LP_PATH_DEFAULTS
 345 LC_PATH_DEFAULTS
 346 ])
 347
 348 #
 349 # LB_PROG_CC
 350 #
 351 # checks on the C compiler
 352 #
 353 AC_DEFUN([LB_PROG_CC],
 354 [AC_PROG_RANLIB
 355 AC_MSG_CHECKING([for buggy compiler])
 356 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 357 bad_cc() {
 358         AC_MSG_RESULT([buggy compiler found!])
 359         echo
 360         echo "   '$CC_VERSION'"
 361         echo "  has been known to generate bad code, "
 362         echo "  please get an updated compiler."
 363         AC_MSG_ERROR([sorry])
 364 }
 365 case "$CC_VERSION" in
 366         "gcc version 2.95"*)
 367                 bad_cc
 368                 ;;
 369         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 370         # without "sub    $0xc,%esp" to protect the stack from being
 371         # stomped on by interrupts (bug 606)
 372         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 373                 bad_cc
 374                 ;;
 375         # mandrake's similar sub 0xc compiler bug
 376         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 377         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 378                 bad_cc
 379                 ;;
 380         *)
 381                 AC_MSG_RESULT([no known problems])
 382                 ;;
 383 esac
 384
 385 # ---------  unsigned long long sane? -------
 386 AC_CHECK_SIZEOF(unsigned long long, 0)
 387 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 388 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 389 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 390         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 391 fi
 392
 393 AC_MSG_CHECKING([if $CC accepts -m64])
 394 CC_save="$CC"
 395 CC="$CC -m64"
 396 AC_TRY_COMPILE([],[],[
 397         AC_MSG_RESULT([yes])
 398 ],[
 399         AC_MSG_RESULT([no])
 400         CC="$CC_save"
 401 ])
 402
 403 CPPFLAGS="-I\$(top_builddir)/portals/include -I\$(top_srcdir)/portals/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 404
 405 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 406 AC_SUBST(LLCPPFLAGS)
 407
 408 LLCFLAGS="-g -Wall -fPIC"
 409 AC_SUBST(LLCFLAGS)
 410
 411 # everyone builds against portals and lustre
 412 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/portals/include -I$PWD/lustre/include"
 413 AC_SUBST(EXTRA_KCFLAGS)
 414 ])
 415
 416 #
 417 # LB_CONTITIONALS
 418 #
 419 # AM_CONDITIONAL instances for everything
 420 # (so that portals/lustre can disable some if needed)
 421 AC_DEFUN([LB_CONDITIONALS],
 422 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 423 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 424 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 425 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 426 AM_CONDITIONAL(CRAY_PORTALS, test x$cray_portals != xno)
 427 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 428 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 429 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 430
 431 # this lets lustre cancel libsysio, per-branch or if liblustre is
 432 # disabled
 433 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 434         if test "x$with_sysio" != xyes ; then
 435                 SYSIO=""
 436                 LIBSYSIO_SUBDIR=""
 437         fi
 438 fi
 439 AC_SUBST(LIBSYSIO_SUBDIR)
 440 AC_SUBST(SYSIO)
 441
 442 LB_LINUX_CONDITIONALS
 443 LB_DARWIN_CONDITIONALS
 444
 445 LP_CONDITIONALS
 446 LC_CONDITIONALS
 447 ])
 448
 449 #
 450 # LB_CONFIGURE
 451 #
 452 # main configure steps
 453 #
 454 AC_DEFUN([LB_CONFIGURE],
 455 [LB_CANONICAL_SYSTEM
 456
 457 LB_INCLUDE_RULES
 458
 459 LB_PATH_DEFAULTS
 460
 461 LB_PROG_CC
 462
 463 LB_PATH_LIBSYSIO
 464 LB_PATH_CRAY_PORTALS
 465
 466 LB_CONFIG_DOCS
 467 LB_CONFIG_UTILS
 468 LB_CONFIG_TESTS
 469
 470 LB_CONFIG_MODULES
 471
 472 LC_CONFIG_LIBLUSTRE
 473
 474 LP_CONFIGURE
 475 LC_CONFIGURE
 476
 477 LB_CONDITIONALS
 478 LB_CONFIG_HEADERS
 479
 480 AC_CONFIG_FILES(
 481 [Makefile:build/Makefile.in.toplevel]
 482 [autoMakefile
 483 build/autoMakefile
 484 build/autoconf/Makefile
 485 build/Rules
 486 build/lustre.spec
 487 ])
 488
 489 LP_CONFIG_FILES
 490 LC_CONFIG_FILES
 491
 492 AC_OUTPUT
 493
 494 cat <<_ACEOF
 495
 496 CC:            $CC
 497 LD:            $LD
 498 CPPFLAGS:      $CPPFLAGS
 499 LLCPPFLAGS:    $LLCPPFLAGS
 500 CFLAGS:        $CFLAGS
 501 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 502 LLCFLAGS:      $LLCFLAGS
 503
 504 Type 'make' to build Lustre.
 505 _ACEOF
 506 ])