lustre/autoconf/lustre-core.m4

   1 #
   2 # LC_CONFIG_SRCDIR
   3 #
   4 # Wrapper for AC_CONFIG_SUBDIR
   5 #
   6 AC_DEFUN([LC_CONFIG_SRCDIR],
   7 [AC_CONFIG_SRCDIR([lustre/obdclass/obdo.c])
   8 libcfs_is_module=yes
   9 ldiskfs_is_ext4=yes
  10 ])
  11
  12 #
  13 # LC_PATH_DEFAULTS
  14 #
  15 # lustre specific paths
  16 #
  17 AC_DEFUN([LC_PATH_DEFAULTS],
  18 [# ptlrpc kernel build requires this
  19 LUSTRE="$PWD/lustre"
  20 AC_SUBST(LUSTRE)
  21
  22 # mount.lustre
  23 rootsbindir='$(CROSS_PATH)/sbin'
  24 AC_SUBST(rootsbindir)
  25
  26 demodir='$(docdir)/demo'
  27 AC_SUBST(demodir)
  28
  29 pkgexampledir='${pkgdatadir}/examples'
  30 AC_SUBST(pkgexampledir)
  31 ])
  32
  33 #
  34 # LC_TARGET_SUPPORTED
  35 #
  36 # is the target os supported?
  37 #
  38 AC_DEFUN([LC_TARGET_SUPPORTED],
  39 [case $target_os in
  40         linux* | darwin*)
  41 $1
  42                 ;;
  43         *)
  44 $2
  45                 ;;
  46 esac
  47 ])
  48
  49 #
  50 # LC_CONFIG_OBD_BUFFER_SIZE
  51 #
  52 # the maximum buffer size of lctl ioctls
  53 #
  54 AC_DEFUN([LC_CONFIG_OBD_BUFFER_SIZE],
  55 [AC_MSG_CHECKING([maximum OBD ioctl size])
  56 AC_ARG_WITH([obd-buffer-size],
  57         AC_HELP_STRING([--with-obd-buffer-size=[size]],
  58                         [set lctl ioctl maximum bytes (default=8192)]),
  59         [
  60                 OBD_BUFFER_SIZE=$with_obd_buffer_size
  61         ],[
  62                 OBD_BUFFER_SIZE=8192
  63         ])
  64 AC_MSG_RESULT([$OBD_BUFFER_SIZE bytes])
  65 AC_DEFINE_UNQUOTED(CONFIG_LUSTRE_OBD_MAX_IOCTL_BUFFER, $OBD_BUFFER_SIZE, [IOCTL Buffer Size])
  66 ])
  67
  68 #
  69 # LC_READLINK_SSIZE_T
  70 #
  71 AC_DEFUN([LC_READLINK_SSIZE_T],
  72 [AC_MSG_CHECKING([if readlink returns ssize_t])
  73 AC_TRY_COMPILE([
  74         #include <unistd.h>
  75 ],[
  76         ssize_t readlink(const char *, char *, size_t);
  77 ],[
  78         AC_MSG_RESULT([yes])
  79         AC_DEFINE(HAVE_POSIX_1003_READLINK, 1, [readlink returns ssize_t])
  80 ],[
  81         AC_MSG_RESULT([no])
  82 ])
  83 ])
  84
  85 #
  86 # LC_FUNC_DEV_SET_RDONLY
  87 #
  88 # check whether dev_set_rdonly is exported.  This is needed until we
  89 # have another mechanism to fence IO from the underlying device.
  90 #
  91 AC_DEFUN([LC_FUNC_DEV_SET_RDONLY],
  92 [LB_CHECK_SYMBOL_EXPORT([dev_set_rdonly],
  93 [block/ll_rw_block.c,block/blk-core.c],[
  94         AC_DEFINE(HAVE_DEV_SET_RDONLY, 1, [kernel exports dev_set_rdonly])
  95 ],[
  96         AC_MSG_WARN([kernel missing dev_set_rdonly patch for testing])
  97 ])
  98 ])
  99
 100 #
 101 # Ensure stack size big than 8k in Lustre server (all kernels)
 102 #
 103 AC_DEFUN([LC_STACK_SIZE],
 104 [AC_MSG_CHECKING([stack size big than 8k])
 105 LB_LINUX_TRY_COMPILE([
 106         #include <linux/thread_info.h>
 107 ],[
 108         #if THREAD_SIZE < 8192
 109         #error "stack size < 8192"
 110         #endif
 111 ],[
 112         AC_MSG_RESULT(yes)
 113 ],[
 114         AC_MSG_ERROR([Lustre requires that Linux is configured with at least a 8KB stack.])
 115 ])
 116 ])
 117
 118 #
 119 # Allow the user to set the MDS thread upper limit
 120 #
 121 AC_DEFUN([LC_MDS_MAX_THREADS],
 122 [
 123         AC_ARG_WITH([mds_max_threads],
 124         AC_HELP_STRING([--with-mds-max-threads=count],
 125                        [maximum threads available on the MDS: (default=512)]),
 126         [
 127                 MDS_THREAD_COUNT=$with_mds_max_threads
 128                 AC_DEFINE_UNQUOTED(MDS_MAX_THREADS, $MDS_THREAD_COUNT, [maximum number of MDS threads])
 129         ])
 130 ])
 131
 132 #
 133 # LC_CONFIG_PINGER
 134 #
 135 # the pinger is temporary, until we have the recovery node in place
 136 #
 137 AC_DEFUN([LC_CONFIG_PINGER],
 138 [AC_MSG_CHECKING([whether to enable pinger support])
 139 AC_ARG_ENABLE([pinger],
 140         AC_HELP_STRING([--disable-pinger],
 141                         [disable recovery pinger support]),
 142         [],[enable_pinger='yes'])
 143 AC_MSG_RESULT([$enable_pinger])
 144 if test x$enable_pinger != xno ; then
 145   AC_DEFINE(ENABLE_PINGER, 1, Use the Pinger)
 146 fi
 147 ])
 148
 149 #
 150 # LC_CONFIG_CHECKSUM
 151 #
 152 # do checksum of bulk data between client and OST
 153 #
 154 AC_DEFUN([LC_CONFIG_CHECKSUM],
 155 [AC_MSG_CHECKING([whether to enable data checksum support])
 156 AC_ARG_ENABLE([checksum],
 157        AC_HELP_STRING([--disable-checksum],
 158                        [disable data checksum support]),
 159        [],[enable_checksum='yes'])
 160 AC_MSG_RESULT([$enable_checksum])
 161 if test x$enable_checksum != xno ; then
 162   AC_DEFINE(ENABLE_CHECKSUM, 1, do data checksums)
 163 fi
 164 ])
 165
 166 #
 167 # LC_CONFIG_LIBLUSTRE_RECOVERY
 168 #
 169 AC_DEFUN([LC_CONFIG_LIBLUSTRE_RECOVERY],
 170 [AC_MSG_CHECKING([whether to enable liblustre recovery support])
 171 AC_ARG_ENABLE([liblustre-recovery],
 172         AC_HELP_STRING([--disable-liblustre-recovery],
 173                         [disable liblustre recovery support]),
 174         [],[enable_liblustre_recovery='yes'])
 175 AC_MSG_RESULT([$enable_liblustre_recovery])
 176 if test x$enable_liblustre_recovery != xno ; then
 177   AC_DEFINE(ENABLE_LIBLUSTRE_RECOVERY, 1, Liblustre Can Recover)
 178 fi
 179 ])
 180
 181 #
 182 # LC_CONFIG_HEALTH_CHECK_WRITE
 183 #
 184 # Turn off the actual write to the disk
 185 #
 186 AC_DEFUN([LC_CONFIG_HEALTH_CHECK_WRITE],
 187 [AC_MSG_CHECKING([whether to enable a write with the health check])
 188 AC_ARG_ENABLE([health_write],
 189         AC_HELP_STRING([--enable-health_write],
 190                         [enable disk writes when doing health check]),
 191         [],[enable_health_write='no'])
 192 AC_MSG_RESULT([$enable_health_write])
 193 if test x$enable_health_write != xno ; then
 194   AC_DEFINE(USE_HEALTH_CHECK_WRITE, 1, Write when Checking Health)
 195 fi
 196 ])
 197
 198 AC_DEFUN([LC_CONFIG_LRU_RESIZE],
 199 [AC_MSG_CHECKING([whether to enable lru self-adjusting])
 200 AC_ARG_ENABLE([lru_resize],
 201         AC_HELP_STRING([--enable-lru-resize],
 202                         [enable lru resize support]),
 203         [],[enable_lru_resize='yes'])
 204 AC_MSG_RESULT([$enable_lru_resize])
 205 if test x$enable_lru_resize != xno; then
 206    AC_DEFINE(HAVE_LRU_RESIZE_SUPPORT, 1, [Enable lru resize support])
 207 fi
 208 ])
 209
 210 #
 211 # Quota support. The kernel must support CONFIG_QUOTA.
 212 #
 213 AC_DEFUN([LC_QUOTA_CONFIG],
 214 [LB_LINUX_CONFIG_IM([QUOTA],[],[
 215         AC_MSG_ERROR([Lustre quota requires that CONFIG_QUOTA is enabled in your kernel.])
 216         ])
 217 ])
 218
 219 # truncate_complete_page() has never been exported from an upstream kernel
 220 # remove_from_page_cache() was exported between 2.6.35 and 2.6.38
 221 # delete_from_page_cache() is exported from 2.6.39
 222 AC_DEFUN([LC_EXPORT_TRUNCATE_COMPLETE_PAGE],
 223          [LB_CHECK_SYMBOL_EXPORT([truncate_complete_page],
 224                                  [mm/truncate.c],
 225                                  [AC_DEFINE(HAVE_TRUNCATE_COMPLETE_PAGE, 1,
 226                                             [kernel export truncate_complete_page])])
 227           LB_CHECK_SYMBOL_EXPORT([remove_from_page_cache],
 228                                  [mm/filemap.c],
 229                                  [AC_DEFINE(HAVE_REMOVE_FROM_PAGE_CACHE, 1,
 230                                             [kernel export remove_from_page_cache])])
 231           LB_CHECK_SYMBOL_EXPORT([delete_from_page_cache],
 232                                  [mm/filemap.c],
 233                                  [AC_DEFINE(HAVE_DELETE_FROM_PAGE_CACHE, 1,
 234                                             [kernel export delete_from_page_cache])])
 235          ])
 236
 237 #
 238 # LC_CAPA_CRYPTO
 239 #
 240 AC_DEFUN([LC_CAPA_CRYPTO],
 241 [LB_LINUX_CONFIG_IM([CRYPTO],[],[
 242         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO is enabled in your kernel.])
 243 ])
 244 LB_LINUX_CONFIG_IM([CRYPTO_HMAC],[],[
 245         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_HMAC is enabled in your kernel.])
 246 ])
 247 LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],[
 248         AC_MSG_ERROR([Lustre capability require that CONFIG_CRYPTO_SHA1 is enabled in your kernel.])
 249 ])
 250 ])
 251
 252 #
 253 # LC_CONFIG_RMTCLIENT
 254 #
 255 dnl FIXME
 256 dnl the AES symbol usually tied with arch, e.g. CRYPTO_AES_586
 257 dnl FIXME
 258 AC_DEFUN([LC_CONFIG_RMTCLIENT],
 259 [LB_LINUX_CONFIG_IM([CRYPTO_AES],[],[
 260         AC_MSG_WARN([Lustre remote client require that CONFIG_CRYPTO_AES is enabled in your kernel.])
 261 ])
 262 ])
 263
 264 #
 265 # LC_CONFIG_GSS_KEYRING (default 'auto', tests for dependencies, if found, enables; only called if gss is enabled)
 266 #
 267 AC_DEFUN([LC_CONFIG_GSS_KEYRING],
 268 [AC_MSG_CHECKING([whether to enable gss keyring backend])
 269  AC_ARG_ENABLE([gss_keyring],
 270                [AC_HELP_STRING([--disable-gss-keyring],
 271                                [disable gss keyring backend])],
 272                [],[enable_gss_keyring='auto'])
 273  AC_MSG_RESULT([$enable_gss_keyring])
 274
 275  if test x$enable_gss_keyring != xno; then
 276         LB_LINUX_CONFIG_IM([KEYS],[],
 277                            [gss_keyring_conf_test='fail';
 278                             AC_MSG_WARN([GSS keyring backend require that CONFIG_KEYS be enabled in your kernel.])])
 279
 280         AC_CHECK_LIB([keyutils], [keyctl_search], [],
 281                      [gss_keyring_conf_test='fail';
 282                       AC_MSG_WARN([libkeyutils is not found, which is required by gss keyring backend])],)
 283
 284         if test x$gss_keyring_conf_test != xfail; then
 285                 AC_DEFINE([HAVE_GSS_KEYRING], [1], [Define this if you enable gss keyring backend])
 286                 enable_gss_keyring='yes'
 287         else
 288                 if test x$enable_gss_keyring == xyes; then
 289                         AC_MSG_ERROR([Cannot enable gss_keyring. See above for details.])
 290                 else
 291                         AC_MSG_WARN([Cannot enable gss keyring.  See above for details.])
 292                 fi
 293         fi
 294  fi
 295 ])
 296
 297 AC_DEFUN([LC_CONFIG_SUNRPC],
 298 [LB_LINUX_CONFIG_IM([SUNRPC],[],
 299                     [if test x$sunrpc_required == xyes; then
 300                          AC_MSG_ERROR([kernel SUNRPC support is required by using GSS.])
 301                      fi])
 302 ])
 303
 304 #
 305 # LC_CONFIG_GSS (default 'auto' (tests for dependencies, if found, enables))
 306 #
 307 # Build gss and related tools of Lustre. Currently both kernel and user space
 308 # parts are depend on linux platform.
 309 #
 310 AC_DEFUN([LC_CONFIG_GSS],
 311 [AC_MSG_CHECKING([whether to enable gss/krb5 support])
 312  AC_ARG_ENABLE([gss],
 313                [AC_HELP_STRING([--enable-gss], [enable gss/krb5 support])],
 314                [],[enable_gss='auto'])
 315  AC_MSG_RESULT([$enable_gss])
 316
 317  if test x$enable_gss != xno; then
 318         LC_CONFIG_GSS_KEYRING
 319         sunrpc_required=$enable_gss
 320         LC_CONFIG_SUNRPC
 321         sunrpc_required=no
 322
 323         LB_LINUX_CONFIG_IM([CRYPTO_MD5],[],
 324                            [AC_MSG_WARN([kernel MD5 support is recommended by using GSS.])])
 325         LB_LINUX_CONFIG_IM([CRYPTO_SHA1],[],
 326                            [AC_MSG_WARN([kernel SHA1 support is recommended by using GSS.])])
 327         LB_LINUX_CONFIG_IM([CRYPTO_SHA256],[],
 328                            [AC_MSG_WARN([kernel SHA256 support is recommended by using GSS.])])
 329         LB_LINUX_CONFIG_IM([CRYPTO_SHA512],[],
 330                            [AC_MSG_WARN([kernel SHA512 support is recommended by using GSS.])])
 331
 332         require_krb5=$enable_gss
 333         AC_KERBEROS_V5
 334         require_krb5=no
 335
 336         if test x$KRBDIR != x; then
 337                 AC_CHECK_LIB([gssapi], [gss_export_lucid_sec_context],
 338                              [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssapi";
 339                               gss_conf_test='success'],
 340                              [AC_CHECK_LIB([gssglue], [gss_export_lucid_sec_context],
 341                                            [GSSAPI_LIBS="$GSSAPI_LDFLAGS -lgssglue";
 342                                             gss_conf_test='success'],
 343                                            [if test x$enable_gss == xyes; then
 344                                                 AC_MSG_ERROR([libgssapi or libgssglue is not found, which is required by GSS.])
 345                                             else
 346                                                 AC_MSG_WARN([libgssapi or libgssglue is not found, which is required by GSS.])
 347                                             fi])],)
 348                 AC_SUBST(GSSAPI_LIBS)
 349         fi
 350
 351         if test x$gss_conf_test == xsuccess; then
 352                 AC_DEFINE([HAVE_GSS], [1], [Define this is if you enable gss])
 353                 enable_gss='yes'
 354         fi
 355
 356  fi
 357 ])
 358
 359 # up to v2.6.27 had a 3 arg version (inode, mask, nameidata)
 360 # v2.6.27->v2.6.37 had a 2 arg version (inode, mask)
 361 # v2.6.37->v3.0 had a 3 arg version (inode, mask, nameidata)
 362 # v3.1 onward have a 2 arg version (inode, mask)
 363 AC_DEFUN([LC_INODE_PERMISION_2ARGS],
 364 [AC_MSG_CHECKING([inode_operations->permission has two args])
 365 LB_LINUX_TRY_COMPILE([
 366         #include <linux/fs.h>
 367 ],[
 368         struct inode *inode __attribute__ ((unused));
 369
 370         inode = NULL;
 371         inode->i_op->permission(NULL, 0);
 372 ],[
 373         AC_DEFINE(HAVE_INODE_PERMISION_2ARGS, 1,
 374                   [inode_operations->permission has two args])
 375         AC_MSG_RESULT([yes])
 376 ],[
 377         AC_MSG_RESULT([no])
 378 ])
 379 ])
 380
 381 # 2.6.34 has quotactl_ops->[sg]et_dqblk that take struct fs_disk_quota
 382 AC_DEFUN([LC_HAVE_DQUOT_FS_DISK_QUOTA],
 383 tmp_flags="$EXTRA_KCFLAGS"
 384 EXTRA_KCFLAGS="-Werror"
 385 [AC_MSG_CHECKING([if quotactl_ops.set_dqblk takes struct fs_disk_quota])
 386 LB_LINUX_TRY_COMPILE([
 387         #include <linux/fs.h>
 388         #include <linux/quota.h>
 389 ],[
 390         struct quotactl_ops qops = {};
 391         struct fs_disk_quota fdq;
 392         qops.set_dqblk(NULL, 0, 0, &fdq);
 393 ],[
 394         AC_DEFINE(HAVE_DQUOT_FS_DISK_QUOTA, 1, [quotactl_ops.set_dqblk takes struct fs_disk_quota])
 395         AC_MSG_RESULT([yes])
 396 ],[
 397         AC_MSG_RESULT([no])
 398 ])
 399 EXTRA_KCFLAGS="$tmp_flags"
 400 ])
 401
 402 # 2.6.34 has renamed dquot options to dquot_*, check for dquot_suspend
 403 AC_DEFUN([LC_HAVE_DQUOT_SUSPEND],
 404 [AC_MSG_CHECKING([if dquot_suspend is defined])
 405 LB_LINUX_TRY_COMPILE([
 406         #include <linux/quotaops.h>
 407 ],[
 408         dquot_suspend(NULL, -1);
 409 ],[
 410         AC_DEFINE(HAVE_DQUOT_SUSPEND, 1, [dquot_suspend is defined])
 411         AC_MSG_RESULT([yes])
 412 ],[
 413         AC_MSG_RESULT([no])
 414 ])
 415 ])
 416
 417 # 2.6.32
 418
 419 # 2.6.32 replaces 2 functions blk_queue_max_phys_segments and blk_queue_max_hw_segments by blk_queue_max_segments
 420 AC_DEFUN([LC_BLK_QUEUE_MAX_SEGMENTS],
 421 [AC_MSG_CHECKING([if blk_queue_max_segments is defined])
 422 LB_LINUX_TRY_COMPILE([
 423         #include <linux/blkdev.h>
 424 ],[
 425         blk_queue_max_segments(NULL, 0);
 426 ],[
 427         AC_MSG_RESULT(yes)
 428         AC_DEFINE(HAVE_BLK_QUEUE_MAX_SEGMENTS, 1,
 429                   [blk_queue_max_segments is defined])
 430 ],[
 431         AC_MSG_RESULT(no)
 432 ])
 433 ])
 434
 435 #
 436 # LC_QUOTA64
 437 #
 438 # Check if kernel has been patched for 64-bit quota limits support.
 439 # The upstream version of this patch in RHEL6 2.6.32 kernels introduces
 440 # the constant QFMT_VFS_V1 in include/linux/quota.h, so we can check for
 441 # that in the absence of quotaio_v1.h in the kernel headers.
 442 #
 443 AC_DEFUN([LC_QUOTA64],[
 444         AC_MSG_CHECKING([if kernel has 64-bit quota limits support])
 445 tmp_flags="$EXTRA_KCFLAGS"
 446 EXTRA_KCFLAGS="-I$LINUX/fs"
 447         LB_LINUX_TRY_COMPILE([
 448                 #include <linux/kernel.h>
 449                 #include <linux/fs.h>
 450                 #if defined(HAVE_FS_QUOTA_QUOTAIO_H)
 451                 # include <quota/quotaio_v2.h>
 452                 struct v2r1_disk_dqblk dqblk_r1;
 453                 #else
 454                 #include <linux/quota.h>
 455                 int ver = QFMT_VFS_V1;
 456                 #endif
 457         ],[],[
 458                 AC_DEFINE(HAVE_QUOTA64, 1, [have quota64])
 459                 AC_MSG_RESULT([yes])
 460         ],[
 461                 LB_CHECK_FILE([$LINUX/include/linux/lustre_version.h],[
 462                         AC_MSG_ERROR([You have got no 64-bit kernel quota support.])
 463                 ],[])
 464                 AC_MSG_RESULT([no])
 465         ])
 466 EXTRA_KCFLAGS=$tmp_flags
 467 ])
 468
 469 #
 470 # 2.6.36 fs_struct.lock use spinlock instead of rwlock.
 471 #
 472 AC_DEFUN([LC_FS_STRUCT_RWLOCK],
 473 [AC_MSG_CHECKING([if fs_struct.lock use rwlock])
 474 LB_LINUX_TRY_COMPILE([
 475         #include <asm/atomic.h>
 476         #include <linux/spinlock.h>
 477         #include <linux/fs_struct.h>
 478 ],[
 479         ((struct fs_struct *)0)->lock = (rwlock_t){ 0 };
 480 ],[
 481         AC_DEFINE(HAVE_FS_STRUCT_RWLOCK, 1,
 482                   [fs_struct.lock use rwlock])
 483         AC_MSG_RESULT([yes])
 484 ],[
 485         AC_MSG_RESULT([no])
 486 ])
 487 ])
 488
 489 #
 490 # 2.6.36 super_operations add evict_inode method. it hybird of
 491 # delete_inode & clear_inode.
 492 #
 493 AC_DEFUN([LC_SBOPS_EVICT_INODE],
 494 [AC_MSG_CHECKING([if super_operations.evict_inode exist])
 495 LB_LINUX_TRY_COMPILE([
 496         #include <linux/fs.h>
 497 ],[
 498         ((struct super_operations *)0)->evict_inode(NULL);
 499 ],[
 500         AC_DEFINE(HAVE_SBOPS_EVICT_INODE, 1,
 501                 [super_operations.evict_inode() is exist in kernel])
 502         AC_MSG_RESULT([yes])
 503 ],[
 504         AC_MSG_RESULT([no])
 505 ])
 506 ])
 507
 508 #
 509 # 2.6.35 file_operations.fsync taken 2 arguments.
 510 # 3.0.0 file_operations.fsync takes 4 arguments.
 511 #
 512 AC_DEFUN([LC_FILE_FSYNC],
 513 [AC_MSG_CHECKING([if file_operations.fsync takes 4 or 2 arguments])
 514 LB_LINUX_TRY_COMPILE([
 515         #include <linux/fs.h>
 516 ],[
 517         ((struct file_operations *)0)->fsync(NULL, 0, 0, 0);
 518 ],[
 519         AC_DEFINE(HAVE_FILE_FSYNC_4ARGS, 1,
 520                 [file_operations.fsync takes 4 arguments])
 521         AC_MSG_RESULT([yes, 4 args])
 522 ],[
 523         LB_LINUX_TRY_COMPILE([
 524                 #include <linux/fs.h>
 525         ],[
 526            ((struct file_operations *)0)->fsync(NULL, 0);
 527         ],[
 528                 AC_DEFINE(HAVE_FILE_FSYNC_2ARGS, 1,
 529                         [file_operations.fsync takes 2 arguments])
 530                 AC_MSG_RESULT([yes, 2 args])
 531         ],[
 532                 AC_MSG_RESULT([no])
 533         ])
 534 ])
 535 ])
 536
 537 #
 538 # 2.6.37 remove kernel_locked
 539 #
 540 AC_DEFUN([LC_KERNEL_LOCKED],
 541 [AC_MSG_CHECKING([if kernel_locked is defined])
 542 LB_LINUX_TRY_COMPILE([
 543         #include <linux/smp_lock.h>
 544 ],[
 545         kernel_locked();
 546 ],[
 547         AC_MSG_RESULT([yes])
 548         AC_DEFINE(HAVE_KERNEL_LOCKED, 1,
 549                 [kernel_locked is defined])
 550 ],[
 551         AC_MSG_RESULT([no])
 552 ])
 553 ])
 554
 555 #
 556 # 2.6.38 dentry_operations.d_compare() taken 7 arguments.
 557 #
 558 AC_DEFUN([LC_D_COMPARE_7ARGS],
 559 [AC_MSG_CHECKING([if d_compare taken 7 arguments])
 560 LB_LINUX_TRY_COMPILE([
 561         #include <linux/dcache.h>
 562 ],[
 563         ((struct dentry_operations*)0)->d_compare(NULL,NULL,NULL,NULL,0,NULL,NULL);
 564 ],[
 565         AC_DEFINE(HAVE_D_COMPARE_7ARGS, 1,
 566                 [d_compare need 7 arguments])
 567         AC_MSG_RESULT([yes])
 568 ],[
 569         AC_MSG_RESULT([no])
 570 ])
 571 ])
 572
 573 #
 574 # 2.6.38 dentry_operations.d_delete() defined 'const' for 1st parameter.
 575 #
 576 AC_DEFUN([LC_D_DELETE_CONST],
 577 [AC_MSG_CHECKING([if d_delete has const declare on first parameter])
 578 tmp_flags="$EXTRA_KCFLAGS"
 579 EXTRA_KCFLAGS="-Werror"
 580 LB_LINUX_TRY_COMPILE([
 581         #include <linux/dcache.h>
 582 ],[
 583         const struct dentry *d = NULL;
 584         ((struct dentry_operations*)0)->d_delete(d);
 585 ],[
 586         AC_DEFINE(HAVE_D_DELETE_CONST, const,
 587                 [d_delete first parameter declared const])
 588         AC_MSG_RESULT([yes])
 589 ],[
 590         AC_DEFINE(HAVE_D_DELETE_CONST, , [])
 591         AC_MSG_RESULT([no])
 592 ])
 593 EXTRA_KCFLAGS="$tmp_flags"
 594 ])
 595
 596 #
 597 # 2.6.38 dcache_lock removed. rcu-walk commited.
 598 #
 599 AC_DEFUN([LC_DCACHE_LOCK],
 600 [AC_MSG_CHECKING([if dcache_lock is exist])
 601 LB_LINUX_TRY_COMPILE([
 602         #include <linux/dcache.h>
 603 ],[
 604         spin_lock(&dcache_lock);
 605 ],[
 606         AC_DEFINE(HAVE_DCACHE_LOCK, 1,
 607                 [dcache_lock is exist])
 608         AC_MSG_RESULT([yes])
 609 ],[
 610         AC_MSG_RESULT([no])
 611 ])
 612 ])
 613
 614 #
 615 # 2.6.38 inode.i_rcu added.
 616 #
 617 AC_DEFUN([LC_INODE_I_RCU],
 618 [AC_MSG_CHECKING([if inode.i_rcu exists])
 619 LB_LINUX_TRY_COMPILE([
 620         #include <linux/fs.h>
 621 ],[
 622         struct inode ino;
 623         struct rcu_head rcu = {};
 624         ino.i_rcu = rcu;
 625 ],[
 626         AC_DEFINE(HAVE_INODE_I_RCU, 1,
 627                 [inode.i_rcu exists])
 628         AC_MSG_RESULT([yes])
 629 ],[
 630         AC_MSG_RESULT([no])
 631 ])
 632 ])
 633
 634 #
 635 # 2.6.38 export blkdev_get_by_dev
 636 #
 637 AC_DEFUN([LC_BLKDEV_GET_BY_DEV],
 638 [LB_CHECK_SYMBOL_EXPORT([blkdev_get_by_dev],
 639 [fs/block_dev.c],[
 640 AC_DEFINE(HAVE_BLKDEV_GET_BY_DEV, 1,
 641             [blkdev_get_by_dev is exported by the kernel])
 642 ],[
 643 ])
 644 ])
 645
 646 #
 647 # 2.6.38 export simple_setattr
 648 #
 649 AC_DEFUN([LC_EXPORT_SIMPLE_SETATTR],
 650 [LB_CHECK_SYMBOL_EXPORT([simple_setattr],
 651 [fs/libfs.c],[
 652 AC_DEFINE(HAVE_SIMPLE_SETATTR, 1,
 653             [simple_setattr is exported by the kernel])
 654 ],[
 655 ])
 656 ])
 657
 658 #
 659 # 2.6.39 remove unplug_fn from request_queue.
 660 #
 661 AC_DEFUN([LC_REQUEST_QUEUE_UNPLUG_FN],
 662 [AC_MSG_CHECKING([if request_queue has unplug_fn field])
 663 LB_LINUX_TRY_COMPILE([
 664         #include <linux/blkdev.h>
 665 ],[
 666         do{ }while(sizeof(((struct request_queue *)0)->unplug_fn));
 667 ],[
 668         AC_DEFINE(HAVE_REQUEST_QUEUE_UNPLUG_FN, 1,
 669                   [request_queue has unplug_fn field])
 670         AC_MSG_RESULT([yes])
 671 ],[
 672         AC_MSG_RESULT([no])
 673 ])
 674 ])
 675
 676 #
 677 # 2.6.39 replace get_sb with mount in struct file_system_type
 678 #
 679 AC_DEFUN([LC_HAVE_FSTYPE_MOUNT],
 680 [AC_MSG_CHECKING([if file_system_type has mount field])
 681 LB_LINUX_TRY_COMPILE([
 682         #include <linux/fs.h>
 683 ],[
 684         struct file_system_type fst;
 685         void *i = (void *) fst.mount;
 686 ],[
 687         AC_DEFINE(HAVE_FSTYPE_MOUNT, 1,
 688                 [struct file_system_type has mount field])
 689         AC_MSG_RESULT([yes])
 690 ],[
 691         AC_MSG_RESULT([no])
 692 ])
 693 ])
 694
 695 #
 696 # 3.0 dirty_inode() has a flag parameter
 697 # see kernel commit aa38572954ade525817fe88c54faebf85e5a61c0
 698 #
 699 AC_DEFUN([LC_DIRTY_INODE_WITH_FLAG],
 700 [AC_MSG_CHECKING([if dirty_inode super_operation takes flag])
 701 LB_LINUX_TRY_COMPILE([
 702         #include <linux/fs.h>
 703 ],[
 704         struct inode *inode;
 705         inode->i_sb->s_op->dirty_inode(NULL, 0);
 706 ],[
 707         AC_DEFINE(HAVE_DIRTY_INODE_HAS_FLAG, 1,
 708                   [dirty_inode super_operation takes flag])
 709         AC_MSG_RESULT([yes])
 710 ],[
 711         AC_MSG_RESULT([no])
 712 ])
 713 ])
 714
 715 #
 716 # 2.6.38 generic_permission taken 4 parameters.
 717 # in fact, it means rcu-walk aware permission bring.
 718 #
 719 # 3.1 generic_permission taken 2 parameters.
 720 # see kernel commit 2830ba7f34ebb27c4e5b8b6ef408cd6d74860890
 721 #
 722 AC_DEFUN([LC_GENERIC_PERMISSION],
 723 [AC_MSG_CHECKING([if generic_permission take 2 or 4 arguments])
 724 LB_LINUX_TRY_COMPILE([
 725         #include <linux/fs.h>
 726 ],[
 727         generic_permission(NULL, 0);
 728 ],[
 729         AC_DEFINE(HAVE_GENERIC_PERMISSION_2ARGS, 1,
 730                   [generic_permission taken 2 arguments])
 731         AC_MSG_RESULT([yes, 2 args])
 732 ],[
 733         LB_LINUX_TRY_COMPILE([
 734                 #include <linux/fs.h>
 735         ],[
 736                 generic_permission(NULL, 0, 0, NULL);
 737         ],[
 738                 AC_DEFINE(HAVE_GENERIC_PERMISSION_4ARGS, 1,
 739                           [generic_permission taken 4 arguments])
 740                 AC_MSG_RESULT([yes, 4 args])
 741         ],[
 742                 AC_MSG_RESULT([no])
 743         ])
 744 ])
 745 ])
 746
 747 #
 748 # 3.1 renames lock-manager ops(lock_manager_operations) from fl_xxx to lm_xxx
 749 # see kernel commit 8fb47a4fbf858a164e973b8ea8ef5e83e61f2e50
 750 #
 751 AC_DEFUN([LC_LM_XXX_LOCK_MANAGER_OPS],
 752 [AC_MSG_CHECKING([if lock-manager ops renamed to lm_xxx])
 753 LB_LINUX_TRY_COMPILE([
 754         #include <linux/fs.h>
 755 ],[
 756         struct lock_manager_operations lm_ops;
 757         lm_ops.lm_compare_owner = NULL;
 758 ],[
 759         AC_DEFINE(HAVE_LM_XXX_LOCK_MANAGER_OPS, 1,
 760                   [lock-manager ops renamed to lm_xxx])
 761         AC_MSG_RESULT([yes])
 762 ],[
 763         AC_MSG_RESULT([no])
 764 ])
 765 ])
 766
 767 #
 768 # 3.1 kills inode->i_alloc_sem, use i_dio_count and inode_dio_wait/
 769 #     inode_dio_done instead.
 770 # see kernel commit bd5fe6c5eb9c548d7f07fe8f89a150bb6705e8e3
 771 #
 772 AC_DEFUN([LC_INODE_DIO_WAIT],
 773 [AC_MSG_CHECKING([if inode->i_alloc_sem is killed and use inode_dio_wait/done.])
 774 LB_LINUX_TRY_COMPILE([
 775         #include <linux/fs.h>
 776 ],[
 777         inode_dio_wait((struct inode *)0);
 778         inode_dio_done((struct inode *)0);
 779 ],[
 780         AC_DEFINE(HAVE_INODE_DIO_WAIT, 1,
 781                   [inode->i_alloc_sem is killed and use inode_dio_wait/done])
 782         AC_MSG_RESULT([yes])
 783 ],[
 784         AC_MSG_RESULT([no])
 785 ])
 786 ])
 787
 788 #
 789 # 3.1 adds get_acl method to inode_operations to read ACL from disk.
 790 # see kernel commit 4e34e719e457f2e031297175410fc0bd4016a085
 791 #
 792 AC_DEFUN([LC_IOP_GET_ACL],
 793 [AC_MSG_CHECKING([inode_operations has .get_acl member function])
 794 LB_LINUX_TRY_COMPILE([
 795         #include <linux/fs.h>
 796 ],[
 797         struct inode_operations iop;
 798         iop.get_acl = NULL;
 799 ],[
 800         AC_DEFINE(HAVE_IOP_GET_ACL, 1,
 801                   [inode_operations has .get_acl member function])
 802         AC_MSG_RESULT([yes])
 803 ],[
 804         AC_MSG_RESULT([no])
 805 ])
 806 ])
 807
 808 #
 809 # 3.1 introduced generic_file_llseek_size()
 810 #
 811 AC_DEFUN([LC_FILE_LLSEEK_SIZE],
 812         [LB_CHECK_SYMBOL_EXPORT([generic_file_llseek_size],
 813         [fs/read_write.c],
 814         [AC_DEFINE(HAVE_FILE_LLSEEK_SIZE, 1,
 815                    [generic_file_llseek_size is exported by the kernel])])
 816 ])
 817
 818 #
 819 # 3.2 request_queue.make_request_fn defined as function returns with void
 820 # see kernel commit 5a7bbad27a410350e64a2d7f5ec18fc73836c14f
 821 #
 822 AC_DEFUN([LC_HAVE_VOID_MAKE_REQUEST_FN],
 823 [AC_MSG_CHECKING([if request_queue.make_request_fn returns void but not int])
 824 LB_LINUX_TRY_COMPILE([
 825         #include <linux/blkdev.h>
 826 ],[
 827         int ret;
 828         make_request_fn         *mrf;
 829         ret = mrf(NULL, NULL);
 830 ],[
 831         AC_MSG_RESULT([no])
 832 ],[
 833         AC_DEFINE(HAVE_VOID_MAKE_REQUEST_FN, 1,
 834                   [request_queue.make_request_fn returns void but not int])
 835         AC_MSG_RESULT([yes])
 836 ])
 837 ])
 838
 839 #
 840 # 3.2 protects inode->i_nlink from direct modification
 841 # see kernel commit a78ef704a8dd430225955f0709b22d4a6ba21deb
 842 # at the same time adds set_nlink(), so checks set_nlink() for it.
 843 #
 844 AC_DEFUN([LC_HAVE_PROTECT_I_NLINK],
 845 [AC_MSG_CHECKING([if inode->i_nlink is protected from direct modification])
 846 LB_LINUX_TRY_COMPILE([
 847         #include <linux/fs.h>
 848 ],[
 849         struct inode i;
 850         set_nlink(&i, 1);
 851 ],[
 852         AC_DEFINE(HAVE_PROTECT_I_NLINK, 1,
 853                   [inode->i_nlink is protected from direct modification])
 854         AC_MSG_RESULT([yes])
 855 ],[
 856         AC_MSG_RESULT([no])
 857 ])
 858 ])
 859
 860 #
 861 # 3.3 introduces migrate_mode.h and migratepage has 4 args
 862 #
 863 AC_DEFUN([LC_HAVE_MIGRATE_HEADER],
 864 [LB_CHECK_FILE([$LINUX/include/linux/migrate.h],[
 865                 AC_DEFINE(HAVE_MIGRATE_H, 1,
 866                 [kernel has include/linux/migrate.h])
 867 ],[LB_CHECK_FILE([$LINUX/include/linux/migrate_mode.h],[
 868                 AC_DEFINE(HAVE_MIGRATE_MODE_H, 1,
 869                         [kernel has include/linux/migrate_mode.h])
 870 ],[
 871         AC_MSG_RESULT([no])
 872 ])
 873 ])
 874 ])
 875
 876 AC_DEFUN([LC_MIGRATEPAGE_4ARGS],
 877 [AC_MSG_CHECKING([if address_space_operations.migratepage has 4 args])
 878 LB_LINUX_TRY_COMPILE([
 879         #include <linux/fs.h>
 880 #ifdef HAVE_MIGRATE_H
 881         #include <linux/migrate.h>
 882 #elif defined(HAVE_MIGRATE_MODE_H)
 883         #include <linux/migrate_mode.h>
 884 #endif
 885 ],[
 886         struct address_space_operations aops;
 887
 888         aops.migratepage(NULL, NULL, NULL, MIGRATE_ASYNC);
 889 ],[
 890         AC_DEFINE(HAVE_MIGRATEPAGE_4ARGS, 1,
 891                 [address_space_operations.migratepage has 4 args])
 892         AC_MSG_RESULT([yes])
 893 ],[
 894         AC_MSG_RESULT([no])
 895 ])
 896 ])
 897
 898 #
 899 # 3.3 switchs super_operations to use dentry as parameter (but not vfsmount)
 900 # see kernel commit 34c80b1d93e6e20ca9dea0baf583a5b5510d92d4
 901 #
 902 AC_DEFUN([LC_SUPEROPS_USE_DENTRY],
 903 [AC_MSG_CHECKING([if super_operations use dentry as parameter])
 904 tmp_flags="$EXTRA_KCFLAGS"
 905 EXTRA_KCFLAGS="-Werror"
 906 LB_LINUX_TRY_COMPILE([
 907         #include <linux/fs.h>
 908         int show_options(struct seq_file *seq, struct dentry *root){
 909                 return 0;
 910         }
 911 ],[
 912         struct super_operations ops;
 913         ops.show_options = show_options;
 914 ],[
 915         AC_DEFINE(HAVE_SUPEROPS_USE_DENTRY, 1,
 916                   [super_operations use dentry as parameter])
 917         AC_MSG_RESULT([yes])
 918 ],[
 919         AC_MSG_RESULT([no])
 920 ])
 921 EXTRA_KCFLAGS="$tmp_flags"
 922 ])
 923
 924 #
 925 # 3.3 switchs inode_operations to use umode_t as parameter (but not int)
 926 # see kernel commit 1a67aafb5f72a436ca044293309fa7e6351d6a35
 927 #
 928 AC_DEFUN([LC_INODEOPS_USE_UMODE_T],
 929 [AC_MSG_CHECKING([if inode_operations use umode_t as parameter])
 930 tmp_flags="$EXTRA_KCFLAGS"
 931 EXTRA_KCFLAGS="-Werror"
 932 LB_LINUX_TRY_COMPILE([
 933         #include <linux/fs.h>
 934         #include <linux/types.h>
 935         int my_mknod(struct inode *dir, struct dentry *dchild,
 936                      umode_t mode, dev_t dev)
 937         {
 938                 return 0;
 939         }
 940 ],[
 941         struct inode_operations ops;
 942         ops.mknod = my_mknod;
 943 ],[
 944         AC_DEFINE(HAVE_INODEOPS_USE_UMODE_T, 1,
 945                   [inode_operations use umode_t as parameter])
 946         AC_MSG_RESULT([yes])
 947 ],[
 948         AC_MSG_RESULT([no])
 949 ])
 950 EXTRA_KCFLAGS="$tmp_flags"
 951 ])
 952
 953 # 3.4 kmap_atomic removes second argument
 954 # see kernel commit 1ec9c5ddc17aa398f05646abfcbaf315b544e62f
 955 #
 956 AC_DEFUN([LC_KMAP_ATOMIC_HAS_1ARG],
 957 [AC_MSG_CHECKING([if kmap_atomic has only 1 argument])
 958 LB_LINUX_TRY_COMPILE([
 959         #include <linux/highmem.h>
 960 ],[
 961         kmap_atomic(NULL);
 962 ],[
 963         AC_DEFINE(HAVE_KMAP_ATOMIC_HAS_1ARG, 1,
 964                   [have kmap_atomic has only 1 argument])
 965         AC_MSG_RESULT([yes])
 966 ],[
 967         AC_MSG_RESULT([no])
 968 ])
 969 ])
 970
 971 #
 972 # 3.4 switchs touch_atime to struct path
 973 # see kernel commit 68ac1234fb949b66941d94dce4157742799fc581
 974 #
 975 AC_DEFUN([LC_TOUCH_ATIME_1ARG],
 976 [AC_MSG_CHECKING([if touch_atime use one argument])
 977 LB_LINUX_TRY_COMPILE([
 978         #include <linux/fs.h>
 979 ],[
 980         touch_atime((struct path *)NULL);
 981 ],[
 982         AC_DEFINE(HAVE_TOUCH_ATIME_1ARG, 1,
 983                   [touch_atime use one argument])
 984         AC_MSG_RESULT([yes])
 985 ],[
 986         AC_MSG_RESULT([no])
 987 ])
 988 ])
 989
 990 #
 991 # 3.4 converts d_alloc_root to d_make_root
 992 # see kernel commit 32991ab305ace7017c62f8eecbe5eb36dc32e13b
 993 #
 994 AC_DEFUN([LC_HAVE_D_MAKE_ROOT],
 995 [AC_MSG_CHECKING([if have d_make_root])
 996 LB_LINUX_TRY_COMPILE([
 997         #include <linux/fs.h>
 998 ],[
 999         d_make_root((struct inode *)NULL);
1000 ],[
1001         AC_DEFINE(HAVE_D_MAKE_ROOT, 1,
1002                   [have d_make_root])
1003         AC_MSG_RESULT([yes])
1004 ],[
1005         AC_MSG_RESULT([no])
1006 ])
1007 ])
1008
1009 #
1010 # 3.5 renames end_writeback() back to clear_inode()...
1011 # see kernel commit dbd5768f87ff6fb0a4fe09c4d7b6c4a24de99430
1012 #
1013 AC_DEFUN([LC_HAVE_CLEAR_INODE],
1014 [AC_MSG_CHECKING([if have clear_inode])
1015 LB_LINUX_TRY_COMPILE([
1016         #include <linux/fs.h>
1017 ],[
1018         clear_inode((struct inode *)NULL);
1019 ],[
1020         AC_DEFINE(HAVE_CLEAR_INODE, 1,
1021                   [have clear_inode])
1022         AC_MSG_RESULT([yes])
1023 ],[
1024         AC_MSG_RESULT([no])
1025 ])
1026 ])
1027
1028 #
1029 # 3.5 encode_fh has parent inode passed in directly
1030 # see kernel commit b0b0382b
1031 #
1032 AC_DEFUN([LC_HAVE_ENCODE_FH_PARENT],
1033 [AC_MSG_CHECKING([if encode_fh have parent inode as parameter])
1034 tmp_flags="$EXTRA_KCFLAGS"
1035 EXTRA_KCFLAGS="-Werror"
1036 LB_LINUX_TRY_COMPILE([
1037         #include <linux/exportfs.h>
1038         #include <linux/fs.h>
1039         #include <linux/types.h>
1040         int ll_encode_fh(struct inode *i, __u32 *a, int *b, struct inode *p)
1041         {
1042                 return 0;
1043         }
1044 ],[
1045         struct export_operations exp_op;
1046         exp_op.encode_fh = ll_encode_fh;
1047 ],[
1048         AC_DEFINE(HAVE_ENCODE_FH_PARENT, 1,
1049                   [have parent inode as parameter])
1050         AC_MSG_RESULT([yes])
1051 ],[
1052         AC_MSG_RESULT([no])
1053 ])
1054 EXTRA_KCFLAGS="$tmp_flags"
1055 ])
1056
1057 # 3.5 has generic_file_llseek_size with 5 args
1058 AC_DEFUN([LC_FILE_LLSEEK_SIZE_5ARG],
1059 [AC_MSG_CHECKING([if kernel has generic_file_llseek_size with 5 args])
1060 LB_LINUX_TRY_COMPILE([
1061         #include <linux/fs.h>
1062 ],[
1063         generic_file_llseek_size(NULL, 0, 0, 0, 0);
1064 ], [
1065         AC_MSG_RESULT([yes])
1066         AC_DEFINE(HAVE_FILE_LLSEEK_SIZE_5ARGS, 1,
1067                 [kernel has generic_file_llseek_size with 5 args])
1068 ],[
1069         AC_MSG_RESULT([no])
1070 ])
1071 ])
1072
1073 #
1074 # 3.6 switch i_dentry/d_alias from list to hlist
1075 #
1076 AC_DEFUN([LC_HAVE_DENTRY_D_ALIAS_HLIST],
1077 [AC_MSG_CHECKING([if i_dentry/d_alias uses hlist])
1078 tmp_flags="$EXTRA_KCFLAGS"
1079 EXTRA_KCFLAGS="-Werror"
1080 LB_LINUX_TRY_COMPILE([
1081         #include <linux/fs.h>
1082         #include <linux/list.h>
1083 ],[
1084         struct inode inode;
1085         struct dentry dentry;
1086         struct hlist_head head;
1087         struct hlist_node node;
1088         inode.i_dentry = head;
1089         dentry.d_alias = node;
1090 ],[
1091         AC_DEFINE(HAVE_DENTRY_D_ALIAS_HLIST, 1,
1092                   [have i_dentry/d_alias uses hlist])
1093         AC_MSG_RESULT([yes])
1094 ],[
1095         AC_MSG_RESULT([no])
1096 ])
1097 EXTRA_KCFLAGS="$tmp_flags"
1098 ])
1099
1100 #
1101 # 3.6 dentry_open uses struct path as first argument
1102 # see kernel commit 765927b2
1103 #
1104 AC_DEFUN([LC_DENTRY_OPEN_USE_PATH],
1105 [AC_MSG_CHECKING([if dentry_open uses struct path as first argument])
1106 tmp_flags="$EXTRA_KCFLAGS"
1107 EXTRA_KCFLAGS="-Werror"
1108 LB_LINUX_TRY_COMPILE([
1109         #include <linux/fs.h>
1110         #include <linux/path.h>
1111 ],[
1112         struct path path;
1113         dentry_open(&path, 0, NULL);
1114 ],[
1115         AC_DEFINE(HAVE_DENTRY_OPEN_USE_PATH, 1,
1116                   [dentry_open uses struct path as first argument])
1117         AC_MSG_RESULT([yes])
1118 ],[
1119         AC_MSG_RESULT([no])
1120 ])
1121 EXTRA_KCFLAGS="$tmp_flags"
1122 ])
1123
1124 #
1125 # 3.6 vfs adds iop->atomic_open
1126 #
1127 AC_DEFUN([LC_HAVE_IOP_ATOMIC_OPEN],
1128 [AC_MSG_CHECKING([if iop has atomic_open])
1129 LB_LINUX_TRY_COMPILE([
1130         #include <linux/fs.h>
1131 ],[
1132         struct inode_operations iop;
1133         iop.atomic_open = NULL;
1134 ],[
1135         AC_DEFINE(HAVE_IOP_ATOMIC_OPEN, 1,
1136                   [have iop atomic_open])
1137         AC_MSG_RESULT([yes])
1138 ],[
1139         AC_MSG_RESULT([no])
1140 ])
1141 ])
1142
1143 #
1144 # 3.7 posix_acl_{to,from}_xattr take struct user_namespace
1145 #
1146 AC_DEFUN([LC_HAVE_POSIXACL_USER_NS],
1147 [AC_MSG_CHECKING([if posix_acl_to_xattr takes struct user_namespace])
1148 LB_LINUX_TRY_COMPILE([
1149         #include <linux/fs.h>
1150         #include <linux/posix_acl_xattr.h>
1151 ],[
1152         posix_acl_to_xattr((struct user_namespace *)NULL, NULL, NULL, 0);
1153 ],[
1154         AC_DEFINE(HAVE_POSIXACL_USER_NS, 1,
1155                   [posix_acl_to_xattr takes struct user_namespace])
1156         AC_MSG_RESULT([yes])
1157 ],[
1158         AC_MSG_RESULT([no])
1159 ])
1160 ])
1161
1162 #
1163 # 3.8 struct file has new memeber f_inode
1164 #
1165 AC_DEFUN([LC_HAVE_FILE_F_INODE],
1166 [AC_MSG_CHECKING([if struct file has memeber f_inode])
1167 LB_LINUX_TRY_COMPILE([
1168         #include <linux/fs.h>
1169 ],[
1170         ((struct file *)0)->f_inode = NULL;
1171 ],[
1172         AC_DEFINE(HAVE_FILE_F_INODE, 1,
1173                   [struct file has memeber f_inode])
1174         AC_MSG_RESULT([yes])
1175 ],[
1176         AC_MSG_RESULT([no])
1177 ])
1178 ])
1179
1180 #
1181 # 3.9 uses hlist_for_each_entry with 3 args
1182 # b67bfe0d42cac56c512dd5da4b1b347a23f4b70a
1183 #
1184 AC_DEFUN([LC_HAVE_HLIST_FOR_EACH_3ARG],
1185 [AC_MSG_CHECKING([if hlist_for_each_entry has 3 args])
1186 LB_LINUX_TRY_COMPILE([
1187         #include <linux/list.h>
1188         #include <linux/fs.h>
1189 ],[
1190         struct inode *inode;
1191         struct dentry *dentry;
1192         hlist_for_each_entry(dentry, &inode->i_dentry, d_alias) {
1193                 continue;
1194         }
1195 ],[
1196         AC_DEFINE(HAVE_HLIST_FOR_EACH_3ARG, 1, [3 args])
1197         AC_MSG_RESULT([yes])
1198 ],[
1199         AC_MSG_RESULT([no])
1200 ])
1201 ])
1202
1203 #
1204 # 3.9 killed f_vfsmnt by
1205 # 182be684784334598eee1d90274e7f7aa0063616
1206 # replacement is f_path.mnt
1207 #
1208 AC_DEFUN([LC_HAVE_F_PATH_MNT],
1209 [AC_MSG_CHECKING([if struct file has f_path.mnt])
1210 LB_LINUX_TRY_COMPILE([
1211         #include <linux/fs.h>
1212 ],[
1213         struct file *fp = NULL;
1214         struct path  path;
1215
1216         path.mnt = fp->f_path.mnt;
1217 ],[
1218         AC_DEFINE(HAVE_F_PATH_MNT,1,[yes])
1219         AC_MSG_RESULT([yes])
1220 ],[
1221         AC_MSG_RESULT([no])
1222 ])
1223 ])
1224
1225 #
1226 # LC_PROG_LINUX
1227 #
1228 # Lustre linux kernel checks
1229 #
1230 AC_DEFUN([LC_PROG_LINUX],
1231          [
1232          LC_CONFIG_PINGER
1233          LC_CONFIG_CHECKSUM
1234          LC_CONFIG_LIBLUSTRE_RECOVERY
1235          LC_CONFIG_HEALTH_CHECK_WRITE
1236          LC_CONFIG_LRU_RESIZE
1237          LC_LLITE_LLOOP_MODULE
1238
1239          LC_CAPA_CRYPTO
1240          LC_CONFIG_RMTCLIENT
1241          LC_CONFIG_GSS
1242
1243          # 2.6.32
1244          LC_BLK_QUEUE_MAX_SEGMENTS
1245
1246          # 2.6.34
1247          LC_HAVE_DQUOT_FS_DISK_QUOTA
1248          LC_HAVE_DQUOT_SUSPEND
1249
1250          # 2.6.35, 3.0.0
1251          LC_FILE_FSYNC
1252          LC_EXPORT_SIMPLE_SETATTR
1253          LC_EXPORT_TRUNCATE_COMPLETE_PAGE
1254
1255          # 2.6.36
1256          LC_FS_STRUCT_RWLOCK
1257          LC_SBOPS_EVICT_INODE
1258
1259          # 2.6.37
1260          LC_KERNEL_LOCKED
1261
1262          # 2.6.38
1263          LC_BLKDEV_GET_BY_DEV
1264          LC_GENERIC_PERMISSION
1265          LC_DCACHE_LOCK
1266          LC_INODE_I_RCU
1267          LC_D_COMPARE_7ARGS
1268          LC_D_DELETE_CONST
1269
1270          # 2.6.39
1271          LC_REQUEST_QUEUE_UNPLUG_FN
1272          LC_HAVE_FSTYPE_MOUNT
1273
1274          # 3.0
1275          LC_DIRTY_INODE_WITH_FLAG
1276
1277          # 3.1
1278          LC_LM_XXX_LOCK_MANAGER_OPS
1279          LC_INODE_DIO_WAIT
1280          LC_IOP_GET_ACL
1281          LC_FILE_LLSEEK_SIZE
1282          LC_INODE_PERMISION_2ARGS
1283
1284          # 3.2
1285          LC_HAVE_VOID_MAKE_REQUEST_FN
1286          LC_HAVE_PROTECT_I_NLINK
1287
1288          # 3.3
1289          LC_HAVE_MIGRATE_HEADER
1290          LC_MIGRATEPAGE_4ARGS
1291          LC_SUPEROPS_USE_DENTRY
1292          LC_INODEOPS_USE_UMODE_T
1293
1294          # 3.4
1295          LC_TOUCH_ATIME_1ARG
1296          LC_HAVE_D_MAKE_ROOT
1297          LC_KMAP_ATOMIC_HAS_1ARG
1298
1299          # 3.5
1300          LC_HAVE_CLEAR_INODE
1301          LC_HAVE_ENCODE_FH_PARENT
1302          LC_FILE_LLSEEK_SIZE_5ARG
1303
1304          # 3.6
1305          LC_HAVE_DENTRY_D_ALIAS_HLIST
1306          LC_DENTRY_OPEN_USE_PATH
1307          LC_HAVE_IOP_ATOMIC_OPEN
1308
1309          # 3.7
1310          LC_HAVE_POSIXACL_USER_NS
1311
1312          # 3.8
1313          LC_HAVE_FILE_F_INODE
1314
1315          # 3.9
1316          LC_HAVE_HLIST_FOR_EACH_3ARG
1317          LC_HAVE_F_PATH_MNT
1318
1319          #
1320          if test x$enable_server != xno ; then
1321                 LC_FUNC_DEV_SET_RDONLY
1322                 LC_STACK_SIZE
1323                 LC_QUOTA64
1324                 LC_QUOTA_CONFIG
1325          fi
1326 ])
1327
1328 #
1329 # LC_CONFIG_CLIENT
1330 #
1331 # Check whether to build the client side of Lustre
1332 #
1333 AC_DEFUN([LC_CONFIG_CLIENT],
1334 [AC_MSG_CHECKING([whether to build Lustre client support])
1335 AC_ARG_ENABLE([client],
1336         AC_HELP_STRING([--disable-client],
1337                         [disable Lustre client support]),
1338         [],[enable_client='yes'])
1339 AC_MSG_RESULT([$enable_client])
1340 ])
1341
1342 #
1343 # LC_CONFIG_LIBLUSTRE
1344 #
1345 # whether to build liblustre
1346 #
1347 AC_DEFUN([LC_CONFIG_LIBLUSTRE],
1348 [AC_MSG_CHECKING([whether to build Lustre library])
1349 AC_ARG_ENABLE([liblustre],
1350         AC_HELP_STRING([--disable-liblustre],
1351                         [disable building of Lustre library]),
1352         [],[enable_liblustre=$with_sysio])
1353 AC_MSG_RESULT([$enable_liblustre])
1354 # only build sysio if liblustre is built
1355 with_sysio="$enable_liblustre"
1356
1357 AC_MSG_CHECKING([whether to build liblustre tests])
1358 AC_ARG_ENABLE([liblustre-tests],
1359         AC_HELP_STRING([--enable-liblustre-tests],
1360                         [enable liblustre tests, if --disable-tests is used]),
1361         [],[enable_liblustre_tests=$enable_tests])
1362 if test x$enable_liblustre != xyes ; then
1363    enable_liblustre_tests='no'
1364 fi
1365 AC_MSG_RESULT([$enable_liblustre_tests])
1366
1367 AC_MSG_CHECKING([whether to enable liblustre acl])
1368 AC_ARG_ENABLE([liblustre-acl],
1369         AC_HELP_STRING([--disable-liblustre-acl],
1370                         [disable ACL support for liblustre]),
1371         [],[enable_liblustre_acl=yes])
1372 AC_MSG_RESULT([$enable_liblustre_acl])
1373 if test x$enable_liblustre_acl = xyes ; then
1374   AC_DEFINE(LIBLUSTRE_POSIX_ACL, 1, Liblustre Support ACL-enabled MDS)
1375 fi
1376
1377 #
1378 # --enable-mpitest
1379 #
1380 AC_ARG_ENABLE(mpitests,
1381         AC_HELP_STRING([--enable-mpitests=yes|no|mpicc wrapper],
1382                            [include mpi tests]),
1383         [
1384          enable_mpitests=yes
1385          case $enableval in
1386          yes)
1387                 MPICC_WRAPPER=mpicc
1388                 ;;
1389          no)
1390                 enable_mpitests=no
1391                 ;;
1392          *)
1393                 MPICC_WRAPPER=$enableval
1394                  ;;
1395          esac
1396         ],
1397         [
1398         MPICC_WRAPPER=mpicc
1399         enable_mpitests=yes
1400         ]
1401 )
1402
1403 if test x$enable_mpitests != xno; then
1404         AC_MSG_CHECKING([whether mpitests can be built])
1405         oldcc=$CC
1406         CC=$MPICC_WRAPPER
1407         AC_LINK_IFELSE(
1408             [AC_LANG_PROGRAM([[
1409                     #include <mpi.h>
1410                 ]],[[
1411                     int flag;
1412                     MPI_Initialized(&flag);
1413                 ]])],
1414             [
1415                     AC_MSG_RESULT([yes])
1416             ],[
1417                     AC_MSG_RESULT([no])
1418                     enable_mpitests=no
1419         ])
1420         CC=$oldcc
1421 fi
1422 AC_SUBST(MPICC_WRAPPER)
1423
1424 AC_MSG_NOTICE([Enabling Lustre configure options for libsysio])
1425 ac_configure_args="$ac_configure_args --with-lustre-hack --with-sockets"
1426
1427 LC_CONFIG_PINGER
1428 LC_CONFIG_LIBLUSTRE_RECOVERY
1429 ])
1430
1431 #
1432 # LC_CONFIG_QUOTA
1433 #
1434 # whether to enable quota support global control
1435 #
1436 AC_DEFUN([LC_CONFIG_QUOTA],
1437 [AC_ARG_ENABLE([quota],
1438         AC_HELP_STRING([--enable-quota],
1439                         [enable quota support]),
1440         [],[enable_quota='yes'])
1441 ])
1442
1443 AC_DEFUN([LC_QUOTA],
1444 [#check global
1445 LC_CONFIG_QUOTA
1446 #check for utils
1447 if test x$enable_quota != xno -a x$enable_utils != xno; then
1448 AC_CHECK_HEADER(sys/quota.h,
1449                 [AC_DEFINE(HAVE_SYS_QUOTA_H, 1, [Define to 1 if you have <sys/quota.h>.])],
1450                 [AC_MSG_ERROR([don't find <sys/quota.h> in your system])])
1451 fi
1452 ])
1453
1454 #
1455 # LC_CONFIG_SPLIT
1456 #
1457 # whether to enable split support
1458 #
1459 AC_DEFUN([LC_CONFIG_SPLIT],
1460 [AC_MSG_CHECKING([whether to enable split support])
1461 AC_ARG_ENABLE([split],
1462         AC_HELP_STRING([--enable-split],
1463                         [enable split support]),
1464         [],[enable_split='no'])
1465 AC_MSG_RESULT([$enable_split])
1466 if test x$enable_split != xno; then
1467    AC_DEFINE(HAVE_SPLIT_SUPPORT, 1, [enable split support])
1468 fi
1469 ])
1470
1471 #
1472 # LC_LLITE_LLOOP_MODULE
1473 # lloop_llite.ko does not currently work with page sizes
1474 # of 64k or larger.
1475 #
1476 AC_DEFUN([LC_LLITE_LLOOP_MODULE],
1477 [AC_MSG_CHECKING([whether to enable llite_lloop module])
1478 LB_LINUX_TRY_COMPILE([
1479         #include <asm/page.h>
1480 ],[
1481         #if PAGE_SIZE >= 65536
1482         #error "PAGE_SIZE >= 65536"
1483         #endif
1484 ],[
1485         enable_llite_lloop_module='yes'
1486         AC_MSG_RESULT([yes])
1487 ],[
1488         enable_llite_lloop_module='no'
1489         AC_MSG_RESULT([no])
1490 ])
1491 ])
1492
1493 #
1494 # LC_OSD_ADDON
1495 #
1496 # configure support for optional OSD implementation
1497 #
1498 AC_DEFUN([LC_OSD_ADDON],
1499 [AC_MSG_CHECKING([for osd])
1500 AC_ARG_WITH([osd],
1501         AC_HELP_STRING([--with-osd=path],
1502                        [set path to optional osd]),
1503         [
1504                 case $with_osd in
1505                         no)     ENABLEOSDADDON=0
1506                                 ;;
1507                         *)      OSDADDON="${with_osd}"
1508                                 ENABLEOSDADDON=1
1509                                 ;;
1510                 esac
1511         ], [
1512                 ENABLEOSDADDON=0
1513         ])
1514 if test $ENABLEOSDADDON -eq 0; then
1515         AC_MSG_RESULT([no])
1516         OSDADDON=
1517 else
1518         OSDMODNAME=`basename $OSDADDON`
1519         if test -e $LUSTRE/$OSDMODNAME; then
1520                 AC_MSG_RESULT([can't link])
1521                 OSDADDON=
1522         elif ln -s $OSDADDON $LUSTRE/$OSDMODNAME; then
1523                 AC_MSG_RESULT([$OSDMODNAME])
1524                 OSDADDON="subdir-m += $OSDMODNAME"
1525         else
1526                 AC_MSG_RESULT([can't link])
1527                 OSDADDON=
1528         fi
1529 fi
1530 AC_SUBST(OSDADDON)
1531 ])
1532
1533 #
1534 # LC_CONFIGURE
1535 #
1536 # other configure checks
1537 #
1538 AC_DEFUN([LC_CONFIGURE],
1539 [LC_CONFIG_OBD_BUFFER_SIZE
1540
1541 if test $target_cpu == "i686" -o $target_cpu == "x86_64"; then
1542         CFLAGS="$CFLAGS -Werror"
1543 fi
1544
1545 # maximum MDS thread count
1546 LC_MDS_MAX_THREADS
1547
1548 # include/liblustre.h
1549 AC_CHECK_HEADERS([sys/user.h sys/vfs.h stdint.h blkid/blkid.h])
1550
1551 # liblustre/llite_lib.h
1552 AC_CHECK_HEADERS([xtio.h file.h])
1553
1554 # liblustre/dir.c
1555 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
1556
1557 # liblustre/lutil.c
1558 AC_CHECK_HEADERS([netinet/in.h arpa/inet.h catamount/data.h])
1559 AC_CHECK_FUNCS([inet_ntoa])
1560
1561 # libsysio/src/readlink.c
1562 LC_READLINK_SSIZE_T
1563
1564 # libcfs prng.c - depends on linux/types.h from liblustre/dir.c
1565 AC_CHECK_HEADERS([linux/random.h], [], [],
1566                  [#ifdef HAVE_LINUX_TYPES_H
1567                   # include <linux/types.h>
1568                   #endif
1569                  ])
1570
1571 # utils/llverfs.c
1572 AC_CHECK_HEADERS([ext2fs/ext2fs.h])
1573
1574 # check for -lz support
1575 ZLIB=""
1576 AC_CHECK_LIB([z],
1577              [adler32],
1578              [AC_CHECK_HEADERS([zlib.h],
1579                                [ZLIB="-lz"
1580                                 AC_DEFINE([HAVE_ADLER], 1,
1581                                           [support alder32 checksum type])],
1582                                [AC_MSG_WARN([No zlib-devel package found,
1583                                              unable to use adler32 checksum])])],
1584              [AC_MSG_WARN([No zlib package found, unable to use adler32 checksum])]
1585 )
1586 AC_SUBST(ZLIB)
1587
1588 SELINUX=""
1589 AC_CHECK_LIB([selinux],
1590                 [is_selinux_enabled],
1591                 [AC_CHECK_HEADERS([selinux.h],
1592                                 [SELINUX="-lselinux"
1593                                 AC_DEFINE([HAVE_SELINUX], 1,
1594                                                 [support for selinux ])],
1595                                 [AC_MSG_WARN([No selinux-devel package found,
1596                                                 unable to build selinux enabled
1597                                                 tools])])],
1598                 [AC_MSG_WARN([No selinux package found, unable to build selinux
1599                                 enabled tools])]
1600 )
1601 AC_SUBST(SELINUX)
1602
1603 # Super safe df
1604 AC_ARG_ENABLE([mindf],
1605       AC_HELP_STRING([--enable-mindf],
1606                       [Make statfs report the minimum available space on any single OST instead of the sum of free space on all OSTs]),
1607       [],[])
1608 if test "$enable_mindf" = "yes" ;  then
1609       AC_DEFINE([MIN_DF], 1, [Report minimum OST free space])
1610 fi
1611
1612 AC_ARG_ENABLE([fail_alloc],
1613         AC_HELP_STRING([--disable-fail-alloc],
1614                 [disable randomly alloc failure]),
1615         [],[enable_fail_alloc=yes])
1616 AC_MSG_CHECKING([whether to randomly failing memory alloc])
1617 AC_MSG_RESULT([$enable_fail_alloc])
1618 if test x$enable_fail_alloc != xno ; then
1619         AC_DEFINE([RANDOM_FAIL_ALLOC], 1, [enable randomly alloc failure])
1620 fi
1621
1622 AC_ARG_ENABLE([invariants],
1623         AC_HELP_STRING([--enable-invariants],
1624                 [enable invariant checking (cpu intensive)]),
1625         [],[])
1626 AC_MSG_CHECKING([whether to check invariants (expensive cpu-wise)])
1627 AC_MSG_RESULT([$enable_invariants])
1628 if test x$enable_invariants = xyes ; then
1629         AC_DEFINE([CONFIG_LUSTRE_DEBUG_EXPENSIVE_CHECK], 1, [enable invariant checking])
1630 fi
1631
1632 AC_ARG_ENABLE([lu_ref],
1633         AC_HELP_STRING([--enable-lu_ref],
1634                 [enable lu_ref reference tracking code]),
1635         [],[])
1636 AC_MSG_CHECKING([whether to track references with lu_ref])
1637 AC_MSG_RESULT([$enable_lu_ref])
1638 if test x$enable_lu_ref = xyes ; then
1639         AC_DEFINE([USE_LU_REF], 1, [enable lu_ref reference tracking code])
1640 fi
1641
1642 AC_ARG_ENABLE([pgstate-track],
1643               AC_HELP_STRING([--enable-pgstate-track],
1644                              [enable page state tracking]),
1645               [enable_pgstat_track='yes'],[])
1646 AC_MSG_CHECKING([whether to enable page state tracking])
1647 AC_MSG_RESULT([$enable_pgstat_track])
1648 if test x$enable_pgstat_track = xyes ; then
1649         AC_DEFINE([CONFIG_DEBUG_PAGESTATE_TRACKING], 1,
1650                   [enable page state tracking code])
1651 fi
1652 ])
1653
1654 #
1655 # LC_CONDITIONALS
1656 #
1657 # AM_CONDITIONALS for lustre
1658 #
1659 AC_DEFUN([LC_CONDITIONALS],
1660 [AM_CONDITIONAL(LIBLUSTRE, test x$enable_liblustre = xyes)
1661 AM_CONDITIONAL(LIBLUSTRE_TESTS, test x$enable_liblustre_tests = xyes)
1662 AM_CONDITIONAL(MPITESTS, test x$enable_mpitests = xyes, Build MPI Tests)
1663 AM_CONDITIONAL(CLIENT, test x$enable_client = xyes)
1664 AM_CONDITIONAL(SERVER, test x$enable_server = xyes)
1665 AM_CONDITIONAL(SPLIT, test x$enable_split = xyes)
1666 AM_CONDITIONAL(BLKID, test x$ac_cv_header_blkid_blkid_h = xyes)
1667 AM_CONDITIONAL(EXT2FS_DEVEL, test x$ac_cv_header_ext2fs_ext2fs_h = xyes)
1668 AM_CONDITIONAL(GSS, test x$enable_gss = xyes)
1669 AM_CONDITIONAL(GSS_KEYRING, test x$enable_gss_keyring = xyes)
1670 AM_CONDITIONAL(GSS_PIPEFS, test x$enable_gss_pipefs = xyes)
1671 AM_CONDITIONAL(LIBPTHREAD, test x$enable_libpthread = xyes)
1672 AM_CONDITIONAL(LLITE_LLOOP, test x$enable_llite_lloop_module = xyes)
1673 ])
1674
1675 #
1676 # LC_CONFIG_FILES
1677 #
1678 # files that should be generated with AC_OUTPUT
1679 #
1680 AC_DEFUN([LC_CONFIG_FILES],
1681 [AC_CONFIG_FILES([
1682 lustre/Makefile
1683 lustre/autoMakefile
1684 lustre/autoconf/Makefile
1685 lustre/conf/Makefile
1686 lustre/contrib/Makefile
1687 lustre/doc/Makefile
1688 lustre/include/Makefile
1689 lustre/include/lustre_ver.h
1690 lustre/include/linux/Makefile
1691 lustre/include/darwin/Makefile
1692 lustre/include/lustre/Makefile
1693 lustre/kernel_patches/targets/2.6-rhel6.target
1694 lustre/kernel_patches/targets/2.6-rhel5.target
1695 lustre/kernel_patches/targets/2.6-sles11.target
1696 lustre/kernel_patches/targets/3.0-sles11.target
1697 lustre/kernel_patches/targets/3.0-sles11sp3.target
1698 lustre/kernel_patches/targets/2.6-fc11.target
1699 lustre/kernel_patches/targets/2.6-fc12.target
1700 lustre/kernel_patches/targets/2.6-fc15.target
1701 lustre/kernel_patches/targets/3.x-fc18.target
1702 lustre/ldlm/Makefile
1703 lustre/fid/Makefile
1704 lustre/fid/autoMakefile
1705 lustre/liblustre/Makefile
1706 lustre/liblustre/tests/Makefile
1707 lustre/liblustre/tests/mpi/Makefile
1708 lustre/llite/Makefile
1709 lustre/llite/autoMakefile
1710 lustre/lclient/Makefile
1711 lustre/lov/Makefile
1712 lustre/lov/autoMakefile
1713 lustre/mdc/Makefile
1714 lustre/mdc/autoMakefile
1715 lustre/lmv/Makefile
1716 lustre/lmv/autoMakefile
1717 lustre/lfsck/Makefile
1718 lustre/lfsck/autoMakefile
1719 lustre/mdt/Makefile
1720 lustre/mdt/autoMakefile
1721 lustre/mdd/Makefile
1722 lustre/mdd/autoMakefile
1723 lustre/fld/Makefile
1724 lustre/fld/autoMakefile
1725 lustre/obdclass/Makefile
1726 lustre/obdclass/autoMakefile
1727 lustre/obdclass/linux/Makefile
1728 lustre/obdecho/Makefile
1729 lustre/obdecho/autoMakefile
1730 lustre/ofd/Makefile
1731 lustre/ofd/autoMakefile
1732 lustre/osc/Makefile
1733 lustre/osc/autoMakefile
1734 lustre/ost/Makefile
1735 lustre/ost/autoMakefile
1736 lustre/osd-ldiskfs/Makefile
1737 lustre/osd-ldiskfs/autoMakefile
1738 lustre/osd-zfs/Makefile
1739 lustre/osd-zfs/autoMakefile
1740 lustre/mgc/Makefile
1741 lustre/mgc/autoMakefile
1742 lustre/mgs/Makefile
1743 lustre/mgs/autoMakefile
1744 lustre/target/Makefile
1745 lustre/ptlrpc/Makefile
1746 lustre/ptlrpc/autoMakefile
1747 lustre/ptlrpc/gss/Makefile
1748 lustre/ptlrpc/gss/autoMakefile
1749 lustre/quota/Makefile
1750 lustre/quota/autoMakefile
1751 lustre/scripts/Makefile
1752 lustre/tests/Makefile
1753 lustre/tests/mpi/Makefile
1754 lustre/utils/Makefile
1755 lustre/utils/gss/Makefile
1756 lustre/osp/Makefile
1757 lustre/osp/autoMakefile
1758 lustre/lod/Makefile
1759 lustre/lod/autoMakefile
1760 lustre/obdclass/darwin/Makefile
1761 ])
1762 ])