build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a 2.5 kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],
   7 [LB_CHECK_FILE([$LINUX/include/linux/namei.h],
   8         [
   9                 linux25="yes"
  10                 KMODEXT=".ko"
  11         ],[
  12                 KMODEXT=".o"
  13                 linux25="no"
  14         ])
  15 AC_MSG_CHECKING([if you are using Linux 2.6])
  16 AC_MSG_RESULT([$linux25])
  17
  18 MODULE_TARGET="SUBDIRS"
  19 if test $linux25 = "yes" ; then
  20         makerule="$PWD/build"
  21         AC_MSG_CHECKING([for external module build support])
  22         rm -f build/conftest.i
  23         LB_LINUX_TRY_MAKE([],[],
  24                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  25                 [test -s build/conftest.i],
  26                 [
  27                         AC_MSG_RESULT([no])
  28                 ],[
  29                         makerule="_module_$makerule"
  30                         MODULE_TARGET="M"
  31                         LB_LINUX_TRY_MAKE([],[],
  32                                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  33                                 [test -s build/conftest.i],
  34                                 [
  35                                         AC_MSG_RESULT([yes])
  36                                 ],[
  37                                         AC_MSG_ERROR([unknown; check config.log for details])
  38                                 ])
  39                 ])
  40 else
  41         makerule="_dir_$PWD/build"
  42 fi
  43
  44 AC_SUBST(MODULE_TARGET)
  45 AC_SUBST(linux25)
  46 AC_SUBST(KMODEXT)
  47 ])
  48
  49 #
  50 # LB_LINUX_RELEASE
  51 #
  52 # get the release version of linux
  53 #
  54 AC_DEFUN([LB_LINUX_RELEASE],
  55 [LINUXRELEASE=
  56 rm -f build/conftest.i
  57 AC_MSG_CHECKING([for Linux release])
  58 if test -s $LINUX_OBJ/include/linux/utsrelease.h ; then
  59         LINUXRELEASEHEADER=utsrelease.h
  60 else
  61         LINUXRELEASEHEADER=version.h
  62 fi
  63 LB_LINUX_TRY_MAKE([
  64         #include <linux/$LINUXRELEASEHEADER>
  65 ],[
  66         char *LINUXRELEASE;
  67         LINUXRELEASE=UTS_RELEASE;
  68 ],[
  69         $makerule LUSTRE_KERNEL_TEST=conftest.i
  70 ],[
  71         test -s build/conftest.i
  72 ],[
  73         # LINUXRELEASE="UTS_RELEASE"
  74         eval $(grep "LINUXRELEASE=" build/conftest.i)
  75 ],[
  76         AC_MSG_RESULT([unknown])
  77         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  78 ])
  79 rm -f build/conftest.i
  80 if test x$LINUXRELEASE = x ; then
  81         AC_MSG_RESULT([unknown])
  82         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  83 fi
  84 AC_MSG_RESULT([$LINUXRELEASE])
  85 AC_SUBST(LINUXRELEASE)
  86
  87 moduledir='/lib/modules/'$LINUXRELEASE/kernel
  88 AC_SUBST(moduledir)
  89
  90 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  91 AC_SUBST(modulefsdir)
  92
  93 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  94 AC_SUBST(modulenetdir)
  95
  96 # ------------ RELEASE --------------------------------
  97 AC_MSG_CHECKING([for Lustre release])
  98 RELEASE="`echo ${LINUXRELEASE} | tr '-' '_'`_`date +%Y%m%d%H%M`"
  99 AC_MSG_RESULT($RELEASE)
 100 AC_SUBST(RELEASE)
 101 ])
 102
 103 #
 104 # LB_LINUX_PATH
 105 #
 106 # Find paths for linux, handling kernel-source rpms
 107 #
 108 AC_DEFUN([LB_LINUX_PATH],
 109 [AC_MSG_CHECKING([for Linux sources])
 110 AC_ARG_WITH([linux],
 111         AC_HELP_STRING([--with-linux=path],
 112                        [set path to Linux source (default=/usr/src/linux)]),
 113         [LINUX=$with_linux],
 114         [LINUX=/usr/src/linux])
 115 AC_MSG_RESULT([$LINUX])
 116 AC_SUBST(LINUX)
 117
 118 # -------- check for linux --------
 119 LB_CHECK_FILE([$LINUX],[],
 120         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 121
 122 # -------- linux objects (for 2.6) --
 123 AC_MSG_CHECKING([for Linux objects dir])
 124 AC_ARG_WITH([linux-obj],
 125         AC_HELP_STRING([--with-linux-obj=path],
 126                         [set path to Linux objects dir (default=$LINUX)]),
 127         [LINUX_OBJ=$with_linux_obj],
 128         [LINUX_OBJ=$LINUX])
 129 AC_MSG_RESULT([$LINUX_OBJ])
 130 AC_SUBST(LINUX_OBJ)
 131
 132 # -------- check for .config --------
 133 AC_ARG_WITH([linux-config],
 134         [AC_HELP_STRING([--with-linux-config=path],
 135                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 136         [LINUX_CONFIG=$with_linux_config],
 137         [LINUX_CONFIG=$LINUX_OBJ/.config])
 138 AC_SUBST(LINUX_CONFIG)
 139
 140 LB_CHECK_FILE([/boot/kernel.h],
 141         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 142         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 143                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 144
 145 AC_ARG_WITH([kernel-source-header],
 146         AC_HELP_STRING([--with-kernel-source-header=path],
 147                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 148         [KERNEL_SOURCE_HEADER=$with_kernel_source_header])
 149
 150 # ------------ .config exists ----------------
 151 LB_CHECK_FILE([$LINUX_CONFIG],[],
 152         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 153
 154 # ----------- make dep run? ------------------
 155 LB_CHECK_FILES([$LINUX_OBJ/include/linux/autoconf.h
 156                 $LINUX_OBJ/include/linux/version.h
 157                 $LINUX/include/linux/config.h],[],
 158         [AC_MSG_ERROR([Run make config in $LINUX.])])
 159
 160 # ------------ rhconfig.h includes runtime-generated bits --
 161 # red hat kernel-source checks
 162
 163 # we know this exists after the check above.  if the user
 164 # tarred up the tree and ran make dep etc. in it, then
 165 # version.h gets overwritten with a standard linux one.
 166
 167 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 168         # This is a clean kernel-source tree, we need to
 169         # enable extensive workarounds to get this to build
 170         # modules
 171         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 172                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 173                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 174                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 175                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 176                 fi],
 177                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 178         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 179 fi
 180
 181 # this is needed before we can build modules
 182 LB_LINUX_UML
 183 LB_LINUX_VERSION
 184
 185 # --- check that we can build modules at all
 186 AC_MSG_CHECKING([that modules can be built at all])
 187 LB_LINUX_TRY_COMPILE([],[],[
 188         AC_MSG_RESULT([yes])
 189 ],[
 190         AC_MSG_RESULT([no])
 191         AC_MSG_WARN([Consult config.log for details.])
 192         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 193         AC_MSG_ERROR([Kernel modules cannot be build.])
 194 ])
 195
 196 LB_LINUX_RELEASE
 197 ])
 198
 199 #
 200 # LB_LINUX_UML
 201 #
 202 # check for a uml kernel
 203 #
 204 AC_DEFUN([LB_LINUX_UML],
 205 [ARCH_UM=
 206 UML_CFLAGS=
 207
 208 AC_MSG_CHECKING([if you are running user mode linux for $target_cpu])
 209 if test -e $LINUX/include/asm-um ; then
 210         if test  X`ls -id $LINUX/include/asm/ 2>/dev/null | awk '{print [$]1}'` = X`ls -id $LINUX/include/asm-um 2>/dev/null | awk '{print [$]1}'` ; then
 211                 ARCH_UM='ARCH=um'
 212                 # see notes in Rules.in
 213                 UML_CFLAGS='-O0'
 214                 AC_MSG_RESULT(yes)
 215         else
 216                 AC_MSG_RESULT([no (asm doesn't point at asm-um)])
 217         fi
 218 else
 219         AC_MSG_RESULT([no (asm-um missing)])
 220 fi
 221 AC_SUBST(ARCH_UM)
 222 AC_SUBST(UML_CFLAGS)
 223 ])
 224
 225 # these are like AC_TRY_COMPILE, but try to build modules against the
 226 # kernel, inside the build directory
 227
 228 #
 229 # LB_LINUX_CONFTEST
 230 #
 231 # create a conftest.c file
 232 #
 233 AC_DEFUN([LB_LINUX_CONFTEST],
 234 [cat >conftest.c <<_ACEOF
 235 $1
 236 _ACEOF
 237 ])
 238
 239 #
 240 # LB_LINUX_COMPILE_IFELSE
 241 #
 242 # like AC_COMPILE_IFELSE
 243 #
 244 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 245 [m4_ifvaln([$1], [LB_LINUX_CONFTEST([$1])])dnl
 246 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 247 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make [$2] CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 248         [$4],
 249         [_AC_MSG_LOG_CONFTEST
 250 m4_ifvaln([$5],[$5])dnl])dnl
 251 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 252 ])
 253
 254 #
 255 # LB_LINUX_TRY_COMPILE
 256 #
 257 # like AC_TRY_COMPILE
 258 #
 259 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 260 [LB_LINUX_COMPILE_IFELSE(
 261         [AC_LANG_PROGRAM([[$1]], [[$2]])],
 262         [modules],
 263         [test -s build/conftest.o],
 264         [$3], [$4])])
 265
 266 #
 267 # LB_LINUX_CONFIG
 268 #
 269 # check if a given config option is defined
 270 #
 271 AC_DEFUN([LB_LINUX_CONFIG],
 272 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 273 LB_LINUX_TRY_COMPILE([#include <linux/config.h>],[
 274 #ifndef CONFIG_$1
 275 #error CONFIG_$1 not #defined
 276 #endif
 277 ],[
 278 AC_MSG_RESULT([yes])
 279 $2
 280 ],[
 281 AC_MSG_RESULT([no])
 282 $3
 283 ])
 284 ])
 285
 286 #
 287 # LB_LINUX_CONFIG_IM
 288 #
 289 # check if a given config option is builtin or as module
 290 #
 291 AC_DEFUN([LB_LINUX_CONFIG_IM],
 292 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 293 LB_LINUX_TRY_COMPILE([#include <linux/config.h>],[
 294 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 295 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 296 #endif
 297 ],[
 298 AC_MSG_RESULT([yes])
 299 $2
 300 ],[
 301 AC_MSG_RESULT([no])
 302 $3
 303 ])
 304 ])
 305
 306 #
 307 # LB_LINUX_TRY_MAKE
 308 #
 309 # like LB_LINUX_TRY_COMPILE, but with different arguments
 310 #
 311 AC_DEFUN([LB_LINUX_TRY_MAKE],
 312 [LB_LINUX_COMPILE_IFELSE([AC_LANG_PROGRAM([[$1]], [[$2]])], [$3], [$4], [$5], [$6])])
 313
 314 #
 315 # LB_LINUX_CONFIG_BIG_STACK
 316 #
 317 # check for big stack patch
 318 #
 319 AC_DEFUN([LB_LINUX_CONFIG_BIG_STACK],
 320 [if test "x$ARCH_UM" = "x" -a "x$linux25" = "xno" ; then
 321         case $target_cpu in
 322                 i?86 | x86_64)
 323                         LB_LINUX_CONFIG([STACK_SIZE_16KB],[],[
 324                                 LB_LINUX_CONFIG([STACK_SIZE_32KB],[],[
 325                                         LB_LINUX_CONFIG([STACK_SIZE_64KB],[],[
 326                                                 AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 16KB stack.])
 327                                         ])
 328                                 ])
 329                         ])
 330                         ;;
 331         esac
 332 fi
 333 ])
 334
 335 #
 336 # LB_PROG_LINUX
 337 #
 338 # linux tests
 339 #
 340 AC_DEFUN([LB_PROG_LINUX],
 341 [LB_LINUX_PATH
 342
 343 LB_LINUX_CONFIG([MODULES],[],[
 344         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 345 ])
 346
 347 LB_LINUX_CONFIG([MODVERSIONS])
 348
 349 LB_LINUX_CONFIG([PREEMPT],[
 350         AC_MSG_ERROR([Lustre does not support kernels with preempt enabled.])
 351 ])
 352
 353 LB_LINUX_CONFIG([KALLSYMS],[],[
 354 if test "x$ARCH_UM" = "x" ; then
 355         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 356 fi
 357 ])
 358
 359 LB_LINUX_CONFIG([KMOD],[],[
 360         AC_MSG_WARN([])
 361         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 362         AC_MSG_WARN([])
 363 ])
 364
 365 #LB_LINUX_CONFIG_BIG_STACK
 366
 367 # LNet tests
 368 LN_PROG_LINUX
 369
 370 # Lustre tests
 371 LC_PROG_LINUX
 372
 373 # Portals tests
 374 if test "$PORTALS" ; then
 375         LP_PROG_LINUX
 376 fi
 377 ])
 378
 379 #
 380 # LB_LINUX_CONDITIONALS
 381 #
 382 # AM_CONDITIONALS for linux
 383 #
 384 AC_DEFUN([LB_LINUX_CONDITIONALS],
 385 [AM_CONDITIONAL(LINUX25, test x$linux25 = xyes)
 386 ])
 387