build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a 2.5 kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],
   7 [LB_CHECK_FILE([$LINUX/include/linux/namei.h],
   8         [
   9                 linux25="yes"
  10                 KMODEXT=".ko"
  11         ],[
  12                 KMODEXT=".o"
  13                 linux25="no"
  14         ])
  15 AC_MSG_CHECKING([if you are using Linux 2.6])
  16 AC_MSG_RESULT([$linux25])
  17
  18 MODULE_TARGET="SUBDIRS"
  19 if test $linux25 = "yes" ; then
  20         makerule="$PWD/build"
  21         AC_MSG_CHECKING([for external module build support])
  22         rm -f build/conftest.i
  23         LB_LINUX_TRY_MAKE([],[],
  24                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  25                 [test -s build/conftest.i],
  26                 [
  27                         AC_MSG_RESULT([no])
  28                 ],[
  29                         makerule="_module_$makerule"
  30                         MODULE_TARGET="M"
  31                         LB_LINUX_TRY_MAKE([],[],
  32                                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  33                                 [test -s build/conftest.i],
  34                                 [
  35                                         AC_MSG_RESULT([yes])
  36                                 ],[
  37                                         AC_MSG_ERROR([unknown; check config.log for details])
  38                                 ])
  39                 ])
  40 else
  41         makerule="_dir_$PWD/build"
  42 fi
  43
  44 AC_SUBST(MODULE_TARGET)
  45 AC_SUBST(linux25)
  46 AC_SUBST(KMODEXT)
  47 ])
  48
  49 #
  50 # LB_LINUX_RELEASE
  51 #
  52 # get the release version of linux
  53 #
  54 AC_DEFUN([LB_LINUX_RELEASE],
  55 [LINUXRELEASE=
  56 rm -f build/conftest.i
  57 AC_MSG_CHECKING([for Linux release])
  58 if test -s $LINUX_OBJ/include/linux/utsrelease.h ; then
  59         LINUXRELEASEHEADER=utsrelease.h
  60 else
  61         LINUXRELEASEHEADER=version.h
  62 fi
  63 LB_LINUX_TRY_MAKE([
  64         #include <linux/$LINUXRELEASEHEADER>
  65 ],[
  66         char *LINUXRELEASE;
  67         LINUXRELEASE=UTS_RELEASE;
  68 ],[
  69         $makerule LUSTRE_KERNEL_TEST=conftest.i
  70 ],[
  71         test -s build/conftest.i
  72 ],[
  73         # LINUXRELEASE="UTS_RELEASE"
  74         eval $(grep "LINUXRELEASE=" build/conftest.i)
  75 ],[
  76         AC_MSG_RESULT([unknown])
  77         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  78 ])
  79 rm -f build/conftest.i
  80 if test x$LINUXRELEASE = x ; then
  81         AC_MSG_RESULT([unknown])
  82         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  83 fi
  84 AC_MSG_RESULT([$LINUXRELEASE])
  85 AC_SUBST(LINUXRELEASE)
  86
  87 moduledir='/lib/modules/'$LINUXRELEASE/kernel
  88 AC_SUBST(moduledir)
  89
  90 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  91 AC_SUBST(modulefsdir)
  92
  93 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  94 AC_SUBST(modulenetdir)
  95
  96 # ------------ RELEASE --------------------------------
  97 AC_MSG_CHECKING([for Lustre release])
  98 RELEASE="`echo ${LINUXRELEASE} | tr '-' '_'`_`date +%Y%m%d%H%M`"
  99 AC_MSG_RESULT($RELEASE)
 100 AC_SUBST(RELEASE)
 101
 102 # check is redhat/suse kernels
 103 AC_MSG_CHECKING([that RedHat kernel])
 104 LB_LINUX_TRY_COMPILE([
 105                 #include <linux/version.h>
 106         ],[
 107                 #ifndef RHEL_RELEASE_CODE
 108                 #error "not redhat kernel"
 109                 #endif
 110         ],[
 111                 RHEL_KENEL="yes"
 112                 RHEL_KERNEL="yes"
 113                 AC_MSG_RESULT([yes])
 114         ],[
 115                 AC_MSG_RESULT([no])
 116 ])
 117
 118 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 119
 120 ])
 121
 122 #
 123 #
 124 # LB_LINUX_PATH
 125 #
 126 # Find paths for linux, handling kernel-source rpms
 127 #
 128 AC_DEFUN([LB_LINUX_PATH],
 129 [AC_MSG_CHECKING([for Linux sources])
 130 AC_ARG_WITH([linux],
 131         AC_HELP_STRING([--with-linux=path],
 132                        [set path to Linux source (default=/usr/src/linux)]),
 133         [
 134                 if ! [[[ $with_linux = /* ]]]; then
 135                         AC_MSG_ERROR([You must provide an absolute pathname to the --with-linux= option.])
 136                 else
 137                         LINUX=$with_linux
 138                 fi
 139         ],
 140         [LINUX=/usr/src/linux])
 141 AC_MSG_RESULT([$LINUX])
 142 AC_SUBST(LINUX)
 143
 144 # -------- check for linux --------
 145 LB_CHECK_FILE([$LINUX],[],
 146         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 147
 148 # -------- linux objects (for 2.6) --
 149 AC_MSG_CHECKING([for Linux objects dir])
 150 AC_ARG_WITH([linux-obj],
 151         AC_HELP_STRING([--with-linux-obj=path],
 152                         [set path to Linux objects dir (default=$LINUX)]),
 153         [LINUX_OBJ=$with_linux_obj],
 154         [LINUX_OBJ=$LINUX])
 155 AC_MSG_RESULT([$LINUX_OBJ])
 156 AC_SUBST(LINUX_OBJ)
 157
 158 # -------- check for .config --------
 159 AC_ARG_WITH([linux-config],
 160         [AC_HELP_STRING([--with-linux-config=path],
 161                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 162         [LINUX_CONFIG=$with_linux_config],
 163         [LINUX_CONFIG=$LINUX_OBJ/.config])
 164 AC_SUBST(LINUX_CONFIG)
 165
 166 LB_CHECK_FILE([/boot/kernel.h],
 167         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 168         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 169                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 170
 171 AC_ARG_WITH([kernel-source-header],
 172         AC_HELP_STRING([--with-kernel-source-header=path],
 173                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 174         [KERNEL_SOURCE_HEADER=$with_kernel_source_header])
 175
 176 # ------------ .config exists ----------------
 177 LB_CHECK_FILE([$LINUX_CONFIG],[],
 178         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 179
 180 # ----------- make dep run? ------------------
 181 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 182 # and at more old has only one line
 183 # include <autoconf.h>
 184 LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[],
 185         [AC_MSG_ERROR([Run make config in $LINUX.])])
 186 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 187         [AC_MSG_ERROR([Run make config in $LINUX.])])
 188
 189 # ------------ rhconfig.h includes runtime-generated bits --
 190 # red hat kernel-source checks
 191
 192 # we know this exists after the check above.  if the user
 193 # tarred up the tree and ran make dep etc. in it, then
 194 # version.h gets overwritten with a standard linux one.
 195
 196 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 197         # This is a clean kernel-source tree, we need to
 198         # enable extensive workarounds to get this to build
 199         # modules
 200         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 201                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 202                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 203                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 204                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 205                 fi],
 206                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 207         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 208 fi
 209
 210 # this is needed before we can build modules
 211 LB_LINUX_UML
 212 LB_LINUX_VERSION
 213
 214 # --- check that we can build modules at all
 215 AC_MSG_CHECKING([that modules can be built at all])
 216 LB_LINUX_TRY_COMPILE([],[],[
 217         AC_MSG_RESULT([yes])
 218 ],[
 219         AC_MSG_RESULT([no])
 220         AC_MSG_WARN([Consult config.log for details.])
 221         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 222         AC_MSG_ERROR([Kernel modules cannot be built.])
 223 ])
 224
 225 LB_LINUX_RELEASE
 226 ]) # end of LB_LINUX_PATH
 227
 228 # LB_LINUX_SYMVERFILE
 229 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 230 # around this version, but it matters for servers only.
 231 AC_DEFUN([LB_LINUX_SYMVERFILE],
 232         [AC_MSG_CHECKING([name of module symbol version file])
 233         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 234                 SYMVERFILE=Modules.symvers
 235         else
 236                 SYMVERFILE=Module.symvers
 237         fi
 238         AC_MSG_RESULT($SYMVERFILE)
 239         AC_SUBST(SYMVERFILE)
 240 ])
 241
 242 #
 243 #
 244 # LB_LINUX_MODPOST
 245 #
 246 # Find modpost and check it
 247 #
 248 AC_DEFUN([LB_LINUX_MODPOST],
 249 [
 250 # Find the modpost utility
 251 LB_CHECK_FILE([$LINUX_OBJ/scripts/mod/modpost],
 252         [MODPOST=$LINUX_OBJ/scripts/mod/modpost],
 253         [LB_CHECK_FILE([$LINUX_OBJ/scripts/modpost],
 254                 [MODPOST=$LINUX_OBJ/scripts/modpost],
 255                 AC_MSG_ERROR([modpost not found.])
 256         )]
 257 )
 258 AC_SUBST(MODPOST)
 259
 260 # Ensure it can run
 261 AC_MSG_CHECKING([if modpost can be run])
 262 if $MODPOST ; then
 263         AC_MSG_RESULT([yes])
 264 else
 265         AC_MSG_ERROR([modpost can not be run.])
 266 fi
 267
 268 # Check if modpost supports (and therefore requires) -m
 269 AC_MSG_CHECKING([if modpost supports -m])
 270 if $MODPOST -m 2>/dev/null ; then
 271         AC_MSG_RESULT([yes])
 272         MODPOST_ARGS=-m
 273 else
 274         AC_MSG_RESULT([no])
 275         MODPOST_ARGS=""
 276 fi
 277 AC_SUBST(MODPOST_ARGS)
 278 ])
 279
 280 #
 281 # LB_LINUX_UML
 282 #
 283 # check for a uml kernel
 284 #
 285 AC_DEFUN([LB_LINUX_UML],
 286 [ARCH_UM=
 287 UML_CFLAGS=
 288
 289 AC_MSG_CHECKING([if you are running user mode linux for $target_cpu])
 290 if test -e $LINUX/include/asm-um ; then
 291         if test  X`ls -id $LINUX/include/asm/ 2>/dev/null | awk '{print [$]1}'` = X`ls -id $LINUX/include/asm-um 2>/dev/null | awk '{print [$]1}'` ; then
 292                 ARCH_UM='ARCH=um'
 293                 # see notes in Rules.in
 294                 UML_CFLAGS='-O0'
 295                 AC_MSG_RESULT(yes)
 296         else
 297                 AC_MSG_RESULT([no])
 298         fi
 299 else
 300         AC_MSG_RESULT([no (asm-um missing)])
 301 fi
 302 AC_SUBST(ARCH_UM)
 303 AC_SUBST(UML_CFLAGS)
 304 ])
 305
 306 # these are like AC_TRY_COMPILE, but try to build modules against the
 307 # kernel, inside the build directory
 308
 309 #
 310 # LB_LINUX_CONFTEST
 311 #
 312 # create a conftest.c file
 313 #
 314 AC_DEFUN([LB_LINUX_CONFTEST],
 315 [cat >conftest.c <<_ACEOF
 316 $1
 317 _ACEOF
 318 ])
 319
 320
 321 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 322 # --------------------------------------
 323 m4_define([LB_LANG_PROGRAM],
 324 [$1
 325 int
 326 main (void)
 327 {
 328 dnl Do *not* indent the following line: there may be CPP directives.
 329 dnl Don't move the `;' right after for the same reason.
 330 $2
 331   ;
 332   return 0;
 333 }])
 334
 335 #
 336 # LB_LINUX_COMPILE_IFELSE
 337 #
 338 # like AC_COMPILE_IFELSE
 339 #
 340 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 341 [m4_ifvaln([$1], [LB_LINUX_CONFTEST([$1])])dnl
 342 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 343 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`uname -m|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/'`/include -I$LINUX/include -I$LINUX_OBJ/include -I$LINUX_OBJ/include2 -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 344         [$4],
 345         [_AC_MSG_LOG_CONFTEST
 346 m4_ifvaln([$5],[$5])dnl])dnl
 347 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 348 ])
 349
 350 #
 351 # LB_LINUX_ARCH
 352 #
 353 # Determine the kernel's idea of the current architecture
 354 #
 355 AC_DEFUN([LB_LINUX_ARCH],
 356          [AC_MSG_CHECKING([Linux kernel architecture])
 357           AS_IF([rm -f $PWD/build/arch
 358                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 359                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $ARCH_UM \
 360                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 361                 [AC_MSG_RESULT([$LINUX_ARCH])],
 362                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 363           rm -f build/arch])
 364
 365 #
 366 # LB_LINUX_TRY_COMPILE
 367 #
 368 # like AC_TRY_COMPILE
 369 #
 370 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 371 [LB_LINUX_COMPILE_IFELSE(
 372         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 373         [modules],
 374         [test -s build/conftest.o],
 375         [$3], [$4])])
 376
 377 #
 378 # LB_LINUX_CONFIG
 379 #
 380 # check if a given config option is defined
 381 #
 382 AC_DEFUN([LB_LINUX_CONFIG],
 383 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 384 LB_LINUX_TRY_COMPILE([
 385 #include <linux/autoconf.h>
 386 ],[
 387 #ifndef CONFIG_$1
 388 #error CONFIG_$1 not #defined
 389 #endif
 390 ],[
 391 AC_MSG_RESULT([yes])
 392 $2
 393 ],[
 394 AC_MSG_RESULT([no])
 395 $3
 396 ])
 397 ])
 398
 399 #
 400 # LB_LINUX_CONFIG_IM
 401 #
 402 # check if a given config option is builtin or as module
 403 #
 404 AC_DEFUN([LB_LINUX_CONFIG_IM],
 405 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 406 LB_LINUX_TRY_COMPILE([
 407 #include <linux/autoconf.h>
 408 ],[
 409 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 410 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 411 #endif
 412 ],[
 413 AC_MSG_RESULT([yes])
 414 $2
 415 ],[
 416 AC_MSG_RESULT([no])
 417 $3
 418 ])
 419 ])
 420
 421 #
 422 # LB_LINUX_TRY_MAKE
 423 #
 424 # like LB_LINUX_TRY_COMPILE, but with different arguments
 425 #
 426 AC_DEFUN([LB_LINUX_TRY_MAKE],
 427 [LB_LINUX_COMPILE_IFELSE([AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])], [$3], [$4], [$5], [$6])])
 428
 429 #
 430 # LB_LINUX_CONFIG_BIG_STACK
 431 #
 432 # check for big stack patch
 433 #
 434 AC_DEFUN([LB_LINUX_CONFIG_BIG_STACK],
 435 [if test "x$ARCH_UM" = "x" -a "x$linux25" = "xno" ; then
 436         case $target_cpu in
 437                 i?86 | x86_64)
 438                         LB_LINUX_CONFIG([STACK_SIZE_16KB],[],[
 439                                 LB_LINUX_CONFIG([STACK_SIZE_32KB],[],[
 440                                         LB_LINUX_CONFIG([STACK_SIZE_64KB],[],[
 441                                                 AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 16KB stack.])
 442                                         ])
 443                                 ])
 444                         ])
 445                         ;;
 446         esac
 447 fi
 448 ])
 449
 450 #
 451 # LB_CONFIG_OFED_BACKPORTS
 452 #
 453 # include any OFED backport headers in all compile commands
 454 # NOTE: this does only include the backport paths, not the OFED headers
 455 #       adding the OFED headers is done in the lnet portion
 456 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 457 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 458 # set default
 459 AC_ARG_WITH([o2ib],
 460         AC_HELP_STRING([--with-o2ib=path],
 461                        [build o2iblnd against path]),
 462         [
 463                 case $with_o2ib in
 464                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 465                         ENABLEO2IB=2
 466                         ;;
 467                 no)     ENABLEO2IB=0
 468                         ;;
 469                 *)      O2IBPATHS=$with_o2ib
 470                         ENABLEO2IB=3
 471                         ;;
 472                 esac
 473         ],[
 474                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 475                 ENABLEO2IB=1
 476         ])
 477 if test $ENABLEO2IB -eq 0; then
 478         AC_MSG_RESULT([no])
 479 else
 480         o2ib_found=false
 481         for O2IBPATH in $O2IBPATHS; do
 482                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 483                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 484                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 485                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 486                         o2ib_found=true
 487                         break
 488                 fi
 489         done
 490         if ! $o2ib_found; then
 491                 AC_MSG_RESULT([no])
 492                 case $ENABLEO2IB in
 493                         1) ;;
 494                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 495                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 496                         *) AC_MSG_ERROR([internal error]);;
 497                 esac
 498         else
 499                 if test -f $O2IBPATH/config.mk; then
 500                         . $O2IBPATH/config.mk
 501                 elif test -f $O2IBPATH/ofed_patch.mk; then
 502                         . $O2IBPATH/ofed_patch.mk
 503                 fi
 504                 if test -n "$BACKPORT_INCLUDES"; then
 505                         OFED_BACKPORT_PATH=`echo $BACKPORT_INCLUDES | sed "s#.*/src/ofa_kernel/#$O2IBPATH/#"`
 506                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 507                         AC_MSG_RESULT([yes])
 508                 else
 509                         AC_MSG_RESULT([no])
 510                 fi
 511         fi
 512 fi
 513 ])
 514
 515
 516 #
 517 # LB_PROG_LINUX
 518 #
 519 # linux tests
 520 #
 521 AC_DEFUN([LB_PROG_LINUX],
 522 [LB_LINUX_PATH
 523 LB_LINUX_ARCH
 524 LB_LINUX_SYMVERFILE
 525
 526
 527 LB_LINUX_CONFIG([MODULES],[],[
 528         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 529 ])
 530
 531 LB_LINUX_CONFIG([MODVERSIONS])
 532
 533 LB_LINUX_CONFIG([KALLSYMS],[],[
 534 if test "x$ARCH_UM" = "x" ; then
 535         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 536 fi
 537 ])
 538
 539 LB_LINUX_CONFIG([KMOD],[],[
 540         AC_MSG_WARN([])
 541         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 542         AC_MSG_WARN([])
 543 ])
 544
 545 #LB_LINUX_CONFIG_BIG_STACK
 546
 547 # it's ugly to be doing anything with OFED outside of the lnet module, but
 548 # this has to be done here so that the backports path is set before all of
 549 # the LN_PROG_LINUX checks are done
 550 LB_CONFIG_OFED_BACKPORTS
 551 ])
 552
 553 #
 554 # LB_LINUX_CONDITIONALS
 555 #
 556 # AM_CONDITIONALS for linux
 557 #
 558 AC_DEFUN([LB_LINUX_CONDITIONALS],
 559 [AM_CONDITIONAL(LINUX25, test x$linux25 = xyes)
 560 ])
 561
 562
 563 #
 564 # LB_CHECK_SYMBOL_EXPORT
 565 # check symbol exported or not
 566 # $1 - symbol
 567 # $2 - file(s) for find.
 568 # $3 - do 'yes'
 569 # $4 - do 'no'
 570 #
 571 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 572 # or check
 573 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 574 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 575 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 576 rc=$?
 577 if test $rc -ne 0; then
 578     export=0
 579     for file in $2; do
 580         grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 581         rc=$?
 582         if test $rc -eq 0; then
 583                 export=1
 584                 break;
 585         fi
 586     done
 587     if test $export -eq 0; then
 588         AC_MSG_RESULT([no])
 589         $4
 590     else
 591         AC_MSG_RESULT([yes])
 592         $3
 593     fi
 594 else
 595     AC_MSG_RESULT([yes])
 596     $3
 597 fi
 598 ])
 599
 600 #
 601 # Like AC_CHECK_HEADER but checks for a kernel-space header
 602 #
 603 m4_define([LB_CHECK_LINUX_HEADER],
 604 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 605 AC_CACHE_CHECK([for $1], ac_Header,
 606                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 607                                   [modules],
 608                                   [test -s build/conftest.o],
 609                                   [AS_VAR_SET(ac_Header, [yes])],
 610                                   [AS_VAR_SET(ac_Header, [no])])])
 611 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 612 AS_VAR_POPDEF([ac_Header])dnl
 613 ])