config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='$(CROSS_PATH)/lib/modules/$(LINUXRELEASE)/updates/kernel'
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_CROSS
 259 LB_LINUX_VERSION
 260
 261 # --- check that we can build modules at all
 262 AC_MSG_CHECKING([that modules can be built at all])
 263 LB_LINUX_TRY_COMPILE([],[],[
 264         AC_MSG_RESULT([yes])
 265 ],[
 266         AC_MSG_RESULT([no])
 267         AC_MSG_WARN([Consult config.log for details.])
 268         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 269         AC_MSG_ERROR([Kernel modules cannot be built.])
 270 ])
 271
 272 LB_LINUX_RELEASE
 273 ]) # end of LB_LINUX_PATH
 274
 275 # LB_LINUX_SYMVERFILE
 276 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 277 # around this version, but it matters for servers only.
 278 AC_DEFUN([LB_LINUX_SYMVERFILE],
 279         [AC_MSG_CHECKING([name of module symbol version file])
 280         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 281                 SYMVERFILE=Modules.symvers
 282         else
 283                 SYMVERFILE=Module.symvers
 284         fi
 285         AC_MSG_RESULT($SYMVERFILE)
 286         AC_SUBST(SYMVERFILE)
 287 ])
 288
 289 #
 290 # LB_LINUX_CROSS
 291 #
 292 # check for cross compilation
 293 #
 294 AC_DEFUN([LB_LINUX_CROSS],
 295         [AC_MSG_CHECKING([for cross compilation])
 296 CROSS_VARS=
 297 CROSS_PATH=
 298 AS_IF([test "x$cross_compiling" = xno], [AC_MSG_RESULT([no])],
 299         [case $host_vendor in
 300                 # The K1OM architecture is an extension of the x86 architecture.
 301                 # So, the $host_arch is x86_64.
 302                 k1om)
 303                         AC_MSG_RESULT([Intel(R) Xeon Phi(TM)])
 304                         CC_TARGET_ARCH=`$CC -v 2>&1 | grep Target: | sed -e 's/Target: //'`
 305                         if test $CC_TARGET_ARCH != x86_64-$host_vendor-linux ; then
 306                                 AC_MSG_ERROR([Cross compiler not found in PATH.])
 307                         fi
 308                         CROSS_VARS="ARCH=$host_vendor CROSS_COMPILE=x86_64-$host_vendor-linux-"
 309                         CROSS_PATH=${CROSS_PATH:=/opt/intel/mic/lustre/device-k1om}
 310                         CCAS=$CC
 311                         # need to produce special section for debuginfo extraction
 312                         LDFLAGS="${LDFLAGS} -Wl,--build-id"
 313                         EXTRA_KLDFLAGS="${EXTRA_KLDFLAGS} -Wl,--build-id"
 314                         if test x$enable_server = xyes ; then
 315                                 AC_MSG_WARN([Disabling server (not supported for x86_64-$host_vendor-linux).])
 316                                 enable_server='no'
 317                         fi
 318                         ;;
 319                 *)
 320                         AC_MSG_RESULT([yes, but no changes])
 321                         ;;
 322         esac
 323         ])
 324 AC_SUBST(CROSS_VARS)
 325 AC_SUBST(CROSS_PATH)
 326 ])
 327
 328 # these are like AC_TRY_COMPILE, but try to build modules against the
 329 # kernel, inside the build directory
 330
 331 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 332 # --------------------------------------
 333 m4_define([LB_LANG_PROGRAM],
 334 [
 335 #include <linux/kernel.h>
 336 $1
 337 int
 338 main (void)
 339 {
 340 dnl Do *not* indent the following line: there may be CPP directives.
 341 dnl Don't move the `;' right after for the same reason.
 342 $2
 343   ;
 344   return 0;
 345 }])
 346
 347 #
 348 # LB_LINUX_COMPILE_IFELSE
 349 #
 350 # like AC_COMPILE_IFELSE
 351 #
 352 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 353 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 354 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 355 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 356         [$4],
 357         [_AC_MSG_LOG_CONFTEST
 358 m4_ifvaln([$5],[$5])dnl])
 359 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 360 ])
 361
 362 #
 363 # LB_LINUX_ARCH
 364 #
 365 # Determine the kernel's idea of the current architecture
 366 #
 367 AC_DEFUN([LB_LINUX_ARCH],
 368          [AC_MSG_CHECKING([Linux kernel architecture])
 369           AS_IF([rm -f $PWD/build/arch
 370                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 371                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $CROSS_VARS  \
 372                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 373                 [AC_MSG_RESULT([$LINUX_ARCH])],
 374                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 375           rm -f build/arch])
 376
 377 #
 378 # LB_LINUX_TRY_COMPILE
 379 #
 380 # like AC_TRY_COMPILE
 381 #
 382 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 383 [LB_LINUX_COMPILE_IFELSE(
 384         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 385         [modules],
 386         [test -s build/conftest.o],
 387         [$3], [$4])])
 388
 389 #
 390 # LB_LINUX_CONFIG
 391 #
 392 # check if a given config option is defined
 393 #
 394 AC_DEFUN([LB_LINUX_CONFIG],[
 395         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 396         LB_LINUX_TRY_COMPILE([
 397                 #include <$AUTOCONF_HDIR/autoconf.h>
 398         ],[
 399                 #ifndef CONFIG_$1
 400                 #error CONFIG_$1 not #defined
 401                 #endif
 402         ],[
 403                 AC_MSG_RESULT([yes])
 404                 $2
 405         ],[
 406                 AC_MSG_RESULT([no])
 407                 $3
 408         ])
 409 ])
 410
 411 #
 412 # LB_LINUX_CONFIG_IM
 413 #
 414 # check if a given config option is builtin or as module
 415 #
 416 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 417         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 418         LB_LINUX_TRY_COMPILE([
 419                 #include <$AUTOCONF_HDIR/autoconf.h>
 420         ],[
 421                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 422                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 423                 #endif
 424         ],[
 425                 AC_MSG_RESULT([yes])
 426                 $2
 427         ],[
 428                 AC_MSG_RESULT([no])
 429                 $3
 430         ])
 431 ])
 432
 433 #
 434 # LB_LINUX_TRY_MAKE
 435 #
 436 # like LB_LINUX_TRY_COMPILE, but with different arguments
 437 #
 438 AC_DEFUN([LB_LINUX_TRY_MAKE],
 439         [LB_LINUX_COMPILE_IFELSE(
 440                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 441                 [$3], [$4], [$5], [$6]
 442         )]
 443 )
 444
 445 #
 446 # LB_CONFIG_COMPAT_RDMA
 447 #
 448 AC_DEFUN([LB_CONFIG_COMPAT_RDMA],
 449 [AC_MSG_CHECKING([whether to use Compat RDMA])
 450 # set default
 451 AC_ARG_WITH([o2ib],
 452         AC_HELP_STRING([--with-o2ib=path],
 453                        [build o2iblnd against path]),
 454         [
 455                 case $with_o2ib in
 456                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 457                         ENABLEO2IB=2
 458                         ;;
 459                 no)     ENABLEO2IB=0
 460                         ;;
 461                 *)      O2IBPATHS=$with_o2ib
 462                         ENABLEO2IB=3
 463                         ;;
 464                 esac
 465         ],[
 466                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 467                 ENABLEO2IB=1
 468         ])
 469 if test $ENABLEO2IB -eq 0; then
 470         AC_MSG_RESULT([no])
 471 else
 472         o2ib_found=false
 473         for O2IBPATH in $O2IBPATHS; do
 474                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 475                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 476                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 477                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 478                         o2ib_found=true
 479                         break
 480                 fi
 481         done
 482         compatrdma_found=false
 483         if $o2ib_found; then
 484                 if test \( -f ${O2IBPATH}/include/linux/compat-2.6.h \); then
 485                         compatrdma_found=true
 486                         AC_MSG_RESULT([yes])
 487                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 488                 else
 489                         AC_MSG_RESULT([no])
 490                 fi
 491         fi
 492 fi
 493 ])
 494
 495 #
 496 # LB_CONFIG_OFED_BACKPORTS
 497 #
 498 # include any OFED backport headers in all compile commands
 499 # NOTE: this does only include the backport paths, not the OFED headers
 500 #       adding the OFED headers is done in the lnet portion
 501 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 502 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 503 if test $ENABLEO2IB -eq 0; then
 504         AC_MSG_RESULT([no])
 505 else
 506         if ! $o2ib_found; then
 507                 AC_MSG_RESULT([no])
 508                 case $ENABLEO2IB in
 509                         1) ;;
 510                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 511                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 512                         *) AC_MSG_ERROR([internal error]);;
 513                 esac
 514         else
 515                 if ! $compatrdma_found; then
 516                         if test -f $O2IBPATH/config.mk; then
 517                                 . $O2IBPATH/config.mk
 518                         elif test -f $O2IBPATH/ofed_patch.mk; then
 519                                 . $O2IBPATH/ofed_patch.mk
 520                         fi
 521                 fi
 522                 if test -n "$BACKPORT_INCLUDES"; then
 523                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 524                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 525                         AC_MSG_RESULT([yes])
 526                 else
 527                         AC_MSG_RESULT([no])
 528                 fi
 529         fi
 530 fi
 531 ])
 532
 533 # LC_MODULE_LOADING
 534 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 535 # so we test if request_module is implemented or not
 536 AC_DEFUN([LC_MODULE_LOADING],
 537 [AC_MSG_CHECKING([if kernel module loading is possible])
 538 LB_LINUX_TRY_MAKE([
 539         #include <linux/kmod.h>
 540 ],[
 541         int myretval=ENOSYS ;
 542         return myretval;
 543 ],[
 544         $makerule LUSTRE_KERNEL_TEST=conftest.i
 545 ],[dnl
 546         grep request_module build/conftest.i |dnl
 547                 grep -v `grep "int myretval=" build/conftest.i |dnl
 548                         cut -d= -f2 | cut -d" "  -f1`dnl
 549                 >/dev/null dnl
 550 ],[
 551         AC_MSG_RESULT(yes)
 552         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 553                   [kernel module loading is possible])
 554 ],[
 555         AC_MSG_RESULT(no)
 556         AC_MSG_WARN([])
 557         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 558         AC_MSG_WARN([])
 559 ])
 560 ])
 561
 562 #
 563 # LB_PROG_LINUX
 564 #
 565 # linux tests
 566 #
 567 AC_DEFUN([LB_PROG_LINUX],
 568 [LB_LINUX_PATH
 569 LB_LINUX_ARCH
 570 LB_LINUX_SYMVERFILE
 571
 572
 573 LB_LINUX_CONFIG([MODULES],[],[
 574         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 575 ])
 576
 577 LB_LINUX_CONFIG([MODVERSIONS])
 578
 579 LB_LINUX_CONFIG([KALLSYMS],[],[
 580         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 581 ])
 582
 583 # 2.6.28
 584 LC_MODULE_LOADING
 585
 586 LB_CONFIG_COMPAT_RDMA
 587
 588 # it's ugly to be doing anything with OFED outside of the lnet module, but
 589 # this has to be done here so that the backports path is set before all of
 590 # the LN_PROG_LINUX checks are done
 591 LB_CONFIG_OFED_BACKPORTS
 592 ])
 593
 594 #
 595 # LB_CHECK_SYMBOL_EXPORT
 596 # check symbol exported or not
 597 # $1 - symbol
 598 # $2 - file(s) for find.
 599 # $3 - do 'yes'
 600 # $4 - do 'no'
 601 #
 602 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 603 # or check
 604 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 605 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 606 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 607 rc=$?
 608 if test $rc -ne 0; then
 609         export=0
 610         for file in $2; do
 611                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 612                 rc=$?
 613                 if test $rc -eq 0; then
 614                         export=1
 615                         break;
 616                 fi
 617         done
 618         if test $export -eq 0; then
 619                 AC_MSG_RESULT([no])
 620                 $4
 621         else
 622                 AC_MSG_RESULT([yes])
 623                 $3
 624         fi
 625 else
 626         AC_MSG_RESULT([yes])
 627         $3
 628 fi
 629 ])
 630
 631 #
 632 # Like AC_CHECK_HEADER but checks for a kernel-space header
 633 #
 634 m4_define([LB_CHECK_LINUX_HEADER],
 635 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 636 AC_CACHE_CHECK([for $1], ac_Header,
 637                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 638                                   [modules],
 639                                   [test -s build/conftest.o],
 640                                   [AS_VAR_SET(ac_Header, [yes])],
 641                                   [AS_VAR_SET(ac_Header, [no])])])
 642 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 643 AS_VAR_POPDEF([ac_Header])dnl
 644 ])
 645
 646 #
 647 # LB_USES_DPKG
 648 #
 649 # Determine if the target is a dpkg system or rpm
 650 #
 651 AC_DEFUN([LB_USES_DPKG],
 652 [
 653 AC_MSG_CHECKING([if this distro uses dpkg])
 654 case `lsb_release -i -s 2>/dev/null` in
 655         Ubuntu | Debian)
 656                 AC_MSG_RESULT([yes])
 657                 uses_dpkg=yes
 658                 ;;
 659         *)
 660                 AC_MSG_RESULT([no])
 661                 uses_dpkg=no
 662                 ;;
 663 esac
 664 ])