build/autoconf/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a 2.5 kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],
   7 [LB_CHECK_FILE([$LINUX/include/linux/namei.h],
   8         [
   9                 linux25="yes"
  10                 KMODEXT=".ko"
  11         ],[
  12                 KMODEXT=".o"
  13                 linux25="no"
  14         ])
  15 AC_MSG_CHECKING([if you are using Linux 2.6])
  16 AC_MSG_RESULT([$linux25])
  17
  18 MODULE_TARGET="SUBDIRS"
  19 if test $linux25 = "yes" ; then
  20         makerule="$PWD/build"
  21         AC_MSG_CHECKING([for external module build support])
  22         rm -f build/conftest.i
  23         LB_LINUX_TRY_MAKE([],[],
  24                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  25                 [test -s build/conftest.i],
  26                 [
  27                         AC_MSG_RESULT([no])
  28                 ],[
  29                         makerule="_module_$makerule"
  30                         MODULE_TARGET="M"
  31                         LB_LINUX_TRY_MAKE([],[],
  32                                 [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  33                                 [test -s build/conftest.i],
  34                                 [
  35                                         AC_MSG_RESULT([yes])
  36                                 ],[
  37                                         AC_MSG_ERROR([unknown; check config.log for details])
  38                                 ])
  39                 ])
  40 else
  41         makerule="_dir_$PWD/build"
  42 fi
  43
  44 AC_SUBST(MODULE_TARGET)
  45 AC_SUBST(linux25)
  46 AC_SUBST(KMODEXT)
  47 ])
  48
  49 #
  50 # LB_LINUX_RELEASE
  51 #
  52 # get the release version of linux
  53 #
  54 AC_DEFUN([LB_LINUX_RELEASE],
  55 [LINUXRELEASE=
  56 rm -f build/conftest.i
  57 AC_MSG_CHECKING([for Linux release])
  58 if test -s $LINUX_OBJ/include/linux/utsrelease.h ; then
  59         LINUXRELEASEHEADER=utsrelease.h
  60 else
  61         LINUXRELEASEHEADER=version.h
  62 fi
  63 LB_LINUX_TRY_MAKE([
  64         #include <linux/$LINUXRELEASEHEADER>
  65 ],[
  66         char *LINUXRELEASE;
  67         LINUXRELEASE=UTS_RELEASE;
  68 ],[
  69         $makerule LUSTRE_KERNEL_TEST=conftest.i
  70 ],[
  71         test -s build/conftest.i
  72 ],[
  73         # LINUXRELEASE="UTS_RELEASE"
  74         eval $(grep "LINUXRELEASE=" build/conftest.i)
  75 ],[
  76         AC_MSG_RESULT([unknown])
  77         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  78 ])
  79 rm -f build/conftest.i
  80 if test x$LINUXRELEASE = x ; then
  81         AC_MSG_RESULT([unknown])
  82         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  83 fi
  84 AC_MSG_RESULT([$LINUXRELEASE])
  85 AC_SUBST(LINUXRELEASE)
  86
  87 moduledir='/lib/modules/'$LINUXRELEASE/updates/kernel
  88 AC_SUBST(moduledir)
  89
  90 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  91 AC_SUBST(modulefsdir)
  92
  93 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  94 AC_SUBST(modulenetdir)
  95
  96 # ------------ RELEASE --------------------------------
  97 AC_MSG_CHECKING([for Lustre release])
  98 AC_ARG_WITH([release],
  99         AC_HELP_STRING([--with-release=string],
 100                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
 101         [RELEASE=$withval],
 102         RELEASE=""
 103         if test -n "$DOWNSTREAM_RELEASE"; then
 104                 RELEASE="${DOWNSTREAM_RELEASE}_"
 105         fi
 106         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
 107 AC_MSG_RESULT($RELEASE)
 108 AC_SUBST(RELEASE)
 109
 110 # check is redhat/suse kernels
 111 AC_MSG_CHECKING([that RedHat kernel])
 112 LB_LINUX_TRY_COMPILE([
 113                 #include <linux/version.h>
 114         ],[
 115                 #ifndef RHEL_RELEASE_CODE
 116                 #error "not redhat kernel"
 117                 #endif
 118         ],[
 119                 RHEL_KERNEL="yes"
 120                 AC_MSG_RESULT([yes])
 121         ],[
 122                 AC_MSG_RESULT([no])
 123 ])
 124
 125 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 126
 127 ])
 128
 129 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 130 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 131         new_configure_args=
 132         eval "set x $ac_configure_args"
 133         shift
 134         for arg; do
 135                 case $arg in
 136                         --with-[$1]=*)
 137                                 arg=--with-[$1]=[$2]
 138                                 ;;
 139                         *\'*)
 140                                 arg=$(printf %s\n ["$arg"] | \
 141                                       sed "s/'/'\\\\\\\\''/g")
 142                                 ;;
 143                 esac
 144                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 145                 new_configure_args="$new_configure_args \"$arg\""
 146         done
 147         ac_configure_args=$new_configure_args
 148 ])
 149
 150 # this is the work-horse of the next function
 151 AC_DEFUN([__LB_ARG_CANON_PATH], [
 152         [$3]=$(readlink -f $with_$2)
 153         LB_ARG_REPLACE_PATH([$1], $[$3])
 154 ])
 155
 156 # a front-end for the above function that transforms - and . in the
 157 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 158 AC_DEFUN([LB_ARG_CANON_PATH], [
 159         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 160 ])
 161
 162 #
 163 #
 164 # LB_LINUX_PATH
 165 #
 166 # Find paths for linux, handling kernel-source rpms
 167 #
 168 AC_DEFUN([LB_LINUX_PATH],
 169 [# prep some default values
 170 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 171         if readlink -q -e $DEFAULT_LINUX; then
 172                 break
 173         fi
 174 done
 175 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 176         PATHS="/lib/modules/$(uname -r)/build"
 177 fi
 178 PATHS+=" $DEFAULT_LINUX"
 179 for DEFAULT_LINUX_OBJ in $PATHS; do
 180         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 181                 break
 182         fi
 183 done
 184 AC_MSG_CHECKING([for Linux sources])
 185 AC_ARG_WITH([linux],
 186         AC_HELP_STRING([--with-linux=path],
 187                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 188         [LB_ARG_CANON_PATH([linux], [LINUX])
 189         DEFAULT_LINUX_OBJ=$LINUX],
 190         [LINUX=$DEFAULT_LINUX])
 191 AC_MSG_RESULT([$LINUX])
 192 AC_SUBST(LINUX)
 193
 194 # -------- check for linux --------
 195 LB_CHECK_FILE([$LINUX],[],
 196         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 197
 198 # -------- linux objects (for 2.6) --
 199 AC_MSG_CHECKING([for Linux objects dir])
 200 AC_ARG_WITH([linux-obj],
 201         AC_HELP_STRING([--with-linux-obj=path],
 202                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 203         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 204         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 205
 206 AC_MSG_RESULT([$LINUX_OBJ])
 207 AC_SUBST(LINUX_OBJ)
 208
 209 # -------- check for .config --------
 210 AC_ARG_WITH([linux-config],
 211         [AC_HELP_STRING([--with-linux-config=path],
 212                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 213         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 214         [LINUX_CONFIG=$LINUX_OBJ/.config])
 215 AC_SUBST(LINUX_CONFIG)
 216
 217 LB_CHECK_FILE([/boot/kernel.h],
 218         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 219         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 220                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 221
 222 AC_ARG_WITH([kernel-source-header],
 223         AC_HELP_STRING([--with-kernel-source-header=path],
 224                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 225         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 226
 227 # ------------ .config exists ----------------
 228 LB_CHECK_FILE([$LINUX_CONFIG],[],
 229         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 230
 231 # ----------- make dep run? ------------------
 232 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 233 # and at more old has only one line
 234 # include <autoconf.h>
 235 LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[],
 236         [AC_MSG_ERROR([Run make config in $LINUX.])])
 237 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 238         [AC_MSG_ERROR([Run make config in $LINUX.])])
 239
 240 # ------------ rhconfig.h includes runtime-generated bits --
 241 # red hat kernel-source checks
 242
 243 # we know this exists after the check above.  if the user
 244 # tarred up the tree and ran make dep etc. in it, then
 245 # version.h gets overwritten with a standard linux one.
 246
 247 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 248         # This is a clean kernel-source tree, we need to
 249         # enable extensive workarounds to get this to build
 250         # modules
 251         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 252                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 253                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 254                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 255                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 256                 fi],
 257                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 258         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 259 fi
 260
 261 # this is needed before we can build modules
 262 LB_LINUX_UML
 263 LB_LINUX_VERSION
 264
 265 # --- check that we can build modules at all
 266 AC_MSG_CHECKING([that modules can be built at all])
 267 LB_LINUX_TRY_COMPILE([],[],[
 268         AC_MSG_RESULT([yes])
 269 ],[
 270         AC_MSG_RESULT([no])
 271         AC_MSG_WARN([Consult config.log for details.])
 272         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 273         AC_MSG_ERROR([Kernel modules cannot be built.])
 274 ])
 275
 276 LB_LINUX_RELEASE
 277 ]) # end of LB_LINUX_PATH
 278
 279 # LB_LINUX_SYMVERFILE
 280 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 281 # around this version, but it matters for servers only.
 282 AC_DEFUN([LB_LINUX_SYMVERFILE],
 283         [AC_MSG_CHECKING([name of module symbol version file])
 284         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 285                 SYMVERFILE=Modules.symvers
 286         else
 287                 SYMVERFILE=Module.symvers
 288         fi
 289         AC_MSG_RESULT($SYMVERFILE)
 290         AC_SUBST(SYMVERFILE)
 291 ])
 292
 293 #
 294 #
 295 # LB_LINUX_MODPOST
 296 #
 297 # Find modpost and check it
 298 #
 299 AC_DEFUN([LB_LINUX_MODPOST],
 300 [
 301 # Find the modpost utility
 302 LB_CHECK_FILE([$LINUX_OBJ/scripts/mod/modpost],
 303         [MODPOST=$LINUX_OBJ/scripts/mod/modpost],
 304         [LB_CHECK_FILE([$LINUX_OBJ/scripts/modpost],
 305                 [MODPOST=$LINUX_OBJ/scripts/modpost],
 306                 AC_MSG_ERROR([modpost not found.])
 307         )]
 308 )
 309 AC_SUBST(MODPOST)
 310
 311 # Ensure it can run
 312 AC_MSG_CHECKING([if modpost can be run])
 313 if $MODPOST ; then
 314         AC_MSG_RESULT([yes])
 315 else
 316         AC_MSG_ERROR([modpost can not be run.])
 317 fi
 318
 319 # Check if modpost supports (and therefore requires) -m
 320 AC_MSG_CHECKING([if modpost supports -m])
 321 if $MODPOST -m 2>/dev/null ; then
 322         AC_MSG_RESULT([yes])
 323         MODPOST_ARGS=-m
 324 else
 325         AC_MSG_RESULT([no])
 326         MODPOST_ARGS=""
 327 fi
 328 AC_SUBST(MODPOST_ARGS)
 329 ])
 330
 331 #
 332 # LB_LINUX_UML
 333 #
 334 # check for a uml kernel
 335 #
 336 AC_DEFUN([LB_LINUX_UML],
 337 [ARCH_UM=
 338 UML_CFLAGS=
 339
 340 AC_MSG_CHECKING([if you are running user mode linux for $target_cpu])
 341 if test -e $LINUX/include/asm-um ; then
 342         if test  X`ls -id $LINUX/include/asm/ 2>/dev/null | awk '{print [$]1}'` = X`ls -id $LINUX/include/asm-um 2>/dev/null | awk '{print [$]1}'` ; then
 343                 ARCH_UM='ARCH=um'
 344                 # see notes in Rules.in
 345                 UML_CFLAGS='-O0'
 346                 AC_MSG_RESULT(yes)
 347         else
 348                 AC_MSG_RESULT([no])
 349         fi
 350 else
 351         AC_MSG_RESULT([no (asm-um missing)])
 352 fi
 353 AC_SUBST(ARCH_UM)
 354 AC_SUBST(UML_CFLAGS)
 355 ])
 356
 357 # these are like AC_TRY_COMPILE, but try to build modules against the
 358 # kernel, inside the build directory
 359
 360 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 361 # --------------------------------------
 362 m4_define([LB_LANG_PROGRAM],
 363 [
 364 #include <linux/kernel.h>
 365 $1
 366 int
 367 main (void)
 368 {
 369 dnl Do *not* indent the following line: there may be CPP directives.
 370 dnl Don't move the `;' right after for the same reason.
 371 $2
 372   ;
 373   return 0;
 374 }])
 375
 376 #
 377 # LB_LINUX_COMPILE_IFELSE
 378 #
 379 # like AC_COMPILE_IFELSE
 380 #
 381 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 382 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 383 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 384 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`uname -m|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include include/linux/autoconf.h" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 385         [$4],
 386         [_AC_MSG_LOG_CONFTEST
 387 m4_ifvaln([$5],[$5])dnl])
 388 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 389 ])
 390
 391 #
 392 # LB_LINUX_ARCH
 393 #
 394 # Determine the kernel's idea of the current architecture
 395 #
 396 AC_DEFUN([LB_LINUX_ARCH],
 397          [AC_MSG_CHECKING([Linux kernel architecture])
 398           AS_IF([rm -f $PWD/build/arch
 399                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 400                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $ARCH_UM \
 401                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 402                 [AC_MSG_RESULT([$LINUX_ARCH])],
 403                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 404           rm -f build/arch])
 405
 406 #
 407 # LB_LINUX_TRY_COMPILE
 408 #
 409 # like AC_TRY_COMPILE
 410 #
 411 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 412 [LB_LINUX_COMPILE_IFELSE(
 413         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 414         [modules],
 415         [test -s build/conftest.o],
 416         [$3], [$4])])
 417
 418 #
 419 # LB_LINUX_CONFIG
 420 #
 421 # check if a given config option is defined
 422 #
 423 AC_DEFUN([LB_LINUX_CONFIG],
 424 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 425 LB_LINUX_TRY_COMPILE([
 426 #include <linux/autoconf.h>
 427 ],[
 428 #ifndef CONFIG_$1
 429 #error CONFIG_$1 not #defined
 430 #endif
 431 ],[
 432 AC_MSG_RESULT([yes])
 433 $2
 434 ],[
 435 AC_MSG_RESULT([no])
 436 $3
 437 ])
 438 ])
 439
 440 #
 441 # LB_LINUX_CONFIG_IM
 442 #
 443 # check if a given config option is builtin or as module
 444 #
 445 AC_DEFUN([LB_LINUX_CONFIG_IM],
 446 [AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 447 LB_LINUX_TRY_COMPILE([
 448 #include <linux/autoconf.h>
 449 ],[
 450 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 451 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 452 #endif
 453 ],[
 454 AC_MSG_RESULT([yes])
 455 $2
 456 ],[
 457 AC_MSG_RESULT([no])
 458 $3
 459 ])
 460 ])
 461
 462 #
 463 # LB_LINUX_TRY_MAKE
 464 #
 465 # like LB_LINUX_TRY_COMPILE, but with different arguments
 466 #
 467 AC_DEFUN([LB_LINUX_TRY_MAKE],
 468 [LB_LINUX_COMPILE_IFELSE([AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])], [$3], [$4], [$5], [$6])])
 469
 470 #
 471 # LB_LINUX_CONFIG_BIG_STACK
 472 #
 473 # check for big stack patch
 474 #
 475 AC_DEFUN([LB_LINUX_CONFIG_BIG_STACK],
 476 [if test "x$ARCH_UM" = "x" -a "x$linux25" = "xno" ; then
 477         case $target_cpu in
 478                 i?86 | x86_64)
 479                         LB_LINUX_CONFIG([STACK_SIZE_16KB],[],[
 480                                 LB_LINUX_CONFIG([STACK_SIZE_32KB],[],[
 481                                         LB_LINUX_CONFIG([STACK_SIZE_64KB],[],[
 482                                                 AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 16KB stack.])
 483                                         ])
 484                                 ])
 485                         ])
 486                         ;;
 487         esac
 488 fi
 489 ])
 490
 491 #
 492 # LB_CONFIG_OFED_BACKPORTS
 493 #
 494 # include any OFED backport headers in all compile commands
 495 # NOTE: this does only include the backport paths, not the OFED headers
 496 #       adding the OFED headers is done in the lnet portion
 497 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 498 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 499 # set default
 500 AC_ARG_WITH([o2ib],
 501         AC_HELP_STRING([--with-o2ib=path],
 502                        [build o2iblnd against path]),
 503         [
 504                 case $with_o2ib in
 505                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 506                         ENABLEO2IB=2
 507                         ;;
 508                 no)     ENABLEO2IB=0
 509                         ;;
 510                 *)      O2IBPATHS=$with_o2ib
 511                         ENABLEO2IB=3
 512                         ;;
 513                 esac
 514         ],[
 515                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 516                 ENABLEO2IB=1
 517         ])
 518 if test $ENABLEO2IB -eq 0; then
 519         AC_MSG_RESULT([no])
 520 else
 521         o2ib_found=false
 522         for O2IBPATH in $O2IBPATHS; do
 523                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 524                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 525                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 526                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 527                         o2ib_found=true
 528                         break
 529                 fi
 530         done
 531         if ! $o2ib_found; then
 532                 AC_MSG_RESULT([no])
 533                 case $ENABLEO2IB in
 534                         1) ;;
 535                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 536                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 537                         *) AC_MSG_ERROR([internal error]);;
 538                 esac
 539         else
 540                 if test -f $O2IBPATH/config.mk; then
 541                         . $O2IBPATH/config.mk
 542                 elif test -f $O2IBPATH/ofed_patch.mk; then
 543                         . $O2IBPATH/ofed_patch.mk
 544                 fi
 545                 if test -n "$BACKPORT_INCLUDES"; then
 546                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 547                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 548                         AC_MSG_RESULT([yes])
 549                 else
 550                         AC_MSG_RESULT([no])
 551                 fi
 552         fi
 553 fi
 554 ])
 555
 556 # LC_MODULE_LOADING
 557 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 558 # so we test if request_module is implemented or not
 559 AC_DEFUN([LC_MODULE_LOADING],
 560 [AC_MSG_CHECKING([if kernel module loading is possible])
 561 LB_LINUX_TRY_MAKE([
 562         #include <linux/kmod.h>
 563 ],[
 564         int myretval=ENOSYS ;
 565         return myretval;
 566 ],[
 567         $makerule LUSTRE_KERNEL_TEST=conftest.i
 568 ],[
 569         grep request_module build/conftest.i | grep -v `grep "int myretval=" build/conftest.i | cut -d= -f2 | cut -d" "  -f1` >/dev/null
 570 ],[
 571         AC_MSG_RESULT(yes)
 572         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 573                 [kernel module loading is possible])
 574 ],[
 575         AC_MSG_RESULT(no)
 576         AC_MSG_WARN([])
 577         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 578         AC_MSG_WARN([])
 579 ])
 580 ])
 581
 582 # LC_MODULE_LOADING
 583 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 584 # so we test if request_module is implemented or not
 585 AC_DEFUN([LC_MODULE_LOADING],
 586 [AC_MSG_CHECKING([if kernel module loading is possible])
 587 LB_LINUX_TRY_MAKE([
 588         #include <linux/kmod.h>
 589 ],[
 590         int myretval=ENOSYS ;
 591         return myretval;
 592 ],[
 593         $makerule LUSTRE_KERNEL_TEST=conftest.i
 594 ],[
 595         grep request_module build/conftest.i | grep -v `grep "int myretval=" build/conftest.i | cut -d= -f2 | cut -d" "  -f1` >/dev/null
 596 ],[
 597         AC_MSG_RESULT(yes)
 598         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 599                 [kernel module loading is possible])
 600 ],[
 601         AC_MSG_RESULT(no)
 602         AC_MSG_WARN([])
 603         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 604         AC_MSG_WARN([])
 605 ])
 606 ])
 607
 608 #
 609 # LB_PROG_LINUX
 610 #
 611 # linux tests
 612 #
 613 AC_DEFUN([LB_PROG_LINUX],
 614 [LB_LINUX_PATH
 615 LB_LINUX_ARCH
 616 LB_LINUX_SYMVERFILE
 617
 618
 619 LB_LINUX_CONFIG([MODULES],[],[
 620         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 621 ])
 622
 623 LB_LINUX_CONFIG([MODVERSIONS])
 624
 625 LB_LINUX_CONFIG([KALLSYMS],[],[
 626 if test "x$ARCH_UM" = "x" ; then
 627         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 628 fi
 629 ])
 630
 631 # 2.6.28
 632 LC_MODULE_LOADING
 633
 634 #LB_LINUX_CONFIG_BIG_STACK
 635
 636 # it's ugly to be doing anything with OFED outside of the lnet module, but
 637 # this has to be done here so that the backports path is set before all of
 638 # the LN_PROG_LINUX checks are done
 639 LB_CONFIG_OFED_BACKPORTS
 640 ])
 641
 642 #
 643 # LB_LINUX_CONDITIONALS
 644 #
 645 # AM_CONDITIONALS for linux
 646 #
 647 AC_DEFUN([LB_LINUX_CONDITIONALS],
 648 [AM_CONDITIONAL(LINUX25, test x$linux25 = xyes)
 649 ])
 650
 651
 652 #
 653 # LB_CHECK_SYMBOL_EXPORT
 654 # check symbol exported or not
 655 # $1 - symbol
 656 # $2 - file(s) for find.
 657 # $3 - do 'yes'
 658 # $4 - do 'no'
 659 #
 660 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 661 # or check
 662 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 663 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 664 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 665 rc=$?
 666 if test $rc -ne 0; then
 667     export=0
 668     for file in $2; do
 669         grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 670         rc=$?
 671         if test $rc -eq 0; then
 672                 export=1
 673                 break;
 674         fi
 675     done
 676     if test $export -eq 0; then
 677         AC_MSG_RESULT([no])
 678         $4
 679     else
 680         AC_MSG_RESULT([yes])
 681         $3
 682     fi
 683 else
 684     AC_MSG_RESULT([yes])
 685     $3
 686 fi
 687 ])
 688
 689 #
 690 # Like AC_CHECK_HEADER but checks for a kernel-space header
 691 #
 692 m4_define([LB_CHECK_LINUX_HEADER],
 693 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 694 AC_CACHE_CHECK([for $1], ac_Header,
 695                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 696                                   [modules],
 697                                   [test -s build/conftest.o],
 698                                   [AS_VAR_SET(ac_Header, [yes])],
 699                                   [AS_VAR_SET(ac_Header, [no])])])
 700 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 701 AS_VAR_POPDEF([ac_Header])dnl
 702 ])
 703
 704 #
 705 # LB_USES_DPKG
 706 #
 707 # Determine if the target is a dpkg system or rpm
 708 #
 709 AC_DEFUN([LB_USES_DPKG],
 710 [
 711 AC_MSG_CHECKING([if this distro uses dpkg])
 712 case `lsb_release -i -s 2>/dev/null` in
 713         Ubuntu | Debian)
 714                 AC_MSG_RESULT([yes])
 715                 uses_dpkg=yes
 716                 ;;
 717         *)
 718                 AC_MSG_RESULT([no])
 719                 uses_dpkg=no
 720                 ;;
 721 esac
 722 ])