libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AS_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AS_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AS_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AS_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # Kernel version 3.11 introduced ktime_get_ts64
  53 #
  54 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
  55 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
  56 ktime_get_ts64, [
  57         #include <linux/hrtimer.h>
  58         #include <linux/ktime.h>
  59 ],[
  60         struct timespec64 *ts = NULL;
  61
  62         ktime_get_ts64(ts);
  63 ],[
  64         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
  65                 ['ktime_get_ts64' is available])
  66 ])
  67 ]) # LIBCFS_KTIME_GET_TS64
  68
  69 #
  70 # Kernel version 3.12-rc4 commit c2d816443ef30 added prepare_to_wait_event()
  71 #
  72 AC_DEFUN([LIBCFS_PREPARE_TO_WAIT_EVENT],[
  73 LB_CHECK_COMPILE([does function 'prepare_to_wait_event' exist],
  74 prepare_to_wait_event, [
  75         #include <linux/wait.h>
  76 ],[
  77         prepare_to_wait_event(NULL, NULL, 0);
  78 ],[
  79         AC_DEFINE(HAVE_PREPARE_TO_WAIT_EVENT, 1,
  80                 ['prepare_to_wait_event' is available])
  81 ])
  82 ]) # LIBCFS_PREPARE_TO_WAIT_EVENT
  83
  84 #
  85 # Linux kernel 3.12 introduced struct kernel_param_ops
  86 # This has been backported to all lustre supported
  87 # clients except RHEL6. We have to handle the differences.
  88 #
  89 AC_DEFUN([LIBCFS_KERNEL_PARAM_OPS],[
  90 LB_CHECK_COMPILE([does 'struct kernel_param_ops' exist],
  91 kernel_param_ops, [
  92         #include <linux/module.h>
  93 ],[
  94         struct kernel_param_ops ops;
  95
  96         ops.set = NULL;
  97 ],[
  98         AC_DEFINE(HAVE_KERNEL_PARAM_OPS, 1,
  99                 ['struct kernel_param_ops' is available])
 100 ])
 101 ]) # LIBCFS_KERNEL_PARAM_OPS
 102
 103 #
 104 # Kernel version 3.12 introduced ktime_add
 105 #
 106 AC_DEFUN([LIBCFS_KTIME_ADD],[
 107 LB_CHECK_COMPILE([does function 'ktime_add' exist],
 108 ktime_add, [
 109         #include <linux/hrtimer.h>
 110         #include <linux/ktime.h>
 111 ],[
 112         ktime_t start = ktime_set(0, 0);
 113         ktime_t end = start;
 114         ktime_t total;
 115
 116         total = ktime_add(start, end);
 117 ],[
 118         AC_DEFINE(HAVE_KTIME_ADD, 1,
 119                 [ktime_add is available])
 120 ])
 121 ]) # LIBCFS_KTIME_ADD
 122
 123 #
 124 # Kernel version 3.12 introduced ktime_after
 125 #
 126 AC_DEFUN([LIBCFS_KTIME_AFTER],[
 127 LB_CHECK_COMPILE([does function 'ktime_after' exist],
 128 ktime_after, [
 129         #include <linux/hrtimer.h>
 130         #include <linux/ktime.h>
 131 ],[
 132         ktime_t start = ktime_set(0, 0);
 133         ktime_t end = start;
 134
 135         ktime_after(start, end);
 136 ],[
 137         AC_DEFINE(HAVE_KTIME_AFTER, 1,
 138                 [ktime_after is available])
 139 ])
 140 ]) # LIBCFS_KTIME_AFTER
 141
 142 #
 143 # Kernel version 3.12 introduced ktime_before
 144 # See linux commit 67cb9366ff5f99868100198efba5ca88aaa6ad25
 145 #
 146 AC_DEFUN([LIBCFS_KTIME_BEFORE],[
 147 LB_CHECK_COMPILE([does function 'ktime_before' exist],
 148 ktime_before, [
 149         #include <linux/hrtimer.h>
 150         #include <linux/ktime.h>
 151 ],[
 152         ktime_t start = ktime_set(0, 0);
 153         ktime_t end = start;
 154
 155         ktime_before(start, end);
 156 ],[
 157         AC_DEFINE(HAVE_KTIME_BEFORE, 1,
 158                 [ktime_before is available])
 159 ])
 160 ]) # LIBCFS_KTIME_BEFORE
 161
 162 #
 163 # Kernel version 3.12 introduced ktime_compare
 164 #
 165 AC_DEFUN([LIBCFS_KTIME_COMPARE],[
 166 LB_CHECK_COMPILE([does function 'ktime_compare' exist],
 167 ktime_compare, [
 168         #include <linux/hrtimer.h>
 169         #include <linux/ktime.h>
 170 ],[
 171         ktime_t start = ktime_set(0, 0);
 172         ktime_t end = start;
 173
 174         ktime_compare(start, end);
 175 ],[
 176         AC_DEFINE(HAVE_KTIME_COMPARE, 1,
 177                 [ktime_compare is available])
 178 ])
 179 ]) # LIBCFS_KTIME_COMPARE
 180
 181 #
 182 # FC19 3.12 kernel struct shrinker change
 183 #
 184 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 185 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 186 shrinker_count_objects, [
 187         #include <linux/mmzone.h>
 188         #include <linux/shrinker.h>
 189 ],[
 190         struct shrinker shrinker;
 191
 192         shrinker.count_objects = NULL;
 193 ],[
 194         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 195                 [shrinker has count_objects member])
 196 ])
 197 ]) # LIBCFS_SHRINKER_COUNT
 198
 199 #
 200 # Kernel version 3.13 commit aace05097a0fd467230e39acb148be0fdaa90068
 201 # add match_wildcard() function.
 202 #
 203 AC_DEFUN([LIBCFS_MATCH_WILDCARD],[
 204 LB_CHECK_COMPILE([does function 'match_wildcard' exist],
 205 match_wildcard, [
 206         #include <linux/parser.h>
 207 ],[
 208         bool match;
 209
 210         match = match_wildcard(NULL, NULL);
 211 ],[
 212         AC_DEFINE(HAVE_MATCH_WILDCARD, 1,
 213                 [match_wildcard() is available])
 214 ])
 215 ]) # LIBCFS_MATCH_WILDCARD
 216
 217 #
 218 # LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
 219 #
 220 # v3.14-7405-g91b0abe36a7b added AS_EXITING flag with
 221 # mapping_exiting() and mapping_set_exiting()
 222 #
 223 AC_DEFUN([LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG], [
 224 m4_pattern_allow([AS_EXITING])
 225 tmp_flags="$EXTRA_KCFLAGS"
 226 EXTRA_KCFLAGS="-Werror"
 227 LB_CHECK_COMPILE([if enum mapping_flags has AS_EXITING flag],
 228 mapping_exiting_exists, [
 229         #include <linux/pagemap.h>
 230 ],[
 231         enum mapping_flags flag = AS_EXITING;
 232         (void)flag;
 233 ],[
 234         AC_DEFINE(HAVE_MAPPING_AS_EXITING_FLAG, 1,
 235                 [enum mapping_flags has AS_EXITING flag])
 236 ])
 237 EXTRA_KCFLAGS="$tmp_flags"
 238 ]) # LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
 239
 240 #
 241 # LIBCFS_IOV_ITER_HAS_TYPE
 242 #
 243 # kernel 3.15-rc4 commit 71d8e532b1549a478e6a6a8a44f309d050294d00
 244 # start adding the tag to iov_iter
 245 # kernel 5.13 commit 8cd54c1c848031a87820e58d772166ffdf8c08c0 change
 246 # ->type to ->iter_type
 247 #
 248 AC_DEFUN([LIBCFS_IOV_ITER_HAS_TYPE], [
 249 tmp_flags="$EXTRA_KCFLAGS"
 250 EXTRA_KCFLAGS="-Werror"
 251 iter_type_member=no
 252 LB_CHECK_COMPILE([if iov_iter has member type],
 253 iov_iter_has_type_member, [
 254         #include <linux/uio.h>
 255 ],[
 256         struct iov_iter iter = { .type = ITER_KVEC };
 257         (void)iter;
 258 ],[
 259         AC_DEFINE(HAVE_IOV_ITER_HAS_TYPE_MEMBER, 1,
 260                 [if iov_iter has member type])
 261         iter_type_member=yes
 262 ])
 263 if test $iter_type_member = no; then
 264   LB_CHECK_COMPILE([if iov_iter has member iter_type],
 265   iov_iter_has_iter_type_member, [
 266         #include <linux/uio.h>
 267   ],[
 268         struct iov_iter iter = { .iter_type = ITER_KVEC };
 269         (void)iter;
 270   ],[
 271         AC_DEFINE(HAVE_IOV_ITER_HAS_TYPE_MEMBER, 1,
 272                 [if iov_iter has member iter_type])
 273         iter_type_member=yes
 274   ])
 275 fi
 276 EXTRA_KCFLAGS="$tmp_flags"
 277 ]) # LIBCFS_IOV_ITER_HAS_TYPE
 278
 279 #
 280 # LIBCFS_HAVE_NS_TO_TIMESPEC64
 281 #
 282 # Kernel version 3.16-rc3 commit a84d1169164b274f13b97a23ff235c000efe3b49
 283 # introduced struct __kernel_old_timeval
 284 #
 285 AC_DEFUN([LIBCFS_HAVE_NS_TO_TIMESPEC64],[
 286 LB_CHECK_COMPILE([does 'ns_to_timespec64()' exist],
 287 kernel_old_timeval, [
 288         #include <linux/time.h>
 289 ],[
 290         struct timespec64 kts;
 291
 292         kts = ns_to_timespec64(0);
 293 ],[
 294         AC_DEFINE(HAVE_NS_TO_TIMESPEC64, 1,
 295                 [ns_to_timespec64() is available])
 296 ])
 297 ]) # LIBCFS_HAVE_NS_TO_TIMESPEC64
 298
 299 #
 300 # LIBCFS_HAVE_GLOB
 301 #
 302 # Kernel version 3.16 commit b01250856b25f4417c51aa33afc451fbf7da1484
 303 # added glob support to the Linux kernel
 304 #
 305 AC_DEFUN([LIBCFS_HAVE_GLOB],[
 306 tmp_flags="$EXTRA_KCFLAGS"
 307 EXTRA_KCFLAGS="-Werror"
 308 LB_CHECK_COMPILE([does 'glob_match()' exist],
 309 glob, [
 310         #include <linux/glob.h>
 311 ],[
 312         return glob_match(NULL, NULL);
 313 ],[
 314         AC_DEFINE(HAVE_GLOB, 1,
 315                 [glob_match() is available])
 316 ])
 317 EXTRA_KCFLAGS="$tmp_flags"
 318 ]) # LIBCFS_HAVE_GLOB
 319
 320 #
 321 # Kernel version 3.17 changed hlist_add_after to
 322 # hlist_add_behind
 323 #
 324 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 325 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 326 hlist_add_after, [
 327         #include <linux/list.h>
 328 ],[
 329         hlist_add_after(NULL, NULL);
 330 ],[
 331         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 332                 [hlist_add_after is available])
 333 ])
 334 ]) # LIBCFS_HLIST_ADD_AFTER
 335
 336 #
 337 # Kernel version 3.17 introduced struct timespec64
 338 #
 339 AC_DEFUN([LIBCFS_TIMESPEC64],[
 340 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 341 timespec64, [
 342         #include <linux/time.h>
 343 ],[
 344         struct timespec64 ts;
 345
 346         ts.tv_sec = 0;
 347         ts.tv_nsec = 0;
 348 ],[
 349         AC_DEFINE(HAVE_TIMESPEC64, 1,
 350                 ['struct timespec64' is available])
 351 ])
 352 ]) # LIBCFS_TIMESPEC64
 353
 354 #
 355 # Kernel version 3.17 introduced ktime_get_real_ts64
 356 #
 357 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 358 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 359 ktime_get_real_ts64, [
 360         #include <linux/ktime.h>
 361 ],[
 362         struct timespec64 *ts = NULL;
 363
 364         ktime_get_real_ts64(ts);
 365 ],[
 366         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 367                 ['ktime_get_real_ts64' is available])
 368 ])
 369 ]) # LIBCFS_KTIME_GET_REAL_TS64
 370
 371 #
 372 # Kernel version 3.17 introduced ktime_get_real_seconds
 373 #
 374 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 375 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 376 ktime_get_real_seconds, [
 377         #include <linux/hrtimer.h>
 378         #include <linux/ktime.h>
 379 ],[
 380         time64_t now;
 381
 382         now = ktime_get_real_seconds();
 383 ],[
 384         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 385                 ['ktime_get_real_seconds' is available])
 386 ])
 387 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 388
 389 #
 390 # Kernel version 3.17 created ktime_get_ns wrapper
 391 #
 392 AC_DEFUN([LIBCFS_KTIME_GET_NS],[
 393 LB_CHECK_COMPILE([does function 'ktime_get_ns' exist],
 394 ktime_get_ns, [
 395         #include <linux/hrtimer.h>
 396         #include <linux/ktime.h>
 397 ],[
 398         u64 nanoseconds;
 399
 400         nanoseconds = ktime_get_ns();
 401 ],[],[
 402         AC_DEFINE(NEED_KTIME_GET_NS, 1,
 403                 ['ktime_get_ns' is not available])
 404 ])
 405 ]) # LIBCFS_KTIME_GET_NS
 406
 407 #
 408 # Kernel version 3.17 created ktime_get_real_ns wrapper
 409 #
 410 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
 411 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
 412 ktime_get_real_ns, [
 413         #include <linux/hrtimer.h>
 414         #include <linux/ktime.h>
 415 ],[
 416         u64 nanoseconds;
 417
 418         nanoseconds = ktime_get_real_ns();
 419 ],[],[
 420         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
 421                 ['ktime_get_real_ns' is not available])
 422 ])
 423 ]) # LIBCFS_KTIME_GET_REAL_NS
 424
 425 #
 426 # Kernel version 3.17 introduced ktime_to_timespec64
 427 #
 428 AC_DEFUN([LIBCFS_KTIME_TO_TIMESPEC64],[
 429 LB_CHECK_COMPILE([does function 'ktime_to_timespec64' exist],
 430 ktime_to_timespec64, [
 431         #include <linux/hrtimer.h>
 432         #include <linux/ktime.h>
 433 ],[
 434         ktime_t now = ktime_set(0, 0);
 435         struct timespec64 ts;
 436
 437         ts = ktime_to_timespec64(now);
 438 ],[
 439         AC_DEFINE(HAVE_KTIME_TO_TIMESPEC64, 1,
 440                 ['ktime_to_timespec64' is available])
 441 ])
 442 ]) # LIBCFS_KTIME_TO_TIMESPEC64
 443
 444 #
 445 # Kernel version 3.17 introduced timespec64_sub
 446 #
 447 AC_DEFUN([LIBCFS_TIMESPEC64_SUB],[
 448 LB_CHECK_COMPILE([does function 'timespec64_sub' exist],
 449 timespec64_sub, [
 450         #include <linux/time.h>
 451 ],[
 452         struct timespec64 later = { }, earlier = { }, diff;
 453
 454         diff = timespec64_sub(later, earlier);
 455 ],[
 456         AC_DEFINE(HAVE_TIMESPEC64_SUB, 1,
 457                 ['timespec64_sub' is available])
 458 ])
 459 ]) # LIBCFS_TIMESPEC64_SUB
 460
 461 #
 462 # Kernel version 3.17 introduced timespec64_to_ktime
 463 #
 464 AC_DEFUN([LIBCFS_TIMESPEC64_TO_KTIME],[
 465 LB_CHECK_COMPILE([does function 'timespec64_to_ktime' exist],
 466 timespec64_to_ktime, [
 467         #include <linux/ktime.h>
 468 ],[
 469         struct timespec64 ts;
 470         ktime_t now;
 471
 472         now = timespec64_to_ktime(ts);
 473 ],[
 474         AC_DEFINE(HAVE_TIMESPEC64_TO_KTIME, 1,
 475                 ['timespec64_to_ktime' is available])
 476 ])
 477 ]) # LIBCFS_TIMESPEC64_TO_KTIME
 478
 479 #
 480 # Kernel version 3.19 introduced ktime_get_seconds
 481 #
 482 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 483 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 484 ktime_get_seconds, [
 485         #include <linux/ktime.h>
 486 ],[
 487         time64_t now;
 488
 489         now = ktime_get_seconds();
 490 ],[
 491         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 492                 ['ktime_get_seconds' is available])
 493 ])
 494 ]) # LIBCFS_KTIME_GET_SECONDS
 495
 496 #
 497 # Kernel version 3.19 commit v3.18-rc2-26-g61ada528dea0
 498 # introduce wait_woken()
 499 #
 500 AC_DEFUN([LIBCFS_WAIT_WOKEN],[
 501 LB_CHECK_COMPILE([does function 'wait_woken' exist],
 502 wait_woken, [
 503         #include <linux/wait.h>
 504 ],[
 505         wait_woken(NULL, 0, 0);
 506 ],[
 507         AC_DEFINE(HAVE_WAIT_WOKEN, 1,
 508                 ['wait_woken, is available'])
 509 ])
 510 ]) # LIBCFS_WAIT_WOKEN
 511
 512 #
 513 # Kernel version 4.0 commit 41fbf3b39d5eca01527338b4d0ee15ee1ae1023c
 514 # introduced the helper function ktime_ms_delta.
 515 #
 516 AC_DEFUN([LIBCFS_KTIME_MS_DELTA],[
 517 LB_CHECK_COMPILE([does function 'ktime_ms_delta' exist],
 518 ktime_ms_delta, [
 519         #include <linux/ktime.h>
 520 ],[
 521         ktime_t start = ktime_set(0, 0);
 522         ktime_t end = start;
 523
 524         ktime_ms_delta(start, end);
 525 ],[
 526         AC_DEFINE(HAVE_KTIME_MS_DELTA, 1,
 527                 ['ktime_ms_delta' is available])
 528 ])
 529 ]) # LIBCFS_KTIME_MS_DELTA
 530
 531 #
 532 # Kernel version 4.1 commit b51d23e4e9fea6f264d39535c2a62d1f51e7ccc3
 533 # create per module locks which added kernel_param_[un]lock(). Older
 534 # kernels you have to use __kernel_param_[un]lock(). In that case its
 535 # a global lock for all modules but that is okay since its a rare event.
 536 #
 537 AC_DEFUN([LIBCFS_KERNEL_PARAM_LOCK],[
 538 LB_CHECK_COMPILE([does function 'kernel_param_[un]lock' exist],
 539 kernel_param_lock, [
 540         #include <linux/moduleparam.h>
 541 ],[
 542         kernel_param_lock(NULL);
 543         kernel_param_unlock(NULL);
 544 ],[
 545         AC_DEFINE(HAVE_KERNEL_PARAM_LOCK, 1,
 546                 ['kernel_param_[un]lock' is available])
 547 ])
 548 ]) # LIBCFS_KERNEL_PARAM_LOCK
 549
 550 #
 551 # Kernel version 4.2 changed topology_thread_cpumask
 552 # to topology_sibling_cpumask
 553 #
 554 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 555 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 556 topology_sibling_cpumask, [
 557         #include <linux/topology.h>
 558 ],[
 559         const struct cpumask *mask;
 560
 561         mask = topology_sibling_cpumask(0);
 562 ],[
 563         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 564                 [topology_sibling_cpumask is available])
 565 ])
 566 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 567
 568 #
 569 # Kernel version 4.4 commit ef951599074ba4fad2d0efa0a977129b41e6d203
 570 # introduced kstrtobool and kstrtobool_from_user.
 571 #
 572 AC_DEFUN([LIBCFS_KSTRTOBOOL_FROM_USER], [
 573 LB_CHECK_COMPILE([if Linux kernel has 'kstrtobool_from_user'],
 574 kstrtobool_from_user, [
 575         #include <linux/kernel.h>
 576 ],[
 577         bool result;
 578         return kstrtobool_from_user(NULL, 0, &result);
 579 ],[
 580         AC_DEFINE(HAVE_KSTRTOBOOL_FROM_USER, 1,
 581                 [kernel has kstrtobool_from_user])
 582 ])
 583 ]) # LIBCFS_KSTRTOBOOL_FROM_USER
 584
 585 #
 586 # LIBCFS_NETLINK_CALLBACK_START
 587 #
 588 # Kernel version 4.4-rc3 commit fc9e50f5a5a4e1fa9ba2756f745a13e693cf6a06
 589 # added a start function callback for struct netlink_callback
 590 #
 591 AC_DEFUN([LIBCFS_NETLINK_CALLBACK_START], [
 592 LB_CHECK_COMPILE([if struct genl_ops has start callback],
 593 cb_start, [
 594         #include <net/genetlink.h>
 595 ],[
 596         struct genl_ops ops;
 597
 598         ops.start = NULL;
 599 ],[
 600         AC_DEFINE(HAVE_NETLINK_CALLBACK_START, 1,
 601                 [struct genl_ops has 'start' callback])
 602 ])
 603 ]) # LIBCFS_NETLINK_CALLBACK_START
 604
 605 #
 606 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 607 # added crypto hash helpers
 608 #
 609 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 610 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 611 crypto_hash_helpers, [
 612         #include <crypto/hash.h>
 613 ],[
 614         crypto_ahash_alg_name(NULL);
 615         crypto_ahash_driver_name(NULL);
 616 ],[
 617         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 618                 [crypto hash helper functions are available])
 619 ])
 620 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 621
 622 #
 623 # Kernel version 4.5-rc1 commit 3502cad73c4bbf8f6365d539e814159275252c59
 624 # introduced rhashtable_replace_fast
 625 #
 626 AC_DEFUN([LIBCFS_RHASHTABLE_REPLACE], [
 627 LB_CHECK_COMPILE([if 'rhashtable_replace_fast' exists],
 628 rhashtable_replace_fast, [
 629         #include <linux/rhashtable.h>
 630 ],[
 631         const struct rhashtable_params params = { 0 };
 632
 633         rhashtable_replace_fast(NULL, NULL, NULL, params);
 634 ],[
 635         AC_DEFINE(HAVE_RHASHTABLE_REPLACE, 1,
 636                 [rhashtable_replace_fast() is available])
 637 ])
 638 ]) # LIBCFS_RHASHTABLE_REPLACE
 639
 640 #
 641 # Kernel version 4.5-rc3 commit 2fe829aca9d7bed5fd6b49c6a1452e5e486b6cc3dd
 642 # made kset_find_obj() exportable to modules
 643 #
 644 AC_DEFUN([LIBCFS_EXPORT_KSET_FIND_OBJ], [
 645 LB_CHECK_EXPORT([kset_find_obj], [lib/kobject.c],
 646         [AC_DEFINE(HAVE_KSET_FIND_OBJ, 1,
 647                 [kset_find_obj is exported by the kernel])])
 648 ]) # LIBCFS_EXPORT_KSET_FIND_OBJ
 649
 650 #
 651 # Kernel version 4.6+ commit ef703f49a6c5b909a85149bb6625c4ed0d697186
 652 # fixed the brokenness of hash_64(). The fix removed GOLDEN_RATIO_PRIME_64
 653 # since it was a poor prime value.
 654 #
 655 AC_DEFUN([LIBCFS_BROKEN_HASH_64], [
 656 LB_CHECK_COMPILE([kernel has fixed hash_64()],
 657 broken_hash_64, [
 658         #include <linux/hash.h>
 659 ],[
 660         int tmp = GOLDEN_RATIO_PRIME_64;
 661 ],[
 662         AC_DEFINE(HAVE_BROKEN_HASH_64, 1, [kernel hash_64() is broken])
 663 ])
 664 ]) # LIBCFS_BROKEN_HASH_64
 665
 666 #
 667 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 668 #
 669 # linux 4.6 kernel changed stacktrace_ops address to return an int
 670 #
 671 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 672 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 673 stacktrace_ops_address_return_int, [
 674         #include <asm/stacktrace.h>
 675 ],[
 676         int rc;
 677
 678         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 679 ],[
 680         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 681                 ['struct stacktrace_ops' address function returns an int])
 682 ])
 683 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 684
 685 #
 686 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 687 # arguments to get_user_pages
 688 #
 689 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 690 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 691 get_user_pages_6arg, [
 692         #include <linux/mm.h>
 693 ],[
 694         int rc;
 695
 696         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 697 ],[
 698         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 699                 [get_user_pages takes 6 arguments])
 700 ])
 701 ]) # LIBCFS_GET_USER_PAGES_6ARG
 702
 703 #
 704 # LIBCFS_STRINGHASH
 705 #
 706 # 4.6 kernel created stringhash.h which moved stuff out of dcache.h
 707 # commit f4bcbe792b8f434e32487cff9d9e30ab45a3ce02
 708 #
 709 AC_DEFUN([LIBCFS_STRINGHASH], [
 710 LB_CHECK_LINUX_HEADER([linux/stringhash.h], [
 711         AC_DEFINE(HAVE_STRINGHASH, 1,
 712                 [stringhash.h is present])])
 713 ]) # LIBCFS_STRINGHASH
 714
 715 #
 716 # LIBCFS_RHASHTABLE_INSERT_FAST
 717 #
 718 # 4.7+ kernel commit 5ca8cc5bf11faed257c762018aea9106d529232f
 719 # changed __rhashtable_insert_fast to support the new function
 720 # rhashtable_lookup_get_insert_key().
 721 #
 722 AC_DEFUN([LIBCFS_RHASHTABLE_INSERT_FAST], [
 723 tmp_flags="$EXTRA_KCFLAGS"
 724 EXTRA_KCFLAGS="-Werror"
 725 LB_CHECK_COMPILE([if internal '__rhashtable_insert_fast()' returns int],
 726 rhashtable_insert_fast, [
 727         #include <linux/rhashtable.h>
 728 ],[
 729         const struct rhashtable_params params = { 0 };
 730         int rc;
 731
 732         rc = __rhashtable_insert_fast(NULL, NULL, NULL, params);
 733 ],[
 734         AC_DEFINE(HAVE_HASHTABLE_INSERT_FAST_RETURN_INT, 1,
 735                   ['__rhashtable_insert_fast()' returns int])
 736 ])
 737 EXTRA_KCFLAGS="$tmp_flags"
 738 ]) # LIBCFS_RHASHTABLE_INSERT_FAST
 739
 740 #
 741 # Kernel version 4.7-rc1 commit 8f6fd83c6c5ec66a4a70c728535ddcdfef4f3697
 742 # added 3rd arg to rhashtable_walk_init
 743 #
 744 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_INIT_3ARG], [
 745 LB_CHECK_COMPILE([if 'rhashtable_walk_init' has 3 args],
 746 rhashtable_walk_init, [
 747         #include <linux/gfp.h>
 748         #include <linux/rhashtable.h>
 749 ],[
 750         rhashtable_walk_init(NULL, NULL, GFP_KERNEL);
 751 ],[
 752         AC_DEFINE(HAVE_3ARG_RHASHTABLE_WALK_INIT, 1,
 753                 [rhashtable_walk_init() has 3 args])
 754 ])
 755 ]) # LIBCFS_RHASHTABLE_WALK_INIT_3ARG
 756
 757 #
 758 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 759 # introduced rhashtable_lookup
 760 #
 761 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP], [
 762 LB_CHECK_COMPILE([if 'rhashtable_lookup' exist],
 763 rhashtable_lookup, [
 764         #include <linux/rhashtable.h>
 765 ],[
 766         const struct rhashtable_params params = { 0 };
 767         void *ret;
 768
 769         ret = rhashtable_lookup(NULL, NULL, params);
 770 ],[
 771         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP, 1,
 772                 [rhashtable_lookup() is available])
 773 ])
 774 ]) # LIBCFS_RHASHTABLE_LOOKUP
 775
 776 #
 777 # LIBCFS_RHLTABLE
 778 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 779 # created the rhlist interface to allow inserting duplicate objects
 780 # into the same table.
 781 #
 782 AC_DEFUN([LIBCFS_RHLTABLE], [
 783 LB_CHECK_COMPILE([does 'struct rhltable' exist],
 784 rhtable, [
 785         #include <linux/rhashtable.h>
 786 ],[
 787         struct rhltable *hlt = NULL;
 788
 789         rhltable_destroy(hlt);
 790 ],[
 791         AC_DEFINE(HAVE_RHLTABLE, 1,
 792                   [struct rhltable exist])
 793 ])
 794 ]) # LIBCFS_RHLTABLE
 795
 796 #
 797 # LIBCFS_STACKTRACE_OPS
 798 #
 799 # Kernel version 4.8 commit c8fe4609827aedc9c4b45de80e7cdc8ccfa8541b
 800 # removed both struct stacktrace_ops and dump_trace() function
 801 #
 802 AC_DEFUN([LIBCFS_STACKTRACE_OPS], [
 803 LB_CHECK_COMPILE([if 'struct stacktrace_ops' exists],
 804 stacktrace_ops, [
 805         struct task_struct;
 806         struct pt_regs;
 807         #include <asm/stacktrace.h>
 808 ],[
 809         struct stacktrace_ops ops;
 810         ops.stack = NULL;
 811 ],[
 812         AC_DEFINE(HAVE_STACKTRACE_OPS, 1,
 813                 [struct stacktrace_ops exists])
 814 ])
 815 ]) # LIBCFS_STACKTRACE_OPS
 816
 817 #
 818 # Kernel version 4.9-rc1 commit 246779dd090bd1b74d2652b3a6ca7759f593b27a
 819 # introduced rhashtable_walk_enter
 820 #
 821 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_ENTER], [
 822 LB_CHECK_COMPILE([if 'rhashtable_walk_enter' exists],
 823 rhashtable_walk_enter, [
 824         #include <linux/rhashtable.h>
 825 ],[
 826         rhashtable_walk_enter(NULL, NULL);
 827 ],[
 828         AC_DEFINE(HAVE_RHASHTABLE_WALK_ENTER, 1,
 829                 [rhashtable_walk_enter() is available])
 830 ])
 831 ]) # LIBCFS_RHASHTABLE_WALK_ENTER
 832
 833 #
 834 # Kernel version 4.9 commit 768ae309a96103ed02eb1e111e838c87854d8b51
 835 # mm: replace get_user_pages() write/force parameters with gup_flags
 836 #
 837 AC_DEFUN([LIBCFS_GET_USER_PAGES_GUP_FLAGS], [
 838 LB_CHECK_COMPILE([if 'get_user_pages()' takes gup_flags in arguments],
 839 get_user_pages_gup_flags, [
 840         #include <linux/mm.h>
 841 ],[
 842         int rc;
 843         rc = get_user_pages(0, 0, FOLL_WRITE, NULL, NULL);
 844 ],[
 845         AC_DEFINE(HAVE_GET_USER_PAGES_GUP_FLAGS, 1,
 846                 [get_user_pages takes gup_flags in arguments])
 847 ])
 848 ]) # LIBCFS_GET_USER_PAGES_GUP_FLAGS
 849
 850 #
 851 # Kernel version 4.10 commit 7b737965b33188bd3dbb44e938535c4006d97fbb
 852 # libcfs: Convert to hotplug state machine
 853 #
 854 AC_DEFUN([LIBCFS_HOTPLUG_STATE_MACHINE], [
 855 LB_CHECK_COMPILE([if libcfs supports CPU hotplug state machine],
 856 cpu_hotplug_state_machine, [
 857         #include <linux/cpuhotplug.h>
 858 ],[
 859         cpuhp_remove_state(CPUHP_LUSTRE_CFS_DEAD);
 860 ],[
 861         AC_DEFINE(HAVE_HOTPLUG_STATE_MACHINE, 1,
 862                 [hotplug state machine is supported])
 863 ])
 864 ]) # LIBCFS_HOTPLUG_STATE_MACHINE
 865
 866 #
 867 # Kernel version 4.10-rc3 commit f405df5de3170c00e5c54f8b7cf4766044a032ba
 868 # introduced refcount_t which is atomic_t plus over flow guards.
 869 #
 870 AC_DEFUN([LIBCFS_REFCOUNT_T], [
 871 tmp_flags="$EXTRA_KCFLAGS"
 872 EXTRA_KCFLAGS="-Werror"
 873 LB_CHECK_LINUX_HEADER([linux/refcount.h], [
 874         AC_DEFINE(HAVE_REFCOUNT_T, 1,
 875                 [refcount_t is supported])
 876 ])
 877 EXTRA_KCFLAGS="$tmp_flags"
 878 ]) # LIBCFS_REFCOUNT_T
 879
 880 #
 881 # Kernel version 4.12 commit 499118e966f1d2150bd66647c8932343c4e9a0b8
 882 # introduce memalloc_noreclaim_{save,restore}
 883 #
 884 AC_DEFUN([LIBCFS_MEMALLOC_NORECLAIM], [
 885 LB_CHECK_COMPILE([if memalloc_noreclaim_{save,restore} exist],
 886 memalloc_noreclaim, [
 887         #include <linux/sched/mm.h>
 888 ],[
 889         int flag = memalloc_noreclaim_save();
 890         memalloc_noreclaim_restore(flag);
 891 ],[
 892         AC_DEFINE(HAVE_MEMALLOC_RECLAIM, 1,
 893                 [memalloc_noreclaim_{save,restore}() is supported])
 894 ])
 895 ]) # LIBCFS_MEMALLOC_NORECLAIM
 896
 897 #
 898 # LIBCFS_SCHED_HEADERS
 899 #
 900 # 4.11 has broken up sched.h into more headers.
 901 #
 902 AC_DEFUN([LIBCFS_SCHED_HEADERS], [
 903 LB_CHECK_LINUX_HEADER([linux/sched/signal.h], [
 904         AC_DEFINE(HAVE_SCHED_HEADERS, 1,
 905                 [linux/sched header directory exist])])
 906 ]) # LIBCFS_SCHED_HEADERS
 907
 908 #
 909 # Kernel version 4.11-rc1 commit 2c935bc57221cc2edc787c72ea0e2d30cdcd3d5e
 910 # introduce kref_read
 911 #
 912 AC_DEFUN([LIBCFS_KREF_READ], [
 913 LB_CHECK_COMPILE([if 'kref_read' exists],
 914 kref_read, [
 915         #include <linux/kref.h>
 916 ],[
 917         kref_read(NULL);
 918 ],[
 919         AC_DEFINE(HAVE_KREF_READ, 1,
 920                 [kref_read() is available])
 921 ])
 922 ]) # LIBCFS_KREF_READ
 923
 924 #
 925 # Kernel version 4.11-rc1 commit da20420f83ea0fbcf3d03afda08d971ea1d8a356
 926 # introduced rht_bucket_var
 927 #
 928 AC_DEFUN([LIBCFS_RHT_BUCKET_VAR], [
 929 LB_CHECK_COMPILE([if 'rht_bucket_var' exists],
 930 rht_bucket_var, [
 931         #include <linux/rhashtable.h>
 932 ],[
 933
 934         rht_bucket_var(NULL, 0);
 935 ],[
 936         AC_DEFINE(HAVE_RHT_BUCKET_VAR, 1,
 937                 [rht_bucket_var() is available])
 938 ])
 939 ]) # LIBCFS_RHT_BUCKET_VAR
 940
 941 #
 942 # Kernel version 4.11-rc5 commit fceb6435e85298f747fee938415057af837f5a8a
 943 # began the enhanchement of Netlink with extended ACK struct for advanced
 944 # error handling. By commit 7ab606d1609dd6dfeae9c8ad0a8a4e051d831e46 we
 945 # had full support for this new feature.
 946 #
 947 AC_DEFUN([LIBCFS_NL_EXT_ACK], [
 948 LB_CHECK_COMPILE([if Netlink supports netlink_ext_ack],
 949 netlink_ext_ack, [
 950         #include <net/genetlink.h>
 951 ],[
 952         struct genl_info info;
 953
 954         info.extack = NULL;
 955 ],[
 956         AC_DEFINE(HAVE_NL_PARSE_WITH_EXT_ACK, 1,
 957                 [netlink_ext_ack is an argument to nla_parse type function])
 958 ])
 959 ]) # LIBCFS_NL_EXT_ACK
 960
 961 #
 962 # Kernel version 4.11 commit f9fe1c12d126f9887441fa5bb165046f30ddd4b5
 963 # introduced rhashtable_lookup_get_insert_fast
 964 #
 965 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST], [
 966 LB_CHECK_COMPILE([if 'rhashtable_lookup_get_insert_fast' exist],
 967 rhashtable_lookup_get_insert_fast, [
 968         #include <linux/rhashtable.h>
 969 ],[
 970         const struct rhashtable_params params = { 0 };
 971         void *ret;
 972
 973         ret = rhashtable_lookup_get_insert_fast(NULL, NULL, params);
 974 ],[
 975         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP_GET_INSERT_FAST, 1,
 976                 [rhashtable_lookup_get_insert_fast() is available])
 977 ])
 978 ]) # LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
 979
 980 #
 981 # Kernel version 4.12-rc2 8f553c498e1772cccb39a114da4a498d22992758
 982 # provide proper CPU hotplug locking
 983 #
 984 AC_DEFUN([LIBCFS_CPUS_READ_LOCK], [
 985 LB_CHECK_COMPILE([if 'cpus_read_[un]lock' exist],
 986 cpu_read_lock, [
 987         #include <linux/cpu.h>
 988 ],[
 989         cpus_read_lock();
 990         cpus_read_unlock();
 991 ],[
 992         AC_DEFINE(HAVE_CPUS_READ_LOCK, 1, ['cpus_read_lock' exist])
 993 ])
 994 ]) # LIBCFS_CPUS_READ_LOCK
 995
 996 #
 997 # Kernel version 4.12-rc3 f9727a17db9bab71ddae91f74f11a8a2f9a0ece6
 998 # renamed uuid_be to uuid_t
 999 #
