build/autoconf/lustre-build-ldiskfs.m4

   1 #
   2 # LB_PATH_LDISKFS
   3 #
   4 # --without-ldiskfs   - Disable ldiskfs support.
   5 # --with-ldiskfs=no
   6 #
   7 # --with-ldiskfs      - Enable ldiskfs support and attempt to autodetect the
   8 # --with-ldiskfs=yes    headers in one of the following places in this order:
   9 #                       * ./ldiskfs
  10 #                       * /usr/src/ldiskfs-*/$LINUXRELEASE
  11 #                       * ../ldiskfs
  12 #
  13 # --with-ldiskfs=path - Enable ldiskfs support and use the headers in the
  14 #                       provided path.  No autodetection is performed.
  15 #
  16 # --with-ldiskfs-obj  - When ldiskfs support is enabled the object directory
  17 #                       will be based on the --with-ldiskfs directory.  If
  18 #                       this is detected incorrectly it can be explicitly
  19 #                       specified using this option.
  20 #
  21 # NOTE: As with all external packages ldiskfs is expected to already be
  22 # configured and built.  However, if the ldiskfs tree is located in-tree
  23 # (./ldiskfs) then it will be configured and built recursively as part of
  24 # the lustre build system.
  25 #
  26 # NOTE: The lustre and in-tree ldiskfs build systems both make use these
  27 # macros.  This is undesirable and confusing at best, it is potentially
  28 # danagerous at worst.  The ldiskfs build system should be entirely stand
  29 # alone without dependency on the lustre build system.
  30 #
  31 AC_DEFUN([LB_PATH_LDISKFS],
  32 [
  33 AC_ARG_WITH([ldiskfs],
  34         AC_HELP_STRING([--with-ldiskfs=path], [set path to ldiskfs source]),
  35         [],[
  36                 if test x$enable_server = xyes && test x$enable_dist = xno; then
  37                         with_ldiskfs='yes'
  38                 else
  39                         with_ldiskfs='no'
  40                 fi
  41         ])
  42
  43 case x$with_ldiskfs in
  44         xno)
  45                 LDISKFS_DIR=
  46                 ;;
  47         xyes)
  48                 LDISKFS_DIR=
  49
  50                 # Check ./ldiskfs
  51                 ldiskfs_src=$PWD/ldiskfs
  52                 if test -e "$ldiskfs_src"; then
  53                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  54                 else
  55                         # Check /usr/src/ldiskfs-*/$LINUXRELEASE
  56                         ldiskfs_src=$(ls -1d \
  57                                 /usr/src/ldiskfs-*/$LINUXRELEASE \
  58                                 2>/dev/null | tail -1)
  59                         if test -e "$ldiskfs_src"; then
  60                                 LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  61                         else
  62                                 # Check ../ldiskfs
  63                                 ldiskfs_src=$PWD/../ldiskfs
  64                                 if test -e "$ldiskfs_src"; then
  65                                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  66                                 else
  67                                         # Disable ldiskfs failed to detect
  68                                         with_ldiskfs='no'
  69                                 fi
  70                         fi
  71                 fi
  72
  73                 ;;
  74         *)
  75                 LDISKFS_DIR=$(readlink -f $with_ldiskfs)
  76                 with_ldiskfs='yes'
  77                 ;;
  78 esac
  79
  80 AC_MSG_CHECKING([whether to enable ldiskfs])
  81 AC_MSG_RESULT([$with_ldiskfs])
  82
  83 AC_ARG_WITH([ldiskfs-obj],
  84         AC_HELP_STRING([--with-ldiskfs-obj=path],[set path to ldiskfs objects]),
  85         [
  86                 if test x$with_ldiskfs = xyes; then
  87                         LDISKFS_OBJ="$withval"
  88                 fi
  89         ],[
  90                 if test x$with_ldiskfs = xyes; then
  91                         LDISKFS_OBJ=$LDISKFS_DIR
  92                 fi
  93         ])
  94
  95 if test x$with_ldiskfs = xyes; then
  96         AC_MSG_CHECKING([ldiskfs source directory])
  97         AC_MSG_RESULT([$LDISKFS_DIR])
  98         AC_SUBST(LDISKFS_DIR)
  99
 100         AC_MSG_CHECKING([ldiskfs object directory])
 101         AC_MSG_RESULT([$LDISKFS_OBJ])
 102         AC_SUBST(LDISKFS_OBJ)
 103
 104         LB_LDISKFS_SYMVERS
 105         LB_LDISKFS_RELEASE
 106         LB_LDISKFS_EXT_RELEASE
 107         LB_LDISKFS_EXT_DIR
 108         LB_LDISKFS_BUILD
 109         LB_LDISKFS_DEFINE_OPTIONS
 110 fi
 111
 112 #
 113 # LDISKFS_DEVEL is required because when using the ldiskfs-devel package the
 114 # ext3/4 source will be fully patched to ldiskfs.  When building with the
 115 # in-tree ldiskfs this patching this will occur after the configure step.
 116 # We needed a way to determine if we should check the patched or unpatched
 117 # source files.
 118 #
 119 # Longer term this could be removed by moving the ldiskfs patching in to
 120 # the configure phase.  Or better yet ldiskfs could be updated to generate
 121 # a ldiskfs_config.h which clearly defines how it was built.  This can
 122 # then be directly included by Lustre to avoid all the autoconf guess work.
 123 # For an example of this behavior consult the lustre/zfs build integration.
 124 #
 125 AM_CONDITIONAL(LDISKFS_DEVEL, \
 126         test x$LDISKFS_DIR = x$(readlink -f $PWD/ldiskfs) || \
 127         test x$LDISKFS_DIR = x$(readlink -f $PWD/../ldiskfs))
 128
 129 AM_CONDITIONAL(LDISKFS_BUILD, test x$enable_ldiskfs_build = xyes)
 130 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs = xyes)
 131
 132 if test -e "$PWD/ldiskfs"; then
 133         LDISKFS_DIST_SUBDIR="ldiskfs"
 134         AC_SUBST(LDISKFS_DIST_SUBDIR)
 135         AC_CONFIG_SUBDIRS("ldiskfs")
 136 fi
 137 ])
 138
 139 #
 140 # LB_LDISKFS_EXT_RELEASE
 141 #
 142 # Determine if ext3 or ext4 sources should be used for ldiskfs.
 143 #
 144 AC_DEFUN([LB_LDISKFS_EXT_RELEASE],
 145 [
 146 AC_ARG_ENABLE([ext4],
 147          AC_HELP_STRING([--enable-ext4], [enable ldiskfs build using ext4]),
 148         [],
 149         [
 150                 if test x$RHEL_KERNEL = xyes; then
 151                         enable_ext4='yes'
 152                 else
 153                         # 2.6.22-2.6.26 ext4 available but unstable
 154                         case x$LINUXRELEASE in
 155                         x2.6.2[[0-6]]*)
 156                                 enable_ext4='no' ;;
 157                         *)
 158                                 enable_ext4='yes' ;;
 159                         esac
 160                 fi
 161         ])
 162
 163 if test x$enable_ext4 = xyes; then
 164         LDISKFS_BACKFS='ext4'
 165 else
 166         LDISKFS_BACKFS='ext3'
 167 fi
 168
 169 AC_MSG_CHECKING([whether to use ext3 or ext4 source])
 170 AC_MSG_RESULT([$LDISKFS_BACKFS])
 171 AC_SUBST(LDISKFS_BACKFS)
 172 ])
 173
 174 #
 175 # LB_LDISKFS_EXT_DIR
 176 #
 177 # Determine the location of the ext3/ext4 source code.  It it required
 178 # for several configure tests and to build ldiskfs.
 179 #
 180 AC_DEFUN([LB_LDISKFS_EXT_DIR],
 181 [
 182 # Kernel ext source located with devel headers
 183 linux_src=$LINUX
 184 if test -e "$linux_src/fs/$LDISKFS_BACKFS/super.c"; then
 185         EXT_DIR=$linux_src/fs/$LDISKFS_BACKFS
 186 else
 187         # Kernel ext source provided by kernel-debuginfo-common package
 188         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 189                 2>/dev/null | tail -1)
 190         if test -e "$linux_src/fs/$LDISKFS_BACKFS/super.c"; then
 191                 EXT_DIR=$linux_src/fs/$LDISKFS_BACKFS
 192         else
 193                 EXT_DIR=
 194         fi
 195 fi
 196
 197 AC_MSG_CHECKING([$LDISKFS_BACKFS source directory])
 198 AC_MSG_RESULT([$EXT_DIR])
 199 AC_SUBST(EXT_DIR)
 200 ])
 201
 202 #
 203 # LB_LDISKFS_EXT_SOURCE
 204 #
 205 # Spot check the existance of several source files common to ext3/ext4.
 206 # Detecting this at configure time allows us to avoid a potential build
 207 # failure and provide a useful error message to explain what is wrong.
 208 #
 209 AC_DEFUN([LB_LDISKFS_EXT_SOURCE],
 210 [
 211 if test x$EXT_DIR = x; then
 212         AC_MSG_ERROR([Complete $LDISKFS_BACKFS source must exist.
 213
 214 If you are building using kernel-devel packages then ensure that the
 215 matching kernel-debuginfo-common and kernel-debuginfo-common-<arch>
 216 packages are installed.])
 217 fi
 218
 219 LB_CHECK_FILE([$EXT_DIR/dir.c], [], [ AC_MSG_ERROR(
 220         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 221 LB_CHECK_FILE([$EXT_DIR/file.c], [], [ AC_MSG_ERROR(
 222         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 223 LB_CHECK_FILE([$EXT_DIR/inode.c], [], [ AC_MSG_ERROR(
 224         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 225 LB_CHECK_FILE([$EXT_DIR/super.c], [], [ AC_MSG_ERROR(
 226         [Complete $LDISKFS_BACKFS source must exist for ldiskfs build])])
 227 ])
 228
 229 #
 230 # LB_LDISKFS_DEFINE_OPTIONS
 231 #
 232 # Enable config options related to ldiskfs.  These are used by ldiskfs,
 233 # lvfs, and the osd-ldiskfs code (which includes ldiskfs headers.)
 234 #
 235 AC_DEFUN([LB_LDISKFS_DEFINE_OPTIONS],
 236 [
 237 AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 238
 239 with_ldiskfs_pdo=no
 240 if test $LDISKFS_BACKFS = 'ext4'; then
 241         AC_DEFINE(HAVE_EXT4_LDISKFS, 1, [build ext4 based ldiskfs])
 242         case $LINUXRELEASE in
 243         2.6.32*)
 244                 if test x$RHEL_KERNEL = xyes; then
 245                         with_ldiskfs_pdo=yes
 246                         AC_DEFINE(HAVE_LDISKFS_PDO, 1, [have ldiskfs PDO patch])
 247                 fi
 248         esac
 249 fi
 250
 251 LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET
 252
 253 AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1,
 254         [enable extended attributes for ldiskfs])
 255 AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1,
 256         [enable posix acls for ldiskfs])
 257 AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1,
 258         [enable fs security for ldiskfs])
 259 AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1,
 260         [enable posix acls for ldiskfs])
 261 AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1,
 262         [enable extented attributes for ldiskfs])
 263 AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1,
 264         [enable fs security for ldiskfs])
 265 ])
 266
 267 #
 268 # Check for jbd2_journal_callback_set(), which is needed for commit
 269 # callbacks.  When LU-433 lands jbd2_journal_callback_set() will only
 270 # remain for legacy reasons and AC_MSG_ERROR can be removed.
 271 #
 272 # 2.6.18 with ext3 still uses journal_callback_set() for commit callbacks.
 273 #
 274 AC_DEFUN([LB_LDISKFS_JBD2_JOURNAL_CALLBACK_SET],
 275 [
 276         LB_CHECK_SYMBOL_EXPORT([jbd2_journal_callback_set],
 277         [fs/jbd2/journal.c],
 278         [AC_DEFINE(HAVE_JBD2_JOURNAL_CALLBACK_SET, 1,
 279                 [kernel exports jbd2_journal_callback_set])],
 280         [LB_CHECK_SYMBOL_EXPORT([journal_callback_set],
 281                 [fs/jbd/journal.c],
 282                 [AC_DEFINE(HAVE_JOURNAL_CALLBACK_SET, 1,
 283                         [kernel exports journal_callback_set])],
 284                 [if test x$with_ldiskfs != xno ; then
 285                         AC_MSG_ERROR([ldiskfs needs jbd2-jcberr patch])
 286                 fi])])
 287 ])
 288
 289 #
 290 # Optionally configure/make the ldiskfs sources.  If the sources are
 291 # determined to reside in-tree this feature will automatically be
 292 # enabled.  If the sources are not in-tree it will be disabled.
 293 # Use --enable-ldiskfs-build or --disable-ldiskfs-build if you need
 294 # to override this behavior.
 295 #
 296 AC_DEFUN([LB_LDISKFS_BUILD],
 297 [
 298 AC_ARG_ENABLE([ldiskfs-build],
 299         AC_HELP_STRING([--enable-ldiskfs-build],
 300                 [enable ldiskfs configure/make]),
 301         [], [
 302                 LDISKFS_DIR_INTREE=$(readlink -f $PWD/ldiskfs)
 303                 if test x$LDISKFS_DIR = x$LDISKFS_DIR_INTREE; then
 304                         enable_ldiskfs_build='yes'
 305                 else
 306                         enable_ldiskfs_build='no'
 307                 fi
 308         ])
 309
 310 AC_MSG_CHECKING([whether to build ldiskfs])
 311 if test x$enable_ldiskfs_build = xyes; then
 312         AC_MSG_RESULT([$enable_ldiskfs_build])
 313
 314         LB_CHECK_FILE([$LDISKFS_DIR/configure], [], [
 315                 AC_MSG_ERROR([Complete ldiskfs build system must exist])])
 316         LB_LDISKFS_EXT_SOURCE
 317
 318         LDISKFS_SUBDIR="ldiskfs"
 319         AC_SUBST(LDISKFS_SUBDIR)
 320 else
 321         enable_ldiskfs_build='no'
 322         AC_MSG_RESULT([$enable_ldiskfs_build])
 323 fi
 324 ])
 325
 326 AC_DEFUN([LB_LDISKFS_SYMVERS],
 327 [
 328 AC_MSG_CHECKING([ldiskfs module symbols])
 329 if test -r $LDISKFS_OBJ/Module.symvers; then
 330         LDISKFS_SYMBOLS=Module.symvers
 331 elif test -r $LDISKFS_OBJ/Modules.symvers; then
 332         LDISKFS_SYMBOLS=Modules.symvers
 333 elif test -r $LDISKFS_OBJ/ldiskfs/Module.symvers; then
 334         LDISKFS_SYMBOLS=Module.symvers
 335 elif test -r $LDISKFS_OBJ/ldiskfs/Modules.symvers; then
 336         LDISKFS_SYMBOLS=Modules.symvers
 337 else
 338         LDISKFS_SYMBOLS=$SYMVERFILE
 339 fi
 340
 341 AC_MSG_RESULT([$LDISKFS_SYMBOLS])
 342 AC_SUBST(LDISKFS_SYMBOLS)
 343 ])
 344
 345 AC_DEFUN([LB_LDISKFS_RELEASE],
 346 [
 347 AC_MSG_CHECKING([ldiskfs source release])
 348 if test -r $LDISKFS_OBJ/config.h; then
 349         tmp_flags="$EXTRA_KCFLAGS"
 350         EXTRA_KCFLAGS="-I$LDISKFS_DIR $EXTRA_KCFLAGS"
 351         LB_LINUX_TRY_MAKE([
 352                 #undef PACKAGE_NAME
 353                 #undef PACKAGE_TARNAME
 354                 #undef PACKAGE_VERSION
 355                 #undef PACKAGE_STRING
 356                 #undef PACKAGE_BUGREPORT
 357                 #undef PACKAGE
 358                 #undef VERSION
 359                 #undef STDC_HEADERS
 360
 361                 #include <$LDISKFS_OBJ/config.h>
 362         ],[
 363                 char *LDISKFS_RELEASE;
 364                 LDISKFS_RELEASE=VERSION;
 365         ],[
 366                 $makerule LUSTRE_KERNEL_TEST=conftest.i
 367         ],[
 368                 test -s build/conftest.i
 369         ],[
 370                 eval $(grep "LDISKFS_RELEASE=" build/conftest.i)
 371         ],[
 372                 AC_MSG_RESULT([unknown])
 373                 AC_MSG_ERROR([Could not preprocess test program.])
 374         ])
 375         EXTRA_KCFLAGS="$tmp_flags"
 376         rm build/conftest.i
 377 elif test -r $LDISKFS_DIR/configure.ac; then
 378         LDISKFS_RELEASE=$(awk '/AC\_INIT/ { print [$]3 }' \
 379                  $LDISKFS_DIR/configure.ac | tr ',' '\n')
 380 else
 381         AC_MSG_RESULT([unknown])
 382         AC_MSG_ERROR([Could not locate config.h, META, or configure.ac to check release.])
 383 fi
 384
 385 if test x$LDISKFS_RELEASE = x; then
 386         AC_MSG_RESULT([unknown])
 387         AC_MSG_ERROR([Could not determine ldiskfs release.])
 388 fi
 389
 390 AC_MSG_RESULT([$LDISKFS_RELEASE])
 391 AC_SUBST(LDISKFS_RELEASE)
 392 ])
 393
 394 #
 395 # LB_DEFINE_E2FSPROGS_NAMES
 396 #
 397 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 398 #
 399 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 400 [
 401 AC_ARG_WITH([ldiskfsprogs],
 402         AC_HELP_STRING([--with-ldiskfsprogs],
 403                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 404         [],[withval='no'])
 405
 406 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 407 if test x$withval = xyes ; then
 408         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 409         E2FSPROGS="ldiskfsprogs"
 410         MKE2FS="mkfs.ldiskfs"
 411         DEBUGFS="debugfs.ldiskfs"
 412         TUNE2FS="tunefs.ldiskfs"
 413         E2LABEL="label.ldiskfs"
 414         DUMPE2FS="dumpfs.ldiskfs"
 415         E2FSCK="fsck.ldiskfs"
 416         PFSCK="pfsck.ldiskfs"
 417         AC_MSG_RESULT([enabled])
 418 else
 419         E2FSPROGS="e2fsprogs"
 420         MKE2FS="mke2fs"
 421         DEBUGFS="debugfs"
 422         TUNE2FS="tune2fs"
 423         E2LABEL="e2label"
 424         DUMPE2FS="dumpe2fs"
 425         E2FSCK="e2fsck"
 426         PFSCK="fsck"
 427         AC_MSG_RESULT([disabled])
 428 fi
 429
 430 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 431 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 432 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 433 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 434 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 435 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 436 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 437 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 438
 439 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 440 AC_SUBST([MKE2FS], [$MKE2FS])
 441 AC_SUBST([DEBUGFS], [$DEBUGFS])
 442 AC_SUBST([TUNE2FS], [$TUNE2FS])
 443 AC_SUBST([E2LABEL], [$E2LABEL])
 444 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 445 AC_SUBST([E2FSCK], [$E2FSCK])
 446 AC_SUBST([PFSCK], [$PFSCK])
 447 ])
 448
 449 AC_DEFUN([LB_LDISKFS_SERIES],
 450 [
 451 if $1; then
 452         AC_MSG_CHECKING([which ldiskfs series to use])
 453         case $LINUXRELEASE in
 454         2.6.18*)
 455                 if test x$RHEL_KERNEL = xyes; then
 456                         LDISKFS_SERIES="2.6-rhel5-ext4.series"
 457                 fi
 458                 ;;
 459         2.6.32*)
 460                 if test x$RHEL_KERNEL = xyes; then
 461                         LDISKFS_SERIES="2.6-rhel6.series"
 462                 fi
 463                 ;;
 464         *)
 465                 AC_MSG_WARN([Unknown kernel version $LINUXRELEASE])
 466                 LDISKFS_SERIES=
 467                 ;;
 468         esac
 469         AC_MSG_RESULT([$LDISKFS_SERIES])
 470 else
 471         LDISKFS_SERIES=
 472 fi
 473 AC_SUBST(LDISKFS_SERIES)
 474 ])