build/autoconf/lustre-build-ldiskfs.m4

   1 #
   2 # LB_PATH_LDISKFS
   3 #
   4 # --without-ldiskfs   - Disable ldiskfs support.
   5 # --with-ldiskfs=no
   6 #
   7 # --with-ldiskfs      - Enable ldiskfs support and attempt to autodetect the
   8 # --with-ldiskfs=yes    headers in one of the following places in this order:
   9 #                       * ./ldiskfs
  10 #                       * /usr/src/ldiskfs-*/$LINUXRELEASE
  11 #                       * ../ldiskfs
  12 #
  13 # --with-ldiskfs=path - Enable ldiskfs support and use the headers in the
  14 #                       provided path.  No autodetection is performed.
  15 #
  16 # --with-ldiskfs-obj  - When ldiskfs support is enabled the object directory
  17 #                       will be based on the --with-ldiskfs directory.  If
  18 #                       this is detected incorrectly it can be explicitly
  19 #                       specified using this option.
  20 #
  21 # NOTE: As with all external packages ldiskfs is expected to already be
  22 # configured and built.  However, if the ldiskfs tree is located in-tree
  23 # (./ldiskfs) then it will be configured and built recursively as part of
  24 # the lustre build system.
  25 #
  26 # NOTE: The lustre and in-tree ldiskfs build systems both make use these
  27 # macros.  This is undesirable and confusing at best, it is potentially
  28 # danagerous at worst.  The ldiskfs build system should be entirely stand
  29 # alone without dependency on the lustre build system.
  30 #
  31 AC_DEFUN([LB_PATH_LDISKFS],
  32 [
  33 AC_ARG_WITH([ldiskfs],
  34         AC_HELP_STRING([--with-ldiskfs=path], [set path to ldiskfs source]),
  35         [],[
  36                 if test x$enable_server = xyes && test x$enable_dist = xno; then
  37                         with_ldiskfs='yes'
  38                 else
  39                         with_ldiskfs='no'
  40                 fi
  41         ])
  42
  43 case x$with_ldiskfs in
  44         xno)
  45                 LDISKFS_DIR=
  46                 ;;
  47         xyes)
  48                 LDISKFS_DIR=
  49
  50                 # Check ./ldiskfs
  51                 ldiskfs_src=$PWD/ldiskfs
  52                 if test -e "$ldiskfs_src"; then
  53                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  54                 else
  55                         # Check /usr/src/ldiskfs-*/$LINUXRELEASE
  56                         ldiskfs_src=$(ls -1d \
  57                                 /usr/src/ldiskfs-*/$LINUXRELEASE \
  58                                 2>/dev/null | tail -1)
  59                         if test -e "$ldiskfs_src"; then
  60                                 LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  61                         else
  62                                 # Check ../ldiskfs
  63                                 ldiskfs_src=$PWD/../ldiskfs
  64                                 if test -e "$ldiskfs_src"; then
  65                                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  66                                 else
  67                                         # Disable ldiskfs failed to detect
  68                                         with_ldiskfs='no'
  69                                 fi
  70                         fi
  71                 fi
  72
  73                 ;;
  74         *)
  75                 LDISKFS_DIR=$(readlink -f $with_ldiskfs)
  76                 with_ldiskfs='yes'
  77                 ;;
  78 esac
  79
  80 AC_MSG_CHECKING([whether to enable ldiskfs])
  81 AC_MSG_RESULT([$with_ldiskfs])
  82
  83 AC_ARG_WITH([ldiskfs-obj],
  84         AC_HELP_STRING([--with-ldiskfs-obj=path],[set path to ldiskfs objects]),
  85         [
  86                 if test x$with_ldiskfs = xyes; then
  87                         LDISKFS_OBJ="$withval"
  88                 fi
  89         ],[
  90                 if test x$with_ldiskfs = xyes; then
  91                         LDISKFS_OBJ=$LDISKFS_DIR
  92                 fi
  93         ])
  94
  95 if test x$with_ldiskfs = xyes; then
  96         AC_MSG_CHECKING([ldiskfs source directory])
  97         AC_MSG_RESULT([$LDISKFS_DIR])
  98         AC_SUBST(LDISKFS_DIR)
  99
 100         AC_MSG_CHECKING([ldiskfs object directory])
 101         AC_MSG_RESULT([$LDISKFS_OBJ])
 102         AC_SUBST(LDISKFS_OBJ)
 103
 104         LB_LDISKFS_SYMVERS
 105         LB_LDISKFS_RELEASE
 106         LB_LDISKFS_EXT_RELEASE
 107         LB_LDISKFS_EXT_DIR
 108         LB_LDISKFS_BUILD
 109         LB_LDISKFS_DEFINE_OPTIONS
 110 fi
 111
 112 #
 113 # LDISKFS_DEVEL is required because when using the ldiskfs-devel package the
 114 # ext3/4 source will be fully patched to ldiskfs.  When building with the
 115 # in-tree ldiskfs this patching this will occur after the configure step.
 116 # We needed a way to determine if we should check the patched or unpatched
 117 # source files.
 118 #
 119 # Longer term this could be removed by moving the ldiskfs patching in to
 120 # the configure phase.  Or better yet ldiskfs could be updated to generate
 121 # a ldiskfs_config.h which clearly defines how it was built.  This can
 122 # then be directly included by Lustre to avoid all the autoconf guess work.
 123 # For an example of this behavior consult the lustre/zfs build integration.
 124 #
 125 AM_CONDITIONAL(LDISKFS_DEVEL, \
 126         test x$LDISKFS_DIR = x$(readlink -f $PWD/ldiskfs) || \
 127         test x$LDISKFS_DIR = x$(readlink -f $PWD/../ldiskfs))
 128
 129 AM_CONDITIONAL(LDISKFS_BUILD, test x$enable_ldiskfs_build = xyes)
 130 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs = xyes)
 131
 132 if test -e "$PWD/ldiskfs"; then
 133         LDISKFS_DIST_SUBDIR="ldiskfs"
 134         AC_SUBST(LDISKFS_DIST_SUBDIR)
 135         AC_CONFIG_SUBDIRS("ldiskfs")
 136 fi
 137 ])
 138
 139 #
 140 # LB_LDISKFS_EXT_RELEASE
 141 #
 142 # Determine if ext3 or ext4 sources should be used for ldiskfs.
 143 #
 144 AC_DEFUN([LB_LDISKFS_EXT_RELEASE],
 145 [
 146 AC_ARG_ENABLE([ext4],
 147          AC_HELP_STRING([--enable-ext4], [enable ldiskfs build using ext4]),
 148         [],
 149         [
 150                 if test x$RHEL_KERNEL = xyes; then
 151                         enable_ext4='yes'
 152                 else
 153                         # 2.6.22-2.6.26 ext4 available but unstable
 154                         case x$LINUXRELEASE in
 155                         x2.6.2[[0-6]]*)
 156                                 enable_ext4='no' ;;
 157                         *)
 158                                 enable_ext4='yes' ;;
 159                         esac
 160                 fi
 161         ])
 162
 163 if test x$enable_ext4 = xyes; then
 164         LDISKFS_BACKFS='ext4'
 165 else
 166         LDISKFS_BACKFS='ext3'
 167 fi
 168
 169 AC_MSG_CHECKING([whether to use ext3 or ext4 source])
 170 AC_MSG_RESULT([$LDISKFS_BACKFS])
 171 AC_SUBST(LDISKFS_BACKFS)
 172 ])
 173
 174 #
 175 # LB_LDISKFS_EXT_DIR
 176 #
 177 # Determine the location of the ext3/ext4 source code.  It it required
 178 # for several configure tests and to build ldiskfs.
 179 #
 180 AC_DEFUN([LB_LDISKFS_EXT_DIR],
 181 [
 182 # Kernel ext source located with devel headers
 183 linux_src=$LINUX
 184 if test -e "$linux_src/fs/$LDISKFS_BACKFS/super.c"; then
 185         EXT_DIR=$linux_src/fs/$LDISKFS_BACKFS
 186 else
 187         # Kernel ext source provided by kernel-debuginfo-common package
 188         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 189                 2>/dev/null | tail -1)
 190         if test -e "$linux_src/fs/$LDISKFS_BACKFS/super.c"; then
 191                 EXT_DIR=$linux_src/fs/$LDISKFS_BACKFS
 192         else
 193                 EXT_DIR=
 194         fi
 195 fi
 196
 197 AC_MSG_CHECKING([$LDISKFS_BACKFS source directory])
 198 AC_MSG_RESULT([$EXT_DIR])
 199 AC_SUBST(EXT_DIR)
 200 ])
 201
 202 #
 203 # LB_LDISKFS_EXT_SOURCE
 204 #
 205 # Spot check the existance of several source files common to ext3/ext4.
 206 # Detecting this at configure time allows us to avoid a potential build
 207 # failure and provide a useful error message to explain what is wrong.
 208 #
 209 AC_DEFUN([LB_LDISKFS_EXT_SOURCE],
 210 [
 211 if test x$EXT_DIR = x; then
 212         AC_MSG_ERROR([Complete $LDISKFS_BACKFS source must exist.
 213
 214 If you are building using kernel-devel packages then ensure that the
 215 matching kernel-debuginfo-common and kernel-debuginfo-common-<arch>
 216 packages are installed.])
 217 fi
 218
 219 LB_CHECK_FILE([$EXT_DIR/dir.c], [], [ AC_MSG_ERROR(
 220         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 221 LB_CHECK_FILE([$EXT_DIR/file.c], [], [ AC_MSG_ERROR(
 222         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 223 LB_CHECK_FILE([$EXT_DIR/inode.c], [], [ AC_MSG_ERROR(
 224         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 225 LB_CHECK_FILE([$EXT_DIR/super.c], [], [ AC_MSG_ERROR(
 226         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 227 ])
 228
 229 #
 230 # LB_LDISKFS_DEFINE_OPTIONS
 231 #
 232 # Enable config options related to ldiskfs.  These are used by ldiskfs,
 233 # lvfs, and the osd-ldiskfs code (which includes ldiskfs headers.)
 234 #
 235 AC_DEFUN([LB_LDISKFS_DEFINE_OPTIONS],
 236 [
 237 AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 238
 239 if test $LDISKFS_BACKFS = 'ext4'; then
 240         AC_DEFINE(HAVE_EXT4_LDISKFS, 1, [build ext4 based ldiskfs])
 241 fi
 242
 243 LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET
 244
 245 AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1,
 246         [enable extended attributes for ldiskfs])
 247 AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1,
 248         [enable posix acls for ldiskfs])
 249 AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1,
 250         [enable fs security for ldiskfs])
 251 AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1,
 252         [enable posix acls for ldiskfs])
 253 AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1,
 254         [enable extented attributes for ldiskfs])
 255 AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1,
 256         [enable fs security for ldiskfs])
 257 ])
 258
 259 #
 260 # Check for jbd2_journal_callback_set(), which is needed for commit
 261 # callbacks.  When LU-433 lands jbd2_journal_callback_set() will only
 262 # remain for legacy reasons and AC_MSG_ERROR can be removed.
 263 #
 264 # 2.6.18 with ext3 still uses journal_callback_set() for commit callbacks.
 265 #
 266 AC_DEFUN([LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET],
 267 [
 268         LB_CHECK_SYMBOL_EXPORT([jbd2_journal_callback_set],
 269         [fs/jbd2/journal.c],
 270         [AC_DEFINE(HAVE_JBD2_JOURNAL_CALLBACK_SET, 1,
 271                 [kernel exports jbd2_journal_callback_set])],
 272         [LB_CHECK_SYMBOL_EXPORT([journal_callback_set],
 273                 [fs/jbd/journal.c],
 274                 [AC_DEFINE(HAVE_JOURNAL_CALLBACK_SET, 1,
 275                         [kernel exports journal_callback_set])],
 276                 [if test x$with_ldiskfs != xno ; then
 277                         AC_MSG_ERROR([ldiskfs needs jbd2-jcberr patch])
 278                 fi])])
 279 ])
 280
 281 #
 282 # Optionally configure/make the ldiskfs sources.  If the sources are
 283 # determined to reside in-tree this feature will automatically be
 284 # enabled.  If the sources are not in-tree it will be disabled.
 285 # Use --enable-ldiskfs-build or --disable-ldiskfs-build if you need
 286 # to override this behavior.
 287 #
 288 AC_DEFUN([LB_LDISKFS_BUILD],
 289 [
 290 AC_ARG_ENABLE([ldiskfs-build],
 291         AC_HELP_STRING([--enable-ldiskfs-build],
 292                 [enable ldiskfs configure/make]),
 293         [], [
 294                 LDISKFS_DIR_INTREE=$(readlink -f $PWD/ldiskfs)
 295                 if test x$LDISKFS_DIR = x$LDISKFS_DIR_INTREE; then
 296                         enable_ldiskfs_build='yes'
 297                 else
 298                         enable_ldiskfs_build='no'
 299                 fi
 300         ])
 301
 302 AC_MSG_CHECKING([whether to build ldiskfs])
 303 if test x$enable_ldiskfs_build = xyes; then
 304         AC_MSG_RESULT([$enable_ldiskfs_build])
 305
 306         LB_CHECK_FILE([$LDISKFS_DIR/configure], [], [
 307                 AC_MSG_ERROR([Complete ldiskfs build system must exist])])
 308         LB_LDISKFS_EXT_SOURCE
 309
 310         LDISKFS_SUBDIR="ldiskfs"
 311         AC_SUBST(LDISKFS_SUBDIR)
 312 else
 313         enable_ldiskfs_build='no'
 314         AC_MSG_RESULT([$enable_ldiskfs_build])
 315 fi
 316 ])
 317
 318 AC_DEFUN([LB_LDISKFS_SYMVERS],
 319 [
 320 AC_MSG_CHECKING([ldiskfs module symbols])
 321 if test -r $LDISKFS_OBJ/Module.symvers; then
 322         LDISKFS_SYMBOLS=Module.symvers
 323 elif test -r $LDISKFS_OBJ/Modules.symvers; then
 324         LDISKFS_SYMBOLS=Modules.symvers
 325 elif test -r $LDISKFS_OBJ/ldiskfs/Module.symvers; then
 326         LDISKFS_SYMBOLS=Module.symvers
 327 elif test -r $LDISKFS_OBJ/ldiskfs/Modules.symvers; then
 328         LDISKFS_SYMBOLS=Modules.symvers
 329 else
 330         LDISKFS_SYMBOLS=$SYMVERFILE
 331 fi
 332
 333 AC_MSG_RESULT([$LDISKFS_SYMBOLS])
 334 AC_SUBST(LDISKFS_SYMBOLS)
 335 ])
 336
 337 AC_DEFUN([LB_LDISKFS_RELEASE],
 338 [
 339 AC_MSG_CHECKING([ldiskfs source release])
 340 if test -r $LDISKFS_OBJ/config.h; then
 341         tmp_flags="$EXTRA_KCFLAGS"
 342         EXTRA_KCFLAGS="-I$LDISKFS_DIR $EXTRA_KCFLAGS"
 343         LB_LINUX_TRY_MAKE([
 344                 #undef PACKAGE_NAME
 345                 #undef PACKAGE_TARNAME
 346                 #undef PACKAGE_VERSION
 347                 #undef PACKAGE_STRING
 348                 #undef PACKAGE_BUGREPORT
 349                 #undef PACKAGE
 350                 #undef VERSION
 351                 #undef STDC_HEADERS
 352
 353                 #include <$LDISKFS_OBJ/config.h>
 354         ],[
 355                 char *LDISKFS_RELEASE;
 356                 LDISKFS_RELEASE=VERSION;
 357         ],[
 358                 $makerule LUSTRE_KERNEL_TEST=conftest.i
 359         ],[
 360                 test -s build/conftest.i
 361         ],[
 362                 eval $(grep "LDISKFS_RELEASE=" build/conftest.i)
 363         ],[
 364                 AC_MSG_RESULT([unknown])
 365                 AC_MSG_ERROR([Could not preprocess test program.])
 366         ])
 367         EXTRA_KCFLAGS="$tmp_flags"
 368         rm build/conftest.i
 369 elif test -r $LDISKFS_DIR/configure.ac; then
 370         LDISKFS_RELEASE=$(awk '/AC\_INIT/ { print [$]3 }' \
 371                  $LDISKFS_DIR/configure.ac | tr ',' '\n')
 372 else
 373         AC_MSG_RESULT([unknown])
 374         AC_MSG_ERROR([Could not locate config.h, META, or configure.ac to check release.])
 375 fi
 376
 377 if test x$LDISKFS_RELEASE = x; then
 378         AC_MSG_RESULT([unknown])
 379         AC_MSG_ERROR([Could not determine ldiskfs release.])
 380 fi
 381
 382 AC_MSG_RESULT([$LDISKFS_RELEASE])
 383 AC_SUBST(LDISKFS_RELEASE)
 384 ])
 385
 386 #
 387 # LB_DEFINE_E2FSPROGS_NAMES
 388 #
 389 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 390 #
 391 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 392 [
 393 AC_ARG_WITH([ldiskfsprogs],
 394         AC_HELP_STRING([--with-ldiskfsprogs],
 395                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 396         [],[withval='no'])
 397
 398 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 399 if test x$withval = xyes ; then
 400         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 401         E2FSPROGS="ldiskfsprogs"
 402         MKE2FS="mkfs.ldiskfs"
 403         DEBUGFS="debugfs.ldiskfs"
 404         TUNE2FS="tunefs.ldiskfs"
 405         E2LABEL="label.ldiskfs"
 406         DUMPE2FS="dumpfs.ldiskfs"
 407         E2FSCK="fsck.ldiskfs"
 408         PFSCK="pfsck.ldiskfs"
 409         AC_MSG_RESULT([enabled])
 410 else
 411         E2FSPROGS="e2fsprogs"
 412         MKE2FS="mke2fs"
 413         DEBUGFS="debugfs"
 414         TUNE2FS="tune2fs"
 415         E2LABEL="e2label"
 416         DUMPE2FS="dumpe2fs"
 417         E2FSCK="e2fsck"
 418         PFSCK="fsck"
 419         AC_MSG_RESULT([disabled])
 420 fi
 421
 422 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 423 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 424 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 425 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 426 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 427 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 428 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 429 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 430
 431 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 432 AC_SUBST([MKE2FS], [$MKE2FS])
 433 AC_SUBST([DEBUGFS], [$DEBUGFS])
 434 AC_SUBST([TUNE2FS], [$TUNE2FS])
 435 AC_SUBST([E2LABEL], [$E2LABEL])
 436 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 437 AC_SUBST([E2FSCK], [$E2FSCK])
 438 AC_SUBST([PFSCK], [$PFSCK])
 439 ])
 440
 441 AC_DEFUN([LB_LDISKFS_SERIES],
 442 [
 443 if $1; then
 444         AC_MSG_CHECKING([which ldiskfs series to use])
 445         case $LINUXRELEASE in
 446         2.6.18*)
 447                 if test x$RHEL_KERNEL = xyes; then
 448                         LDISKFS_SERIES="2.6-rhel5-ext4.series"
 449                 fi
 450                 ;;
 451         2.6.32*)
 452                 if test x$RHEL_KERNEL = xyes; then
 453                         LDISKFS_SERIES="2.6-rhel6.series"
 454                 fi
 455                 ;;
 456         *)
 457                 AC_MSG_WARN([Unknown kernel version $LINUXRELEASE])
 458                 LDISKFS_SERIES=
 459                 ;;
 460         esac
 461         AC_MSG_RESULT([$LDISKFS_SERIES])
 462 else
 463         LDISKFS_SERIES=
 464 fi
 465 AC_SUBST(LDISKFS_SERIES)
 466 ])