build/autoconf/lustre-build-ldiskfs.m4

   1 #
   2 # LB_PATH_LDISKFS
   3 #
   4 # --without-ldiskfs   - Disable ldiskfs support.
   5 # --with-ldiskfs=no
   6 #
   7 # --with-ldiskfs      - Enable ldiskfs support and attempt to autodetect the
   8 # --with-ldiskfs=yes    headers in one of the following places in this order:
   9 #                       * ./ldiskfs
  10 #                       * /usr/src/ldiskfs-*/$LINUXRELEASE
  11 #                       * ../ldiskfs
  12 #
  13 # --with-ldiskfs=path - Enable ldiskfs support and use the headers in the
  14 #                       provided path.  No autodetection is performed.
  15 #
  16 # --with-ldiskfs-obj  - When ldiskfs support is enabled the object directory
  17 #                       will be based on the --with-ldiskfs directory.  If
  18 #                       this is detected incorrectly it can be explicitly
  19 #                       specified using this option.
  20 #
  21 # NOTE: As with all external packages ldiskfs is expected to already be
  22 # configured and built.  However, if the ldiskfs tree is located in-tree
  23 # (./ldiskfs) then it will be configured and built recursively as part of
  24 # the lustre build system.
  25 #
  26 # NOTE: The lustre and in-tree ldiskfs build systems both make use these
  27 # macros.  This is undesirable and confusing at best, it is potentially
  28 # danagerous at worst.  The ldiskfs build system should be entirely stand
  29 # alone without dependency on the lustre build system.
  30 #
  31 AC_DEFUN([LB_PATH_LDISKFS],
  32 [
  33 AC_ARG_WITH([ldiskfs],
  34         AC_HELP_STRING([--with-ldiskfs=path], [set path to ldiskfs source]),
  35         [],[
  36                 if test x$enable_server = xyes && test x$enable_dist = xno; then
  37                         with_ldiskfs='yes'
  38                 else
  39                         with_ldiskfs='no'
  40                 fi
  41         ])
  42
  43 case x$with_ldiskfs in
  44         xno)
  45                 LDISKFS_DIR=
  46                 ;;
  47         xyes)
  48                 LDISKFS_DIR=
  49
  50                 # Check ./ldiskfs
  51                 ldiskfs_src=$PWD/ldiskfs
  52                 if test -e "$ldiskfs_src"; then
  53                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  54                 else
  55                         # Check /usr/src/ldiskfs-*/$LINUXRELEASE
  56                         ldiskfs_src=$(ls -1d \
  57                                 /usr/src/ldiskfs-*/$LINUXRELEASE \
  58                                 2>/dev/null | tail -1)
  59                         if test -e "$ldiskfs_src"; then
  60                                 LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  61                         else
  62                                 # Check ../ldiskfs
  63                                 ldiskfs_src=$PWD/../ldiskfs
  64                                 if test -e "$ldiskfs_src"; then
  65                                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  66                                 else
  67                                         # Disable ldiskfs failed to detect
  68                                         with_ldiskfs='no'
  69                                 fi
  70                         fi
  71                 fi
  72
  73                 ;;
  74         *)
  75                 LDISKFS_DIR=$(readlink -f $with_ldiskfs)
  76                 with_ldiskfs='yes'
  77                 ;;
  78 esac
  79
  80 AC_MSG_CHECKING([whether to enable ldiskfs])
  81 AC_MSG_RESULT([$with_ldiskfs])
  82
  83 AC_ARG_WITH([ldiskfs-obj],
  84         AC_HELP_STRING([--with-ldiskfs-obj=path],[set path to ldiskfs objects]),
  85         [
  86                 if test x$with_ldiskfs = xyes; then
  87                         LDISKFS_OBJ="$withval"
  88                 fi
  89         ],[
  90                 if test x$with_ldiskfs = xyes; then
  91                         LDISKFS_OBJ=$LDISKFS_DIR
  92                 fi
  93         ])
  94
  95 if test x$with_ldiskfs = xyes; then
  96         AC_MSG_CHECKING([ldiskfs source directory])
  97         AC_MSG_RESULT([$LDISKFS_DIR])
  98         AC_SUBST(LDISKFS_DIR)
  99
 100         AC_MSG_CHECKING([ldiskfs object directory])
 101         AC_MSG_RESULT([$LDISKFS_OBJ])
 102         AC_SUBST(LDISKFS_OBJ)
 103
 104         LB_LDISKFS_SYMVERS
 105         LB_LDISKFS_RELEASE
 106         LB_LDISKFS_EXT_DIR
 107         LB_LDISKFS_BUILD
 108         LB_LDISKFS_DEFINE_OPTIONS
 109 fi
 110
 111 #
 112 # LDISKFS_DEVEL is required because when using the ldiskfs-devel package the
 113 # ext4 source will be fully patched to ldiskfs.  When building with the
 114 # in-tree ldiskfs this patching this will occur after the configure step.
 115 # We needed a way to determine if we should check the patched or unpatched
 116 # source files.
 117 #
 118 # Longer term this could be removed by moving the ldiskfs patching in to
 119 # the configure phase.  Or better yet ldiskfs could be updated to generate
 120 # a ldiskfs_config.h which clearly defines how it was built.  This can
 121 # then be directly included by Lustre to avoid all the autoconf guess work.
 122 # For an example of this behavior consult the lustre/zfs build integration.
 123 #
 124 AM_CONDITIONAL(LDISKFS_DEVEL, \
 125         test x$LDISKFS_DIR = x$(readlink -f $PWD/ldiskfs) || \
 126         test x$LDISKFS_DIR = x$(readlink -f $PWD/../ldiskfs))
 127
 128 AM_CONDITIONAL(LDISKFS_BUILD, test x$enable_ldiskfs_build = xyes)
 129 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs = xyes)
 130
 131 if test -e "$PWD/ldiskfs"; then
 132         LDISKFS_DIST_SUBDIR="ldiskfs"
 133         AC_SUBST(LDISKFS_DIST_SUBDIR)
 134         AC_CONFIG_SUBDIRS("ldiskfs")
 135 fi
 136 ])
 137
 138 #
 139 # LB_LDISKFS_EXT_DIR
 140 #
 141 # Determine the location of the ext4 source code.  It it required
 142 # for several configure tests and to build ldiskfs.
 143 #
 144 AC_DEFUN([LB_LDISKFS_EXT_DIR],
 145 [
 146 # Kernel ext source located with devel headers
 147 linux_src=$LINUX
 148 if test -e "$linux_src/fs/ext4/super.c"; then
 149         EXT_DIR=$linux_src/fs/ext4
 150 else
 151         # Kernel ext source provided by kernel-debuginfo-common package
 152         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 153                 2>/dev/null | tail -1)
 154         if test -e "$linux_src/fs/ext4/super.c"; then
 155                 EXT_DIR=$linux_src/fs/ext4
 156         else
 157                 EXT_DIR=
 158         fi
 159 fi
 160
 161 AC_MSG_CHECKING([ext4 source directory])
 162 AC_MSG_RESULT([$EXT_DIR])
 163 AC_SUBST(EXT_DIR)
 164 ])
 165
 166 #
 167 # LB_LDISKFS_EXT_SOURCE
 168 #
 169 # Spot check the existance of several source files common to ext4.
 170 # Detecting this at configure time allows us to avoid a potential build
 171 # failure and provide a useful error message to explain what is wrong.
 172 #
 173 AC_DEFUN([LB_LDISKFS_EXT_SOURCE],
 174 [
 175 if test x$EXT_DIR = x; then
 176         enable_ldiskfs_build='no'
 177 else
 178         LB_CHECK_FILE([$EXT_DIR/dir.c], [], [
 179                 enable_ldiskfs_build='no'
 180                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 181         LB_CHECK_FILE([$EXT_DIR/file.c], [], [
 182                 enable_ldiskfs_build='no'
 183                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 184         LB_CHECK_FILE([$EXT_DIR/inode.c], [], [
 185                 enable_ldiskfs_build='no'
 186                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 187         LB_CHECK_FILE([$EXT_DIR/super.c], [], [
 188                 enable_ldiskfs_build='no'
 189                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 190 fi
 191
 192 if test x$enable_ldiskfs_build = xno; then
 193         enable_server='no'
 194         enable_ldiskfs_build='no'
 195         with_ldiskfs='no'
 196         LDISKFS_SUBDIR=
 197
 198         AC_MSG_WARN([
 199
 200 Disabling server because complete ext4 source does not exist.
 201
 202 If you are building using kernel-devel packages and require ldiskfs
 203 server support then ensure that the matching kernel-debuginfo-common
 204 and kernel-debuginfo-common-<arch> packages are installed.
 205
 206 ])
 207
 208 fi
 209 ])
 210
 211 #
 212 # LB_LDISKFS_DEFINE_OPTIONS
 213 #
 214 # Enable config options related to ldiskfs.  These are used by ldiskfs,
 215 # lvfs, and the osd-ldiskfs code (which includes ldiskfs headers.)
 216 #
 217 AC_DEFUN([LB_LDISKFS_DEFINE_OPTIONS],
 218 [
 219 AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 220
 221 with_ldiskfs_pdo=no
 222 case $LINUXRELEASE in
 223 2.6.32*)
 224         if test x$RHEL_KERNEL = xyes; then
 225                 with_ldiskfs_pdo=yes
 226                 AC_DEFINE(HAVE_LDISKFS_PDO, 1, [have ldiskfs PDO patch])
 227         fi
 228         if test x$SUSE_KERNEL = xyes; then
 229                 with_ldiskfs_pdo=yes
 230                 AC_DEFINE(HAVE_LDISKFS_PDO, 1, [have ldiskfs PDO patch])
 231         fi
 232         ;;
 233 esac
 234 LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET
 235
 236 AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1,
 237         [enable extended attributes for ldiskfs])
 238 AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1,
 239         [enable posix acls for ldiskfs])
 240 AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1,
 241         [enable fs security for ldiskfs])
 242 AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1,
 243         [enable posix acls for ldiskfs])
 244 AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1,
 245         [enable extented attributes for ldiskfs])
 246 AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1,
 247         [enable fs security for ldiskfs])
 248 ])
 249
 250 #
 251 # Check for jbd2_journal_callback_set(), which is needed for commit
 252 # callbacks.  When LU-433 lands jbd2_journal_callback_set() will only
 253 # remain for legacy reasons and AC_MSG_ERROR can be removed.
 254 #
 255 AC_DEFUN([LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET],
 256 [
 257         LB_CHECK_SYMBOL_EXPORT([jbd2_journal_callback_set],
 258                 [fs/jbd2/journal.c],
 259                 [AC_DEFINE(HAVE_JBD2_JOURNAL_CALLBACK_SET, 1,
 260                         [kernel exports jbd2_journal_callback_set])])
 261 ])
 262
 263 #
 264 # Optionally configure/make the ldiskfs sources.  If the sources are
 265 # determined to reside in-tree this feature will automatically be
 266 # enabled.  If the sources are not in-tree it will be disabled.
 267 # Use --enable-ldiskfs-build or --disable-ldiskfs-build if you need
 268 # to override this behavior.
 269 #
 270 AC_DEFUN([LB_LDISKFS_BUILD],
 271 [
 272 AC_ARG_ENABLE([ldiskfs-build],
 273         AC_HELP_STRING([--enable-ldiskfs-build],
 274                 [enable ldiskfs configure/make]),
 275         [], [
 276                 LDISKFS_DIR_INTREE=$(readlink -f $PWD/ldiskfs)
 277                 if test x$LDISKFS_DIR = x$LDISKFS_DIR_INTREE; then
 278                         enable_ldiskfs_build='yes'
 279                 else
 280                         enable_ldiskfs_build='no'
 281                 fi
 282         ])
 283
 284 AC_MSG_CHECKING([whether to build ldiskfs])
 285 if test x$enable_ldiskfs_build = xyes; then
 286         AC_MSG_RESULT([$enable_ldiskfs_build])
 287         LDISKFS_SUBDIR="ldiskfs"
 288
 289         LB_CHECK_FILE([$LDISKFS_DIR/configure], [], [
 290                 AC_MSG_ERROR([Complete ldiskfs build system must exist])])
 291         LB_LDISKFS_EXT_SOURCE
 292
 293         AC_SUBST(LDISKFS_SUBDIR)
 294 else
 295         enable_ldiskfs_build='no'
 296         AC_MSG_RESULT([$enable_ldiskfs_build])
 297 fi
 298 ])
 299
 300 AC_DEFUN([LB_LDISKFS_SYMVERS],
 301 [
 302 AC_MSG_CHECKING([ldiskfs module symbols])
 303 if test -r $LDISKFS_OBJ/Module.symvers; then
 304         LDISKFS_SYMBOLS=Module.symvers
 305 elif test -r $LDISKFS_OBJ/Modules.symvers; then
 306         LDISKFS_SYMBOLS=Modules.symvers
 307 elif test -r $LDISKFS_OBJ/ldiskfs/Module.symvers; then
 308         LDISKFS_SYMBOLS=Module.symvers
 309 elif test -r $LDISKFS_OBJ/ldiskfs/Modules.symvers; then
 310         LDISKFS_SYMBOLS=Modules.symvers
 311 else
 312         LDISKFS_SYMBOLS=$SYMVERFILE
 313 fi
 314
 315 AC_MSG_RESULT([$LDISKFS_SYMBOLS])
 316 AC_SUBST(LDISKFS_SYMBOLS)
 317 ])
 318
 319 AC_DEFUN([LB_LDISKFS_RELEASE],
 320 [
 321 AC_MSG_CHECKING([ldiskfs source release])
 322 if test -r $LDISKFS_OBJ/config.h; then
 323         tmp_flags="$EXTRA_KCFLAGS"
 324         EXTRA_KCFLAGS="-I$LDISKFS_DIR $EXTRA_KCFLAGS"
 325         LB_LINUX_TRY_MAKE([
 326                 #undef PACKAGE_NAME
 327                 #undef PACKAGE_TARNAME
 328                 #undef PACKAGE_VERSION
 329                 #undef PACKAGE_STRING
 330                 #undef PACKAGE_BUGREPORT
 331                 #undef PACKAGE
 332                 #undef VERSION
 333                 #undef STDC_HEADERS
 334
 335                 #include <$LDISKFS_OBJ/config.h>
 336         ],[
 337                 char *LDISKFS_RELEASE;
 338                 LDISKFS_RELEASE=VERSION;
 339         ],[
 340                 $makerule LUSTRE_KERNEL_TEST=conftest.i
 341         ],[
 342                 test -s build/conftest.i
 343         ],[
 344                 eval $(grep "LDISKFS_RELEASE=" build/conftest.i)
 345         ],[
 346                 AC_MSG_RESULT([unknown])
 347                 AC_MSG_ERROR([Could not preprocess test program.])
 348         ])
 349         EXTRA_KCFLAGS="$tmp_flags"
 350         rm build/conftest.i
 351 elif test -r $LDISKFS_DIR/configure.ac; then
 352         LDISKFS_RELEASE=$(awk '/AC\_INIT/ { print [$]3 }' \
 353                  $LDISKFS_DIR/configure.ac | tr ',' '\n')
 354 else
 355         AC_MSG_RESULT([unknown])
 356         AC_MSG_ERROR([Could not locate config.h, META, or configure.ac to check release.])
 357 fi
 358
 359 if test x$LDISKFS_RELEASE = x; then
 360         AC_MSG_RESULT([unknown])
 361         AC_MSG_ERROR([Could not determine ldiskfs release.])
 362 fi
 363
 364 AC_MSG_RESULT([$LDISKFS_RELEASE])
 365 AC_SUBST(LDISKFS_RELEASE)
 366 ])
 367
 368 #
 369 # LB_DEFINE_E2FSPROGS_NAMES
 370 #
 371 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 372 #
 373 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 374 [
 375 AC_ARG_WITH([ldiskfsprogs],
 376         AC_HELP_STRING([--with-ldiskfsprogs],
 377                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 378         [],[withval='no'])
 379
 380 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 381 if test x$withval = xyes ; then
 382         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 383         E2FSPROGS="ldiskfsprogs"
 384         MKE2FS="mkfs.ldiskfs"
 385         DEBUGFS="debugfs.ldiskfs"
 386         TUNE2FS="tunefs.ldiskfs"
 387         E2LABEL="label.ldiskfs"
 388         DUMPE2FS="dumpfs.ldiskfs"
 389         E2FSCK="fsck.ldiskfs"
 390         PFSCK="pfsck.ldiskfs"
 391         AC_MSG_RESULT([enabled])
 392 else
 393         E2FSPROGS="e2fsprogs"
 394         MKE2FS="mke2fs"
 395         DEBUGFS="debugfs"
 396         TUNE2FS="tune2fs"
 397         E2LABEL="e2label"
 398         DUMPE2FS="dumpe2fs"
 399         E2FSCK="e2fsck"
 400         PFSCK="fsck"
 401         AC_MSG_RESULT([disabled])
 402 fi
 403
 404 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 405 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 406 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 407 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 408 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 409 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 410 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 411 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 412
 413 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 414 AC_SUBST([MKE2FS], [$MKE2FS])
 415 AC_SUBST([DEBUGFS], [$DEBUGFS])
 416 AC_SUBST([TUNE2FS], [$TUNE2FS])
 417 AC_SUBST([E2LABEL], [$E2LABEL])
 418 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 419 AC_SUBST([E2FSCK], [$E2FSCK])
 420 AC_SUBST([PFSCK], [$PFSCK])
 421 ])
 422
 423 AC_DEFUN([LB_LDISKFS_SERIES],
 424 [
 425 if $1; then
 426         AC_MSG_CHECKING([which ldiskfs series to use])
 427         case $LINUXRELEASE in
 428         2.6.18*)
 429                 if test x$RHEL_KERNEL = xyes; then
 430                         LDISKFS_SERIES="2.6-rhel5-ext4.series"
 431                 fi
 432                 ;;
 433         2.6.32*)
 434                 if test x$RHEL_KERNEL = xyes; then
 435                         LDISKFS_SERIES="2.6-rhel6.series"
 436                 fi
 437                 if test x$SUSE_KERNEL = xyes; then
 438                         LDISKFS_SERIES="2.6-sles11.series"
 439                 fi
 440                 ;;
 441         *)
 442                 AC_MSG_WARN([Unknown kernel version $LINUXRELEASE])
 443                 LDISKFS_SERIES=
 444                 ;;
 445         esac
 446         AC_MSG_RESULT([$LDISKFS_SERIES])
 447 else
 448         LDISKFS_SERIES=
 449 fi
 450 AC_SUBST(LDISKFS_SERIES)
 451 ])