1000 AC_DEFUN([LIBCFS_UUID_T], [
1001 LB_CHECK_COMPILE([if 'uuid_t' exist],
1002 uuid_t, [
1003         #include <linux/uuid.h>
1004 ],[
1005         uuid_t uuid;
1006
1007         memset(uuid.b, 0, 16);
1008 ],[
1009         AC_DEFINE(HAVE_UUID_T, 1, ['uuid_t' exist])
1010 ])
1011 ]) # LIBCFS_UUID_T
1012
1013 #
1014 # Kernel version 4.12-rc3 commit fd851a3cdc196bfc1d229b5f22369069af532bf8
1015 # introduce processor.h
1016 #
1017 AC_DEFUN([LIBCFS_HAVE_PROCESSOR_HEADER], [
1018 tmp_flags="$EXTRA_KCFLAGS"
1019 EXTRA_KCFLAGS="-Werror"
1020 LB_CHECK_LINUX_HEADER([linux/processor.h], [
1021         AC_DEFINE(HAVE_PROCESSOR_H, 1,
1022                 [processor.h is present])
1023 ])
1024 EXTRA_KCFLAGS="$tmp_flags"
1025 ]) # LIBCFS_HAVE_PROCESSOR_HEADER
1026
1027 #
1028 # Kernel verison 4.12-rc6 commit 5dd43ce2f69d42a71dcacdb13d17d8c0ac1fe8f7
1029 # created wait_bit.h
1030 #
1031 AC_DEFUN([LIBCFS_HAVE_WAIT_BIT_HEADER], [
1032 LB_CHECK_LINUX_HEADER([linux/wait_bit.h], [
1033         AC_DEFINE(HAVE_WAIT_BIT_HEADER_H, 1,
1034                 [wait_bit.h is present])])
1035 ]) # LIBCFS_HAVE_WAIT_BIT_HEADER
1036
1037 #
1038 # Kernel version 4.12-rc6 commmit 2055da97389a605c8a00d163d40903afbe413921
1039 # changed:
1040 #       struct wait_queue_head::task_list       => ::head
1041 #       struct wait_queue_entry::task_list      => ::entry
1042 #
1043 AC_DEFUN([LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME], [
1044 LB_CHECK_COMPILE([if linux wait_queue_head list_head is named head],
1045 wait_queue_task_list, [
1046         #include <linux/wait.h>
1047 ],[
1048         wait_queue_head_t e;
1049
1050         INIT_LIST_HEAD(&e.head);
1051 ],[
1052         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY_LIST, 1,
1053                 [linux wait_queue_head_t list_head is name head])
1054 ])
1055 ]) # LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1056
1057 #
1058 # LIBCFS_WAIT_BIT_QUEUE_ENTRY_EXISTS
1059 #
1060 # Kernel version v4.12-rc6-23-g76c85ddc4695
1061 # sched/wait: Standardize wait_bit_queue naming
1062 #
1063 # renamed struct wait_bit_queue  => wait_bit_queue_entry
1064 #
1065 AC_DEFUN([LIBCFS_WAIT_BIT_QUEUE_ENTRY_EXISTS], [
1066 LB_CHECK_COMPILE([if struct wait_bit_queue_entry exists],
1067 struct_wait_bit_queue_entry_exists, [
1068         #include <linux/wait.h>
1069         #if HAVE_WAIT_BIT_HEADER_H
1070                 #include <linux/wait_bit.h>
1071         #endif
1072 ],[
1073         struct wait_bit_queue_entry entry;
1074         memset(&entry, 0, sizeof(entry));
1075 ],[
1076         AC_DEFINE(HAVE_WAIT_BIT_QUEUE_ENTRY, 1,
1077                 [if struct wait_bit_queue_entry exists])
1078 ])
1079 ]) # LIBCFS_WAIT_BIT_QUEUE_ENTRY_EXISTS
1080
1081 #
1082 # LIBCFS_NLA_STRDUP
1083 #
1084 # Kernel version 4.13-rc1 commit 2cf0c8b3e6942ecafe6ebb1a6d0328a81641bf39
1085 # created nla_strdup(). This is needed since push strings can be
1086 # any size.
1087 #
1088 AC_DEFUN([LIBCFS_NLA_STRDUP], [
1089 LB_CHECK_COMPILE([if 'nla_strdup()' exists],
1090 nla_strdup, [
1091         #include <net/netlink.h>
1092 ],[
1093         char *tmp = nla_strdup(NULL, GFP_KERNEL);
1094         (void)tmp;
1095 ],[
1096         AC_DEFINE(HAVE_NLA_STRDUP, 1,
1097                 ['nla_strdup' is available])
1098 ])
1099 ]) # LIBCFS_NLA_STRDUP
1100
1101 #
1102 # LIBCFS_WAIT_QUEUE_ENTRY
1103 #
1104 # Kernel version 4.13 ac6424b981bce1c4bc55675c6ce11bfe1bbfa64f
1105 # Rename wait_queue_t => wait_queue_entry_t
1106 #
1107 AC_DEFUN([LIBCFS_WAIT_QUEUE_ENTRY], [
1108 LB_CHECK_COMPILE([if 'wait_queue_entry_t' exists],
1109 wait_queue_entry, [
1110         #include <linux/wait.h>
1111 ],[
1112         wait_queue_entry_t e;
1113
1114         e.flags = 0;
1115 ],[
1116         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY, 1,
1117                 ['wait_queue_entry_t' is available])
1118 ])
1119 ]) # LIBCFS_WAIT_QUEUE_ENTRY
1120
1121 #
1122 # LIBCFS_NEW_KERNEL_WRITE
1123 #
1124 # Kernel version 4.14 e13ec939e96b13e664bb6cee361cc976a0ee621a
1125 # changed kernel_write prototype to make is plug compatible
1126 # with the unexported vfs_write()
1127 #
1128 AC_DEFUN([LIBCFS_NEW_KERNEL_WRITE], [
1129 tmp_flags="$EXTRA_KCFLAGS"
1130 EXTRA_KCFLAGS="-Werror"
1131 LB_CHECK_COMPILE([if 'kernel_write' matches other read/write helpers],
1132 kernel_write_match, [
1133         #include <linux/fs.h>
1134 ],[
1135         const void *buf = NULL;
1136         loff_t pos = 0;
1137         return kernel_write(NULL, buf, 0, &pos);
1138 ],[
1139         AC_DEFINE(HAVE_NEW_KERNEL_WRITE, 1,
1140                 ['kernel_write' aligns with read/write helpers])
1141 ])
1142 EXTRA_KCFLAGS="$tmp_flags"
1143 ]) # LIBCFS_NEW_KERNEL_WRITE
1144
1145 #
1146 # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1147 #
1148 # kernel 5.0 commit ca79b0c211af63fa3276f0e3fd7dd9ada2439839
1149 # mm: convert totalram_pages and totalhigh_pages variables to atomic
1150 #
1151 AC_DEFUN([LIBCFS_MM_TOTALRAM_PAGES_FUNC], [
1152 tmp_flags="$EXTRA_KCFLAGS"
1153 EXTRA_KCFLAGS="-Werror"
1154 LB_CHECK_COMPILE([if totalram_pages is a function],
1155 totalram_pages, [
1156         #include <linux/mm.h>
1157 ],[
1158         totalram_pages_inc();
1159 ],[
1160         AC_DEFINE(HAVE_TOTALRAM_PAGES_AS_FUNC, 1,
1161                 [if totalram_pages is a function])
1162 ])
1163 EXTRA_KCFLAGS="$tmp_flags"
1164 ]) # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1165
1166 #
1167 # LIBCFS_NEW_KERNEL_READ
1168 #
1169 # 4.14 commit bdd1d2d3d251c65b74ac4493e08db18971c09240 changed
1170 # the signature of kernel_read to match other read/write helpers
1171 # and place offset last.
1172 #
1173 AC_DEFUN([LIBCFS_NEW_KERNEL_READ], [
1174 tmp_flags="$EXTRA_KCFLAGS"
1175 EXTRA_KCFLAGS="-Werror"
1176 LB_CHECK_COMPILE([if 'kernel_read()' has loff_t *pos as last parameter],
1177 kernel_read, [
1178         #include <linux/fs.h>
1179         ],[
1180         loff_t pos = 0;
1181         kernel_read(NULL, NULL, 0, &pos);
1182 ],[
1183         AC_DEFINE(HAVE_KERNEL_READ_LAST_POSP, 1,
1184                 [kernel_read() signature ends with loff_t *pos])
1185 ])
1186 EXTRA_KCFLAGS="$tmp_flags"
1187 ]) # LIBCFS_NEW_KERNEL_READ
1188
1189 #
1190 # LIBCFS_DEFINE_TIMER
1191 #
1192 # Kernel version 4.14 commit 1d27e3e2252ba9d949ca82fbdb73cde102cb2067
1193 # remove expires and data arguments from DEFINE_TIMER. Also the callback
1194 # when from using unsigned long argument to using struct timer_list pointer.
1195 #
1196 AC_DEFUN([LIBCFS_DEFINE_TIMER], [
1197 LB_CHECK_COMPILE([if DEFINE_TIMER takes only 2 arguments],
1198 define_timer, [
1199         #include <linux/timer.h>
1200 ],[
1201         static DEFINE_TIMER(my_timer, NULL);
1202 ],[
1203         AC_DEFINE(HAVE_NEW_DEFINE_TIMER, 1,
1204                 [DEFINE_TIMER uses only 2 arguements])
1205 ])
1206 ]) # LIBCFS_DEFINE_TIMER
1207
1208 #
1209 # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1210 #
1211 # Kernel 2.6.27 commit 8594698ebddeef5443b7da8258ae33b3eaca61d5
1212 # exported save_stack_trace_tsk for x86.
1213 # Kernel 2.6.27 commit 01f4b8b8b8db09b88be7df7e51192e4e678b69d3
1214 # exported save_stack_trace_tsk for powerpc
1215 # Kernel 4.13 commit e27c7fa015d61c8be6a2c32b2144aad2ae6ec975
1216 # exported save_stack_trace_tsk for arm64
1217 # Kernel 4.14 commit 9a3dc3186fc3795e076a4122da9e0258651a9631
1218 # exported save_stack_trace_tsk for arm
1219 #
1220 AC_DEFUN([LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK], [
1221 LB_CHECK_EXPORT([save_stack_trace_tsk], [arch/$SUBARCH/kernel/stacktrace.c],
1222         [AC_DEFINE(HAVE_SAVE_STACK_TRACE_TSK, 1,
1223                 [save_stack_trace_tsk is exported])])
1224 ]) # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1225
1226 #
1227 # LIBCFS_LOCKDEP_IS_HELD
1228 #
1229 # Kernel v4.15-rc8-106-g08f36ff64234
1230 # lockdep: Make lockdep checking constant
1231 #
1232 AC_DEFUN([LIBCFS_LOCKDEP_IS_HELD], [
1233 tmp_flags="$EXTRA_KCFLAGS"
1234 EXTRA_KCFLAGS="-Werror"
1235 LB_CHECK_COMPILE([if 'lockdep_is_held()' uses const argument],
1236 lockdep_is_held, [
1237         #include <linux/lockdep.h>
1238 ],[
1239 #ifdef CONFIG_LOCKDEP
1240         const struct spinlock *lock = NULL;
1241
1242         lockdep_is_held(lock);
1243 #endif
1244 ],[],[
1245         AC_DEFINE(NEED_LOCKDEP_IS_HELD_DISCARD_CONST, 1,
1246                 [lockdep_is_held() argument is const])
1247 ])
1248 EXTRA_KCFLAGS="$tmp_flags"
1249 ]) # LIBCFS_LOCKDEP_IS_HELD
1250
1251 #
1252 # LIBCFS_TIMER_SETUP
1253 #
1254 # Kernel version 4.15 commit e99e88a9d2b067465adaa9c111ada99a041bef9a
1255 # setup_timer() was replaced by timer_setup(), where the callback
1256 # argument is the structure already holding the struct timer_list.
1257 #
1258 AC_DEFUN([LIBCFS_TIMER_SETUP], [
1259 LB_CHECK_COMPILE([if setup_timer has been replaced with timer_setup],
1260 timer_setup, [
1261         #include <linux/timer.h>
1262 ],[
1263         timer_setup(NULL, NULL, 0);
1264 ],[
1265         AC_DEFINE(HAVE_TIMER_SETUP, 1,
1266                 [timer_setup has replaced setup_timer])
1267 ])
1268 ]) # LIBCFS_TIMER_SETUP
1269
1270 #
1271 # LIBCFS_WAIT_VAR_EVENT
1272 #
1273 # Kernel version 4.16-rc4 commit 6b2bb7265f0b62605e8caee3613449ed0db270b9
1274 # added wait_var_event()
1275 #
1276 AC_DEFUN([LIBCFS_WAIT_VAR_EVENT], [
1277 LB_CHECK_COMPILE([if 'wait_var_event' exist],
1278 wait_var_event, [
1279         #ifdef HAVE_WAIT_BIT_HEADER_H
1280         #include <linux/wait_bit.h>
1281         #endif
1282         #include <linux/wait.h>
1283 ],[
1284         wake_up_var(NULL);
1285 ],[
1286         AC_DEFINE(HAVE_WAIT_VAR_EVENT, 1,
1287                 ['wait_var_event' is available])
1288 ])
1289 ]) # LIBCFS_WAIT_VAR_EVENT
1290
1291 #
1292 # LIBCFS_BITMAP_ALLOC
1293 #
1294 # Kernel version 4.17 commit c42b65e363ce97a828f81b59033c3558f8fa7f70
1295 # added bitmap memory allocation handling.
1296 #
1297 AC_DEFUN([LIBCFS_BITMAP_ALLOC], [
1298 LB_CHECK_COMPILE([if Linux bitmap memory management exist],
1299 bitmap_alloc, [
1300         #include <linux/bitmap.h>
1301 ],[
1302         unsigned long *map = bitmap_alloc(1, GFP_KERNEL);
1303 ],[
1304         AC_DEFINE(HAVE_BITMAP_ALLOC, 1,
1305                 [Linux bitmap can be allocated])
1306 ])
1307 ]) # LIBCFS_BITMAP_ALLOC
1308
1309 #
1310 # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1311 #
1312 # Kernel version 4.17-rc2 commit 8236b0ae31c837d2b3a2565c5f8d77f637e824cc
1313 # added clear_and_wake_up_bit()
1314 #
1315 AC_DEFUN([LIBCFS_CLEAR_AND_WAKE_UP_BIT], [
1316 LB_CHECK_COMPILE([if 'clear_and_wake_up_bit' exist],
1317 clear_and_wake_up_bit, [
1318         #ifdef HAVE_WAIT_BIT_HEADER_H
1319         #include <linux/wait_bit.h>
1320         #endif
1321         #include <linux/wait.h>
1322 ],[
1323         clear_and_wake_up_bit(0, NULL);
1324 ],[
1325         AC_DEFINE(HAVE_CLEAR_AND_WAKE_UP_BIT, 1,
1326                 ['clear_and_wake_up_bit' is available])
1327 ])
1328 ]) # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1329
1330 #
1331 # LIBCFS_TCP_SOCK_SET_NODELAY
1332 #
1333 # kernel 4.18.0-293.el8
1334 # tcp_sock_set_nodelay() was added
1335 AC_DEFUN([LIBCFS_TCP_SOCK_SET_NODELAY], [
1336 tmp_flags="$EXTRA_KCFLAGS"
1337 EXTRA_KCFLAGS="-Werror"
1338 LB_CHECK_COMPILE([if 'tcp_sock_set_nodelay()' exists],
1339 tcp_sock_set_nodelay_exists, [
1340         #include <linux/tcp.h>
1341 ],[
1342         tcp_sock_set_nodelay(NULL);
1343 ],[
1344         AC_DEFINE(HAVE_TCP_SOCK_SET_NODELAY, 1,
1345                 ['tcp_sock_set_nodelay()' exists])
1346 ])
1347 EXTRA_KCFLAGS="$tmp_flags"
1348 ]) # LIBCFS_TCP_SOCK_SET_NODELAY
1349
1350 #
1351 # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1352 #
1353 # kernel 4.18.0-293.el8
1354 # tcp_sock_set_keepidle() was added
1355 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPIDLE], [
1356 tmp_flags="$EXTRA_KCFLAGS"
1357 EXTRA_KCFLAGS="-Werror"
1358 LB_CHECK_COMPILE([if 'tcp_sock_set_keepidle()' exists],
1359 tcp_sock_set_keepidle_exists, [
1360         #include <linux/tcp.h>
1361 ],[
1362         tcp_sock_set_keepidle(NULL, 0);
1363 ],[
1364         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPIDLE, 1,
1365                 ['tcp_sock_set_keepidle()' exists])
1366 ])
1367 EXTRA_KCFLAGS="$tmp_flags"
1368 ]) # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1369
1370 #
1371 # LIBCFS_TCP_SOCK_SET_QUICKACK
1372 # kernel v5.7-rc6-2504-gddd061b8daed
1373 #   tcp: add tcp_sock_set_quickack
1374 #
1375 AC_DEFUN([LIBCFS_TCP_SOCK_SET_QUICKACK], [
1376 tmp_flags="$EXTRA_KCFLAGS"
1377 EXTRA_KCFLAGS="-Werror"
1378 LB_CHECK_COMPILE([if 'tcp_sock_set_quickack()' exists],
1379 tcp_sock_set_quickack_exists, [
1380         #include <linux/tcp.h>
1381 ],[
1382         tcp_sock_set_quickack(NULL, 0);
1383 ],[
1384         AC_DEFINE(HAVE_TCP_SOCK_SET_QUICKACK, 1,
1385                 ['tcp_sock_set_quickack()' exists])
1386 ])
1387 EXTRA_KCFLAGS="$tmp_flags"
1388 ]) # LIBCFS_TCP_SOCK_SET_QUICKACK
1389
1390 #
1391 # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1392 # v5.7-rc6-2508-gd41ecaac903c
1393 # tcp: add tcp_sock_set_keepintvl
1394 #
1395 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPINTVL], [
1396 tmp_flags="$EXTRA_KCFLAGS"
1397 EXTRA_KCFLAGS="-Werror"
1398 LB_CHECK_COMPILE([if 'tcp_sock_set_keepintvl()' exists],
1399 tcp_sock_set_keepintvl_exists, [
1400         #include <linux/tcp.h>
1401 ],[
1402         tcp_sock_set_keepintvl(NULL, 0);
1403 ],[
1404         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPINTVL, 1,
1405                 ['tcp_sock_set_keepintvl()' exists])
1406 ])
1407 EXTRA_KCFLAGS="$tmp_flags"
1408 ]) # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1409
1410 #
1411 # LIBCFS_TCP_SOCK_SET_KEEPCNT
1412 # v5.7-rc6-2509-g480aeb9639d6
1413 # tcp: add tcp_sock_set_keepcnt
1414 #
1415 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPCNT], [
1416 tmp_flags="$EXTRA_KCFLAGS"
1417 EXTRA_KCFLAGS="-Werror"
1418 LB_CHECK_COMPILE([if 'tcp_sock_set_keepcnt()' exists],
1419 tcp_sock_set_keepcnt_exists, [
1420         #include <linux/tcp.h>
1421 ],[
1422         tcp_sock_set_keepcnt(NULL, 0);
1423 ],[
1424         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPCNT, 1,
1425                 ['tcp_sock_set_keepcnt()' exists])
1426 ])
1427 EXTRA_KCFLAGS="$tmp_flags"
1428 ]) # LIBCFS_TCP_SOCK_SET_KEEPCNT
1429
1430 #
1431 # LIBCFS_XARRAY_SUPPORT
1432 #
1433 # 4.19-rc5 kernel commit 3159f943aafdbacb2f94c38fdaadabf2bbde2a14
1434 # replaced the radix tree implementation with Xarrays. This change
1435 # introduced functionaly needed for general Xarray support
1436 #
1437 AC_DEFUN([LIBCFS_XARRAY_SUPPORT], [
1438 tmp_flags="$EXTRA_KCFLAGS"
1439 EXTRA_KCFLAGS="-Werror"
1440 LB_CHECK_COMPILE([if page cache uses Xarray],
1441 xarray_support, [
1442         #include <linux/xarray.h>
1443 ],[
1444         xa_is_value(NULL);
1445 ],[
1446         AC_DEFINE(HAVE_XARRAY_SUPPORT, 1,
1447                 [kernel Xarray implementation lacks 'xa_is_value'])
1448 ])
1449 EXTRA_KCFLAGS="$tmp_flags"
1450 ]) # LIBCFS_XARRAY_SUPPORT
1451
1452 #
1453 # Kernel version 4.19-rc6 commit 4a19edb60d0203cd5bf95a8b46ea8f63fd41194c
1454 # added extended ACK handling to Netlink dump handlers
1455 #
1456 AC_DEFUN([LIBCFS_NL_DUMP_EXT_ACK], [
1457 LB_CHECK_COMPILE([if Netlink dump handlers support ext_ack],
1458 netlink_dump_ext_ack, [
1459         #include <net/netlink.h>
1460 ],[
1461         struct netlink_callback *cb = NULL;
1462         cb->extack = NULL;
1463 ],[
1464         AC_DEFINE(HAVE_NL_DUMP_WITH_EXT_ACK, 1,
1465                 [netlink_ext_ack is handled for Netlink dump handlers])
1466 ])
1467 ]) # LIBCFS_NL_DUMP_EXT_ACK
1468
1469 #
1470 # LIBCFS_HAVE_IOV_ITER_TYPE
1471 #
1472 # kernel 4.20 commit 00e23707442a75b404392cef1405ab4fd498de6b
1473 # iov_iter: Use accessor functions to access an iterator's type and direction.
1474 #
1475 AC_DEFUN([LIBCFS_HAVE_IOV_ITER_TYPE], [
1476 tmp_flags="$EXTRA_KCFLAGS"
1477 EXTRA_KCFLAGS="-Werror"
1478 LB_CHECK_COMPILE([if iov_iter_type exists],
1479 macro_iov_iter_type_exists, [
1480         #include <linux/uio.h>
1481 ],[
1482         struct iov_iter iter = { };
1483         enum iter_type type = iov_iter_type(&iter);
1484         (void)type;
1485 ],[
1486         AC_DEFINE(HAVE_IOV_ITER_TYPE, 1,
1487                 [if iov_iter_type exists])
1488 ])
1489 EXTRA_KCFLAGS="$tmp_flags"
1490 ]) # LIBCFS_HAVE_IOV_ITER_TYPE
1491
1492 #
1493 # LIBCFS_GENRADIX
1494 #
1495 # Kernel 5.0 commit ba20ba2e3743bac786dff777954c11930256075e
1496 # implemented generic radix trees to handle very large memory
1497 # allocation that can be used instead of vmalloc which has
1498 # a performance penalty.
1499 #
1500 AC_DEFUN([LIBCFS_GENRADIX], [
1501 LB_CHECK_EXPORT([__genradix_ptr], [lib/generic-radix-tree.c],
1502         [AC_DEFINE(HAVE_GENRADIX_SUPPORT, 1,
1503                 [generic-radix-tree is present])])
1504 ]) # LIBCFS_GENRADIX
1505
1506 #
1507 # LIBCFS_GET_REQUEST_KEY_AUTH
1508 #
1509 # kernel 5.0 commit 822ad64d7e46a8e2c8b8a796738d7b657cbb146d
1510 # keys: Fix dependency loop between construction record and auth key
1511 #
1512 # Added <keys/request_key_auth-type.h> and get_request_key_auth()
1513 # which was propagated to stable
1514 #
1515 AC_DEFUN([LIBCFS_GET_REQUEST_KEY_AUTH], [
1516 tmp_flags="$EXTRA_KCFLAGS"
1517 EXTRA_KCFLAGS="-Werror"
1518 LB_CHECK_COMPILE([if get_request_key_auth() is available],
1519 get_request_key_auth_exported, [
1520         #include <linux/key.h>
1521         #include <linux/keyctl.h>
1522         #include <keys/request_key_auth-type.h>
1523 ],[
1524         struct key *ring;
1525         const struct key *key = NULL;
1526         struct request_key_auth *rka = get_request_key_auth(key);
1527
1528         ring = key_get(rka->dest_keyring);
1529 ],[
1530         AC_DEFINE(HAVE_GET_REQUEST_KEY_AUTH, 1,
1531                 [get_request_key_auth() is available])
1532 ])
1533 EXTRA_KCFLAGS="$tmp_flags"
1534 ]) # LIBCFS_GET_REQUEST_KEY_AUTH
1535
1536 #
1537 # LIBCFS_KOBJ_TYPE_DEFAULT_GROUPS
1538 #
1539 # Linux commit v5.1-rc3-29-gaa30f47cf666
1540 #    kobject: Add support for default attribute groups to kobj_type
1541 # Linux commit v5.18-rc1-2-gcdb4f26a63c3
1542 #    kobject: kobj_type: remove default_attrs
1543 #
1544 AC_DEFUN([LIBCFS_KOBJ_TYPE_DEFAULT_GROUPS],[
1545 LB_CHECK_COMPILE([does struct kobj_type have 'default_groups' member],
1546 kobj_type_default_groups, [
1547                 #include <linux/kobject.h>
1548         ],[
1549                 struct kobj_type *kobj_type = NULL;
1550                 void *has = kobj_type->default_groups;
1551                 (void) has;
1552         ],[
1553                 AC_DEFINE(HAVE_KOBJ_TYPE_DEFAULT_GROUPS, 1,
1554                         [struct kobj_type has 'default_groups' member])
1555         ])
1556 ]) # LIBCFS_KOBJ_TYPE_DEFAULT_GROUPS
1557
1558 #
1559 # LIBCFS_LOOKUP_USER_KEY
1560 #
1561 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1562 # signal: Remove task parameter from force_sig
1563 #
1564 AC_DEFUN([LIBCFS_LOOKUP_USER_KEY], [
1565 tmp_flags="$EXTRA_KCFLAGS"
1566 EXTRA_KCFLAGS="-Werror"
1567 LB_CHECK_COMPILE([if lookup_user_key() is available],
1568 lookup_user_key_exported, [
1569         #include <linux/key.h>
1570         #include <linux/keyctl.h>
1571 ],[
1572         lookup_user_key(KEY_SPEC_USER_KEYRING, 0, 0);
1573 ],[
1574         AC_DEFINE(HAVE_LOOKUP_USER_KEY, 1,
1575                 [lookup_user_key() is available])
1576 ])
1577 EXTRA_KCFLAGS="$tmp_flags"
1578 ]) # LIBCFS_LOOKUP_USER_KEY
1579
1580 #
1581 # LIBCFS_FORCE_SIG_WITH_TASK
1582 #
1583 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1584 # signal: Remove task parameter from force_sig
1585 #
1586 AC_DEFUN([LIBCFS_FORCE_SIG_WITH_TASK], [
1587 tmp_flags="$EXTRA_KCFLAGS"
1588 EXTRA_KCFLAGS="-Werror"
1589 LB_CHECK_COMPILE([if force_sig has task parameter],
1590 force_sig_with_task, [
1591         #include <linux/sched/signal.h>
1592 ],[
1593         force_sig(SIGINT, NULL);
1594 ],[
1595         AC_DEFINE(HAVE_FORCE_SIG_WITH_TASK, 1,
1596                 [force_sig() has task parameter])
1597 ])
1598 EXTRA_KCFLAGS="$tmp_flags"
1599 ]) # LIBCFS_FORCE_SIG_WITH_TASK
1600
1601 #
1602 # LIBCFS_CACHE_DETAIL_WRITERS
1603 #
1604 # kernel v5.3-rc2-1-g64a38e840ce5
1605 # SUNRPC: Track writers of the 'channel' file to improve cache_listeners_exist
1606 #
1607 AC_DEFUN([LIBCFS_CACHE_DETAIL_WRITERS], [
1608 tmp_flags="$EXTRA_KCFLAGS"
1609 EXTRA_KCFLAGS="-Werror"
1610 LB_CHECK_COMPILE([if struct cache_detail has writers],
1611 cache_detail_writers_atomic, [
1612         #include <linux/sunrpc/cache.h>
1613
1614         static struct cache_detail rsi_cache;
1615 ],[
1616         atomic_set(&rsi_cache.writers, 0);
1617 ],[
1618         AC_DEFINE(HAVE_CACHE_DETAIL_WRITERS, 1,
1619                 [struct cache_detail has writers])
1620 ])
1621 EXTRA_KCFLAGS="$tmp_flags"
1622 ]) # LIBCFS_CACHE_DETAIL_WRITERS
1623
1624 #
1625 # LIBCFS_GENL_DUMPIT_INFO
1626 #
1627 # kernel v5.4-rc1 commit bf813b0afeae2f012f0e527a526c1b78ca21ad82
1628 # expanded struct genl_dumpit_info to include struct genl_family.
1629 #
1630 AC_DEFUN([LIBCFS_GENL_DUMPIT_INFO], [
1631 tmp_flags="$EXTRA_KCFLAGS"
1632 EXTRA_KCFLAGS="-Werror"
1633 LB_CHECK_COMPILE([if struct genl_dumpit_info has family field],
1634 genl_dumpit_info, [
1635         #include <net/genetlink.h>
1636 ],[
1637         static struct genl_dumpit_info info;
1638
1639         info.family = NULL;
1640 ],[
1641         AC_DEFINE(HAVE_GENL_DUMPIT_INFO, 1,
1642                 [struct genl_dumpit_info has family field])
1643 ])
1644 EXTRA_KCFLAGS="$tmp_flags"
1645 ]) # LIBCFS_GENL_DUMPIT_INFO
1646
1647 #
1648 # LIBCFS_KALLSYMS_LOOKUP
1649 #
1650 # kernel v5.6-11591-g0bd476e6c671
1651 # kallsyms: unexport kallsyms_lookup_name() and kallsyms_on_each_symbol()
1652 AC_DEFUN([LIBCFS_KALLSYMS_LOOKUP], [
1653 LB_CHECK_EXPORT([kallsyms_lookup_name], [kernel/kallsyms.c],
1654         [AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1655                 [kallsyms_lookup_name is exported by kernel])])
1656 ]) # LIBCFS_KALLSYMS_LOOKUP
1657
1658 #
1659 # v5.5-8862-gd56c0d45f0e2
1660 # proc: decouple proc from VFS with "struct proc_ops"
1661 #
1662 AC_DEFUN([LIBCFS_SRC_HAVE_PROC_OPS], [
1663         LB2_LINUX_TEST_SRC([proc_ops], [
1664                 #include <linux/proc_fs.h>
1665
1666                 static struct proc_ops *my_proc;
1667         ],[
1668                 my_proc->proc_lseek = NULL;
1669         ],[-Werror])
1670 ]) # LIBCFS_SRC_HAVE_PROC_OPS
1671 AC_DEFUN([LIBCFS_HAVE_PROC_OPS], [
1672         AC_MSG_CHECKING([if struct proc_ops exists])
1673         LB2_LINUX_TEST_RESULT([proc_ops], [
1674                 AC_DEFINE(HAVE_PROC_OPS, 1,
1675                         [struct proc_ops exists])
1676                 AC_MSG_RESULT(yes)
1677         ],[
1678                 AC_MSG_RESULT(no)
1679         ])
1680 ]) # LIBCFS_HAVE_PROC_OPS
1681
1682 #
1683 # LIBCFS_IP6_SET_PREF
1684 #
1685 # kernel v5.8-rc1~165^2~71^2~3 commit 18d5ad62327576cbb1e5b9938a59d63ac0c15832
1686 # ipv6: add ip6_sock_set_addr_preferences
1687 #
1688 AC_DEFUN([LIBCFS_IP6_SET_PREF], [
1689 tmp_flags="$EXTRA_KCFLAGS"
1690 EXTRA_KCFLAGS="-Werror"
1691 LB_CHECK_COMPILE([if ip6_sock_set_addr_preferences() exists],
1692 ip6_set_pref_test, [
1693         #include <net/ipv6.h>
1694 ],[
1695         ip6_sock_set_addr_preferences(NULL, 0);
1696 ],[
1697         AC_DEFINE(HAVE_IP6_SET_PREF, 1,
1698                 [if ip6_sock_set_addr_preferences exists])
1699 ])
1700 EXTRA_KCFLAGS="$tmp_flags"
1701 ]) # LIBCFS_IP6_SET_PREF
1702
1703 #
1704 # LIBCFS_VMALLOC_2ARGS
1705 #
1706 # kernel v5.8-rc1~201^2~19
1707 # mm: remove the pgprot argument to __vmalloc
1708 AC_DEFUN([LIBCFS_VMALLOC_2ARGS], [
1709 LB_CHECK_COMPILE([if __vmalloc has 2 args],
1710 vmalloc_2args, [
1711         #include <linux/vmalloc.h>
1712 ],[
1713         __vmalloc(0, 0);
1714 ],[
1715         AC_DEFINE(HAVE_VMALLOC_2ARGS, 1,
1716                 [__vmalloc only takes 2 args.])
1717 ])
1718 ]) # LIBCFS_VMALLOC_2ARGS
1719
1720 #
1721 # LIBCFS_HAVE_NR_UNSTABLE_NFS
1722 #
1723 # kernel v5.8-rc1~201^2~75
1724 # mm/writeback: discard NR_UNSTABLE_NFS, use NR_WRITEBACK instead
1725 #
1726 AC_DEFUN([LIBCFS_HAVE_NR_UNSTABLE_NFS], [
1727 tmp_flags="$EXTRA_KCFLAGS"
1728 EXTRA_KCFLAGS="-Werror"
1729 LB_CHECK_COMPILE([if NR_UNSTABLE_NFS still in use],
1730 nr_unstable_nfs_exists, [
1731         #include <linux/mm.h>
1732
1733         int i;
1734 ],[
1735         i = NR_UNSTABLE_NFS;
1736 ],[
1737         AC_DEFINE(HAVE_NR_UNSTABLE_NFS, 1,
1738                 [NR_UNSTABLE_NFS is still in use.])
1739 ])
1740 EXTRA_KCFLAGS="$tmp_flags"
1741 ]) # LIBCFS_HAVE_NR_UNSTABLE_NFS
1742
1743 #
1744 # LIBCFS_HAVE_MMAP_LOCK
1745 #
1746 # kernel v5.8-rc1~83^2~24
1747 # mmap locking API: rename mmap_sem to mmap_lock
1748 #
1749 AC_DEFUN([LIBCFS_HAVE_MMAP_LOCK], [
1750 LB_CHECK_COMPILE([if mmap_lock API is available],
1751 mmap_write_lock, [
1752         #include <linux/mm.h>
1753 ],[
1754         mmap_write_lock(NULL);
1755 ],[
1756         AC_DEFINE(HAVE_MMAP_LOCK, 1,
1757                 [mmap_lock API is available.])
1758 ])
1759 ]) # LIBCFS_HAVE_MMAP_LOCK
1760
1761 #
1762 # LIBCFS_KERNEL_SETSOCKOPT
1763 #
1764 # kernel v5.8-rc1~165^2~59^2
1765 # net: remove kernel_setsockopt
1766 AC_DEFUN([LIBCFS_KERNEL_SETSOCKOPT], [
1767 tmp_flags="$EXTRA_KCFLAGS"
1768 EXTRA_KCFLAGS="-Werror"
1769 LB_CHECK_COMPILE([if kernel_setsockopt still in use],
1770 kernel_setsockopt_exists, [
1771         #include <linux/net.h>
1772 ],[
1773         kernel_setsockopt(NULL, 0, 0, NULL, 0);
1774 ],[
1775         AC_DEFINE(HAVE_KERNEL_SETSOCKOPT, 1,
1776                 [kernel_setsockopt still in use])
1777 ])
1778 EXTRA_KCFLAGS="$tmp_flags"
1779 ]) # LIBCFS_KERNEL_SETSOCKOPT
1780
1781 #
1782 # LIBCFS_SEC_RELEASE_SECCTX
1783 #
1784 # kernel linux-hwe-5.8 (5.8.0-22.23~20.04.1)
1785 # LSM: Use lsmcontext in security_release_secctx
1786 AC_DEFUN([LIBCFS_SEC_RELEASE_SECCTX], [
1787 LB_CHECK_COMPILE([if security_release_secctx has 1 arg],
1788 security_release_secctx_1arg, [
1789         #include <linux/security.h>
1790 ],[
1791         security_release_secctx(NULL);
1792 ],[
1793         AC_DEFINE(HAVE_SEC_RELEASE_SECCTX_1ARG, 1,
1794                 [security_release_secctx has 1 arg.])
1795 ])
1796 ]) # LIBCFS_SEC_RELEASE_SECCTX
1797
1798 #
1799 # LIBCFS_HAVE_KFREE_SENSITIVE
1800 #
1801 # kernel v5.10-rc1~3
1802 # mm: remove kzfree() compatibility definition
1803 #
1804 AC_DEFUN([LIBCFS_HAVE_KFREE_SENSITIVE], [
1805 LB_CHECK_COMPILE([if kfree_sensitive() is available],
1806 kfree_sensitive_exists, [
1807         #include <linux/slab.h>
1808
1809 ],[
1810         kfree_sensitive(NULL);
1811 ],[
1812         AC_DEFINE(HAVE_KFREE_SENSITIVE, 1,
1813                 [kfree_sensitive() is available.])
1814 ])
1815 EXTRA_KCFLAGS="$tmp_flags"
1816 ]) # LIBCFS_HAVE_KFREE_SENSITIVE
1817
1818 #
1819 # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1820 #
1821 # Kernel v5.10-rc1-114-ga24d22b225ce
1822 # crypto: sha - split sha.h into sha1.h and sha2.h
1823 #
1824 AC_DEFUN([LIBCFS_HAVE_CRYPTO_SHA2_HEADER], [
1825 LB_CHECK_LINUX_HEADER([crypto/sha2.h], [
1826         AC_DEFINE(HAVE_CRYPTO_SHA2_HEADER, 1,
1827                 [crypto/sha2.h is present])])
1828 ]) # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1829
1830 #
1831 # LIBCFS_HAVE_LIST_CMP_FUNC_T
1832 #
1833 # kernel 5.10.70 commit 4f0f586bf0c898233d8f316f471a21db2abd522d
1834 # treewide: Change list_sort to use const pointers
1835 AC_DEFUN([LIBCFS_HAVE_LIST_CMP_FUNC_T], [
1836 tmp_flags="$EXTRA_KCFLAGS"
1837 EXTRA_KCFLAGS="-Werror -Wno-unused-variable"
1838 LB_CHECK_COMPILE([if list_cmp_func_t type is defined],
1839 list_cmp_func_t, [
1840         #include <linux/list_sort.h>
1841 ],[
1842         list_cmp_func_t cmp;
1843 ],[
1844         AC_DEFINE(HAVE_LIST_CMP_FUNC_T, 1,
1845                 [list_cmp_func_t type is defined])
1846 ])
1847 EXTRA_KCFLAGS="$tmp_flags"
1848 ]) # LIBCFS_HAVE_LIST_CMP_FUNC_T
1849
1850 #
1851 # LIBCFS_NLA_STRLCPY
1852 #
1853 # Kernel version 5.10-rc3 commit 872f690341948b502c93318f806d821c56772c42
1854 # replaced nla_strlcpy() with nla_strscpy().
1855 #
1856 AC_DEFUN([LIBCFS_NLA_STRLCPY], [
1857 LB_CHECK_COMPILE([if 'nla_strlcpy()' still exists],
1858 nla_strlcpy, [
1859         #include <net/netlink.h>
1860 ],[
1861         if (nla_strlcpy(NULL, NULL, 0) == 0)
1862                 return -EINVAL;
1863 ],[
1864         AC_DEFINE(HAVE_NLA_STRLCPY, 1,
1865                 ['nla_strlcpy' is available])
1866 ])
1867 ]) # LIBCFS_NLA_STRLCPY
1868
1869 #
1870 # LIBCFS_HAVE_CIPHER_HEADER
1871 #
1872 # Kernel 5.12 commit 0eb76ba29d16df2951d37c54ca279c4e5630b071
1873 # crypto: remove cipher routines from public crypto API
1874 #
1875 AC_DEFUN([LIBCFS_HAVE_CIPHER_HEADER], [
1876 tmp_flags="$EXTRA_KCFLAGS"
1877 EXTRA_KCFLAGS="-Werror"
1878 LB_CHECK_LINUX_HEADER([crypto/internal/cipher.h], [
1879         AC_DEFINE(HAVE_CIPHER_H, 1,
1880                 [crypto/internal/cipher.h is present])
1881 ])
1882 EXTRA_KCFLAGS="$tmp_flags"
1883 ]) # LIBCFS_HAVE_CIPHER_HEADER
1884
1885 #
1886 # LIBCFS_HAVE_TASK_RUNNING
1887 #
1888 # Kernel 5.13-rc6 commit b03fbd4ff24c5f075e58eb19261d5f8b3e40d
1889 # introduced task_is_running() macro.
1890 #
1891 AC_DEFUN([LIBCFS_HAVE_TASK_IS_RUNNING], [
1892 tmp_flags="$EXTRA_KCFLAGS"
1893 EXTRA_KCFLAGS="-Werror"
1894 LB_CHECK_COMPILE([if task_is_running() is defined],
1895 task_is_running, [
1896         #include <linux/sched.h>
1897 ],[
1898         if (task_is_running(current))
1899                 schedule();
1900 ],[
1901         AC_DEFINE(HAVE_TASK_IS_RUNNING, 1,
1902                 [task_is_running() is defined])
1903 ])
1904 EXTRA_KCFLAGS="$tmp_flags"
1905 ]) # LIBCFS_HAVE_TASK_IS_RUNNING
1906
1907 #
1908 # LIBCFS_LINUX_STDARG_HEADER
1909 #
1910 # Kernel 5.14-rc5 commit c0891ac15f0428ffa81b2e818d416bdf3cb74ab6
1911 # isystem: ship and use stdarg.h
1912 #
1913 AC_DEFUN([LIBCFS_LINUX_STDARG_HEADER], [
1914 tmp_flags="$EXTRA_KCFLAGS"
1915 EXTRA_KCFLAGS="-Werror"
1916 LB_CHECK_LINUX_HEADER([linux/stdarg.h], [
1917         AC_DEFINE(HAVE_LINUX_STDARG_HEADER, 1, [linux/stdarg.h is present])
1918 ])
1919 EXTRA_KCFLAGS="$tmp_flags"
1920 ]) # LIBCFS_LINUX_STDARG_HEADER
1921
1922 #
1923 # LIBCFS_HAVE_PANIC_NOTIFIER_HEADER
1924 #
1925 # Kernel 5.14 commit f39650de687e35766572ac89dbcd16a5911e2f0a
1926 # kernel.h: split out panic and oops helpers
1927 #
1928 AC_DEFUN([LIBCFS_HAVE_PANIC_NOTIFIER_HEADER], [
1929 tmp_flags="$EXTRA_KCFLAGS"
1930 EXTRA_KCFLAGS="-Werror"
1931 LB_CHECK_LINUX_HEADER([linux/panic_notifier.h], [
1932         AC_DEFINE(HAVE_PANIC_NOTIFIER_H, 1,
1933                 [linux/panic_notifier.h is present])
1934 ])
1935 EXTRA_KCFLAGS="$tmp_flags"
1936 ]) # LIBCFS_HAVE_PANIC_NOTIFIER_HEADER
1937
1938 #
1939 # LIBCFS_PARAM_SET_UINT_MINMAX
1940 #
1941 # Kernel 5.15-rc1 commit 2a14c9ae15a38148484a128b84bff7e9ffd90d68
1942 # moved param_set_uint_minmax to common code
1943 #
1944 AC_DEFUN([LIBCFS_PARAM_SET_UINT_MINMAX],[
1945 LB_CHECK_COMPILE([does function 'param_set_uint_minmax' exist],
1946 param_set_uint_minmax, [
1947         #include <linux/moduleparam.h>
1948 ],[
1949         param_set_uint_minmax(NULL, NULL, 0, 0);
1950 ],[
1951         AC_DEFINE(HAVE_PARAM_SET_UINT_MINMAX, 1,
1952                 ['param_set_uint_minmax' is available])
1953 ])
1954 ]) # LIBCFS_PARAM_SET_UINT_MINMAX
1955
1956 AC_DEFUN([LIBCFS_PROG_LINUX_SRC], [
1957         # 5.6
1958         LIBCFS_SRC_HAVE_PROC_OPS
1959
1960         AC_MSG_CHECKING([for available kernel interfaces to libcfs])
1961         LB2_LINUX_TEST_COMPILE_ALL([libcfs])
1962         AC_MSG_RESULT([done])
1963 ])
1964 AC_DEFUN([LIBCFS_PROG_LINUX_RESULTS], [
1965         # 5.6
1966         LIBCFS_HAVE_PROC_OPS
1967 ])
1968
1969 #
1970 # LIBCFS_LINUX_BLK_INTEGRITY_HEADER
1971 #
1972 # Kernel 5.15-rc6 commit fe45e630a1035aea94c29016f2598bbde149bbe3
1973 # block: move integrity handling out of <linux/blkdev.h>
1974 #
1975 AC_DEFUN([LIBCFS_LINUX_BLK_INTEGRITY_HEADER], [
1976 tmp_flags="$EXTRA_KCFLAGS"
1977 EXTRA_KCFLAGS="-Werror"
1978 LB_CHECK_LINUX_HEADER([linux/blk-integrity.h], [
1979         AC_DEFINE(HAVE_LINUX_BLK_INTEGRITY_HEADER, 1,
1980                 [linux/blk-integrity.h is present])
1981 ])
1982 EXTRA_KCFLAGS="$tmp_flags"
1983 ]) # LIBCFS_LINUX_BLK_INTEGRITY_HEADER
1984
1985 #
1986 # LIBCFS_PDE_DATA_EXISTS
1987 #
1988 # Linux commit v5.16-11573-g6dfbbae14a7b
1989 #    introduce pde_data()
1990 # Linux commit v5.16-11574-g359745d78351
1991 #    remove PDE_DATA()
1992 #
1993 AC_DEFUN([LIBCFS_PDE_DATA_EXISTS],[
1994 LB_CHECK_COMPILE([does function 'pde_data' exist],
1995 pde_data, [
1996                 #include <linux/proc_fs.h>
1997         ],[
1998                 struct inode *inode = NULL;
1999                 void *data =pde_data(inode);
2000                 (void)data;
2001         ],[
2002                 AC_DEFINE(HAVE_pde_data, 1, [function pde_data() available])
2003         ],[
2004                 AC_DEFINE(pde_data(inode), PDE_DATA(inode),
2005                           [function pde_data() unavailable])
2006         ])
2007 ]) # LIBCFS_PDE_DATA_EXISTS
2008
2009 #
2010 # LIBCFS_BIO_ALLOC_WITH_BDEV
2011 #
2012 # Linux commit v5.17-rc2-21-g07888c665b40
2013 #   block: pass a block_device and opf to bio_alloc
2014 #
2015 AC_DEFUN([LIBCFS_BIO_ALLOC_WITH_BDEV],[
2016 LB_CHECK_COMPILE([does bio_alloc() takes a struct block_device],
2017 bio_alloc_with_bdev, [
2018                 #include <linux/bio.h>
2019         ],[
2020                 struct block_device *bdev = NULL;
2021                 unsigned short nr_vecs = 1;
2022                 gfp_t gfp = GFP_KERNEL;
2023                 struct bio *bio = bio_alloc(bdev, nr_vecs, REQ_OP_WRITE, gfp);
2024                 (void) bio;
2025         ],[
2026                 AC_DEFINE(HAVE_BIO_ALLOC_WITH_BDEV, 1,
2027                         [bio_alloc() takes a struct block_device])
2028         ])
2029 ]) # LIBCFS_BIO_ALLOC_WITH_BDEV
2030
2031 #
2032 # LIBCFS_PROG_LINUX
2033 #
2034 # LibCFS linux kernel checks
2035 #
2036 AC_DEFUN([LIBCFS_PROG_LINUX], [
2037 AC_MSG_NOTICE([LibCFS kernel checks
2038 ==============================================================================])
2039 LIBCFS_CONFIG_PANIC_DUMPLOG
2040
2041 # 3.11
2042 LIBCFS_KTIME_GET_TS64
2043 # 3.12
2044 LIBCFS_PREPARE_TO_WAIT_EVENT
2045 LIBCFS_KERNEL_PARAM_OPS
2046 LIBCFS_KTIME_ADD
2047 LIBCFS_KTIME_AFTER
2048 LIBCFS_KTIME_BEFORE
2049 LIBCFS_KTIME_COMPARE
2050 LIBCFS_SHRINKER_COUNT
2051 # 3.13
2052 LIBCFS_MATCH_WILDCARD
2053 # 3.15
2054 LIBCFS_HAVE_MAPPING_AS_EXITING_FLAG
2055 LIBCFS_IOV_ITER_HAS_TYPE
2056 # 3.16
2057 LIBCFS_HAVE_GLOB
2058 LIBCFS_HAVE_NS_TO_TIMESPEC64
2059 # 3.17
2060 LIBCFS_HLIST_ADD_AFTER
2061 LIBCFS_TIMESPEC64
2062 LIBCFS_KTIME_GET_NS
2063 LIBCFS_KTIME_GET_REAL_TS64
2064 LIBCFS_KTIME_GET_REAL_SECONDS
2065 LIBCFS_KTIME_GET_REAL_NS
2066 LIBCFS_KTIME_TO_TIMESPEC64
2067 LIBCFS_TIMESPEC64_SUB
2068 LIBCFS_TIMESPEC64_TO_KTIME
2069 # 3.19
2070 LIBCFS_KTIME_GET_SECONDS
2071 LIBCFS_WAIT_WOKEN
2072 # 4.0
2073 LIBCFS_KTIME_MS_DELTA
2074 # 4.1
2075 LIBCFS_KERNEL_PARAM_LOCK
2076 # 4.2
2077 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
2078 # 4.4
2079 LIBCFS_KSTRTOBOOL_FROM_USER
2080 LIBCFS_NETLINK_CALLBACK_START
2081 # 4.5
2082 LIBCFS_CRYPTO_HASH_HELPERS
2083 LIBCFS_EXPORT_KSET_FIND_OBJ
2084 LIBCFS_RHASHTABLE_REPLACE
2085 # 4.6
2086 LIBCFS_BROKEN_HASH_64
2087 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
2088 LIBCFS_GET_USER_PAGES_6ARG
2089 LIBCFS_STRINGHASH
2090 # 4.7
2091 LIBCFS_RHASHTABLE_INSERT_FAST
2092 LIBCFS_RHASHTABLE_WALK_INIT_3ARG
2093 # 4.8
2094 LIBCFS_RHASHTABLE_LOOKUP
2095 LIBCFS_RHLTABLE
2096 LIBCFS_STACKTRACE_OPS
2097 # 4.9
2098 LIBCFS_GET_USER_PAGES_GUP_FLAGS
2099 LIBCFS_RHASHTABLE_WALK_ENTER
2100 # 4.10
2101 LIBCFS_HOTPLUG_STATE_MACHINE
2102 LIBCFS_REFCOUNT_T
2103 # 4.11
2104 LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
2105 LIBCFS_SCHED_HEADERS
2106 LIBCFS_KREF_READ
2107 LIBCFS_RHT_BUCKET_VAR
2108 # 4.12
2109 LIBCFS_HAVE_PROCESSOR_HEADER
2110 LIBCFS_HAVE_WAIT_BIT_HEADER
2111 LIBCFS_MEMALLOC_NORECLAIM
2112 LIBCFS_NL_EXT_ACK
2113 LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
2114 LIBCFS_CPUS_READ_LOCK
2115 LIBCFS_UUID_T
2116 # 4.13
2117 LIBCFS_NLA_STRDUP
2118 LIBCFS_WAIT_QUEUE_ENTRY
2119 LIBCFS_WAIT_BIT_QUEUE_ENTRY_EXISTS
2120 # 4.14
2121 LIBCFS_DEFINE_TIMER
2122 LIBCFS_NEW_KERNEL_WRITE
2123 LIBCFS_NEW_KERNEL_READ
2124 LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
2125 # 4.15
2126 LIBCFS_LOCKDEP_IS_HELD
2127 LIBCFS_TIMER_SETUP
2128 # 4.16
2129 LIBCFS_WAIT_VAR_EVENT
2130 # 4.17
2131 LIBCFS_BITMAP_ALLOC
2132 LIBCFS_CLEAR_AND_WAKE_UP_BIT
2133 # 4.18
2134 LIBCFS_TCP_SOCK_SET_NODELAY
2135 LIBCFS_TCP_SOCK_SET_KEEPIDLE
2136 # 4.19
2137 LIBCFS_XARRAY_SUPPORT
2138 LIBCFS_NL_DUMP_EXT_ACK
2139 # 4.20
2140 LIBCFS_HAVE_IOV_ITER_TYPE
2141 # 5.0
2142 LIBCFS_GENRADIX
2143 LIBCFS_MM_TOTALRAM_PAGES_FUNC
2144 LIBCFS_GET_REQUEST_KEY_AUTH
2145 # 5.2
2146 LIBCFS_KOBJ_TYPE_DEFAULT_GROUPS
2147 # 5.3
2148 LIBCFS_LOOKUP_USER_KEY
2149 LIBCFS_FORCE_SIG_WITH_TASK
2150 LIBCFS_CACHE_DETAIL_WRITERS
2151 # 5.4
2152 LIBCFS_GENL_DUMPIT_INFO
2153 # 5.7
2154 LIBCFS_KALLSYMS_LOOKUP
2155 LIBCFS_TCP_SOCK_SET_QUICKACK
2156 LIBCFS_TCP_SOCK_SET_KEEPINTVL
2157 LIBCFS_TCP_SOCK_SET_KEEPCNT
2158 # 5.8
2159 LIBCFS_HAVE_MMAP_LOCK
2160 LIBCFS_KERNEL_SETSOCKOPT
2161 LIBCFS_VMALLOC_2ARGS
2162 LIBCFS_HAVE_NR_UNSTABLE_NFS
2163 LIBCFS_SEC_RELEASE_SECCTX
2164 LIBCFS_IP6_SET_PREF
2165 # 5.10
2166 LIBCFS_HAVE_KFREE_SENSITIVE
2167 LIBCFS_HAVE_CRYPTO_SHA2_HEADER
2168 LIBCFS_HAVE_LIST_CMP_FUNC_T
2169 LIBCFS_NLA_STRLCPY
2170 # 5.12
2171 LIBCFS_HAVE_CIPHER_HEADER
2172 # 5.13
2173 LIBCFS_HAVE_TASK_IS_RUNNING
2174 # 5.14
2175 LIBCFS_LINUX_STDARG_HEADER
2176 LIBCFS_HAVE_PANIC_NOTIFIER_HEADER
2177 # 5.15
2178 LIBCFS_PARAM_SET_UINT_MINMAX
2179 LIBCFS_LINUX_BLK_INTEGRITY_HEADER
2180 # 5.17
2181 LIBCFS_PDE_DATA_EXISTS
2182 LIBCFS_BIO_ALLOC_WITH_BDEV
2183 ]) # LIBCFS_PROG_LINUX
2184
2185 #
2186 # LIBCFS_PATH_DEFAULTS
2187 #
2188 # default paths for installed files
2189 #
2190 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
2191 ]) # LIBCFS_PATH_DEFAULTS
2192
2193 #
2194 # LIBCFS_CONFIGURE
2195 #
2196 # other configure checks
2197 #
2198 AC_DEFUN([LIBCFS_CONFIGURE], [
2199 AC_MSG_NOTICE([LibCFS core checks
2200 ==============================================================================])
2201
2202 # libcfs/libcfs/util/nidstrings.c
2203 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
2204 AC_CHECK_FUNCS([gethostbyname])
2205
2206 # --------  Check for required packages  --------------
2207
2208 AC_MSG_NOTICE([LibCFS required packages checks
2209 ==============================================================================])
2210
2211 AC_MSG_CHECKING([whether to enable readline support])
2212 AC_ARG_ENABLE(readline,
2213         AS_HELP_STRING([--disable-readline],
2214                 [disable readline support]),
2215         [], [enable_readline="yes"])
2216 AC_MSG_RESULT([$enable_readline])
2217
2218 LIBREADLINE=""
2219 AS_IF([test "x$enable_readline" = xyes], [
2220         AC_CHECK_LIB([readline], [readline], [
2221                 LIBREADLINE="-lreadline"
2222                 AC_DEFINE(HAVE_LIBREADLINE, 1,
2223                         [readline library is available])
2224         ])
2225 ])
2226 AC_SUBST(LIBREADLINE)
2227
2228 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
2229 AC_ARG_ENABLE([libpthread],
2230         AS_HELP_STRING([--disable-libpthread],
2231                 [disable libpthread]),
2232         [], [enable_libpthread="yes"])
2233 AC_MSG_RESULT([$enable_libpthread])
2234
2235 PTHREAD_LIBS=""
2236 AS_IF([test "x$enable_libpthread" = xyes], [
2237         AC_CHECK_LIB([pthread], [pthread_create], [
2238                 PTHREAD_LIBS="-lpthread"
2239                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
2240                         [use libpthread for libcfs library])
2241         ])
2242 ], [
2243         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
2244 ])
2245 AC_SUBST(PTHREAD_LIBS)
2246 ]) # LIBCFS_CONFIGURE
2247
2248 #
2249 # LIBCFS_CONFIG_FILES
2250 #
2251 # files that should be generated with AC_OUTPUT
2252 #
2253 AC_DEFUN([LIBCFS_CONFIG_FILES], [
2254 AC_CONFIG_FILES([
2255 libcfs/Makefile
2256 libcfs/autoMakefile
2257 libcfs/autoconf/Makefile
2258 libcfs/include/Makefile
2259 libcfs/include/libcfs/Makefile
2260 libcfs/include/uapi/Makefile
2261 libcfs/include/libcfs/linux/Makefile
2262 libcfs/include/libcfs/util/Makefile
2263 libcfs/include/libcfs/crypto/Makefile
2264 libcfs/include/uapi/linux/Makefile
2265 libcfs/libcfs/Makefile
2266 libcfs/libcfs/autoMakefile
2267 libcfs/libcfs/linux/Makefile
2268 libcfs/libcfs/util/Makefile
2269 libcfs/libcfs/crypto/Makefile
2270 ])
2271 ]) # LIBCFS_CONFIG_FILES