+# LB_CONFIG_SERVERS
+#
+AC_DEFUN([LB_CONFIG_SERVERS], [
+AC_ARG_ENABLE([server],
+ AC_HELP_STRING([--disable-server],
+ [disable Lustre server support]), [
+ AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
+ [AC_MSG_ERROR([server valid options are "yes" or "no"])])
+ AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
+ [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
+ ], [
+ AS_IF([test x$enable_dist = xyes],
+ [enable_server=no], [enable_server=maybe])
+ ])
+
+# There are at least two good reasons why we should really run
+# LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
+# LB_CONFIG_MODULES needs to be run for client support even when
+# servers are disabled, and because module support is actually a
+# prerequisite of server support. However, some things under
+# LB_CONFIG_MODULES need us to already have checked for --disable-server,
+# before running, so until LB_CONFIG_MODULES can be reorganized, we
+# call it here.
+LB_CONFIG_MODULES
+AS_IF([test x$enable_modules = xno], [enable_server=no])
+LB_CONFIG_LDISKFS
+LB_CONFIG_ZFS
+
+# If no backends were configured, and the user did not explicitly
+# require servers to be enabled, we just disable servers.
+AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
+ AS_CASE([$enable_server],
+ [maybe], [enable_server=no],
+ [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
+ ], [
+ AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
+ ])
+
+AC_MSG_CHECKING([whether to build Lustre server support])
+AC_MSG_RESULT([$enable_server])
+AS_IF([test x$enable_server = xyes],
+ [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
+]) # LB_CONFIG_SERVERS
+
+#
+# LB_CONFIG_RPMBUILD_OPTIONS
+#
+# The purpose of this function is to assemble command line options
+# for the rpmbuild command based on the options passed to the configure
+# script, and also upon the decisions that configure makes based on
+# the tests that it runs.
+# These strings can be passed to rpmbuild on the command line
+# in the Make targets named "rpms" and "srpm".
+#
+AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
+RPMBINARGS=
+CONFIGURE_ARGS=
+eval set -- $ac_configure_args
+for arg; do
+ case $arg in
+ --*dir=* ) ;;
+ -C | --cache-file=* ) ;;
+ --prefix=* | --*-prefix=* ) ;;
+ --enable-dist ) ;;
+ --with-release=* ) ;;
+ --with-kmp-moddir=* ) ;;
+ --with-linux=* | --with-linux-obj=* ) ;;
+ --enable-shared | --disable-shared ) ;;
+ --enable-static | --disable-static ) ;;
+ --enable-ldiskfs | --disable-ldiskfs ) ;;
+ --enable-modules | --disable-modules ) ;;
+ --enable-server | --disable-server ) ;;
+ --enable-tests | --disable-tests ) ;;
+ --enable-utils | --disable-utils ) ;;
+ --enable-iokit | --disable-iokit ) ;;
+ --enable-dlc | --disable-dlc ) ;;
+ --enable-manpages | --disable-manpages ) ;;
+ * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
+ esac
+done
+if test -n "$CONFIGURE_ARGS" ; then
+ RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
+fi
+if test -n "$LINUX" ; then
+ RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
+ if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
+ RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
+ fi
+fi
+if test -n "$KMP_MODDIR" ; then
+ RPMBINARGS="$RPMBINARGS --define \"kmoddir $KMP_MODDIR\""
+fi
+if test x$enable_modules != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without lustre_modules"
+fi
+if test x$enable_tests != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without lustre_tests"
+fi
+if test x$enable_utils != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without lustre_utils"
+fi
+if test x$enable_server != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without servers"
+fi
+if test x$enable_ldiskfs != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without ldiskfs"
+fi
+if test x$enable_zfs = xyes ; then
+ RPMBINARGS="$RPMBINARGS --with zfs"
+fi
+if test x$enable_iokit != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without lustre_iokit"
+fi
+if test x$USE_DLC = xyes ; then
+ RPMBINARGS="$RPMBINARGS --with lnet_dlc"
+fi
+if test x$enable_manpages != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without manpages"
+fi
+if test x$enable_shared != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without shared"
+fi
+if test x$enable_static != xyes ; then
+ RPMBINARGS="$RPMBINARGS --without static"
+fi
+
+RPMBUILD_BINARY_ARGS=$RPMBINARGS
+
+AC_SUBST(RPMBUILD_BINARY_ARGS)
+]) # LB_CONFIG_RPMBUILD_OPTIONS
+
+#